Peter Popov wrote:
 
> If it were a bicubic_patch I'd call it double_illuminate trouble, but
> I don't think hf's have this problem. I'm at a loss too.

Well, it seems to have that. While setting up a bug-report scene I ran 
into another bug. It chrashes in 3.1e but not in MegaPov 0.4. Both return
"Illegal grid value in dda_traversal()" during trace. Changing the 
rotation of the height fields to something else than 90*x or changing the 
camera position fixes this.

My most recent official version is unable to run (Linux is down). Could 
someone with the latest official version confirm this bug? 

Note that the appearance of hf.gif is not relevant. Just use whatever you
have at hand.

---
#version 3.1;

// lights above plane:
light_source { <1,1,10>, .85 }
light_source { <-1,1,10>, .85 }

// the first camera statement causes the error 
// "Illegal grid value in dda_traversal()" and eventually crashes.
#declare ChrashCam =1;
#if (ChrashCam)
    camera { location  <0,0,-3> look_at 0 }
    plane {y,0 pigment {rgb 0}} 
#else
    plane { y,0.01 pigment {rgb 0}} 
    camera { location  <0.01,0.01,-3> look_at 0 }
#end

//lights below plane:
light_source { <1,-1,-10>, .85 }
light_source { <-1,-1,-10>, .85 }

background { rgb .1 }

#declare Pig= pigment { color rgb <.4,.2,0>}
#declare Rot=90*x;    // <-- changing this to 90.1*x makes it run with ChrashCam=1

// lit from behind:
height_field {  // top left
    gif "hf.gif"
    smooth              //  <-- commenting out this makes it appear black as it should
    translate -.5
    rotate Rot
    pigment {Pig}
    translate <-.6,.6,0>
}
height_field {  // top right
    gif "hf.gif"
    //smooth
    translate -.5
    rotate Rot
    pigment {Pig}
    translate <.6,.6,0>
}

// lit from front:
height_field {  // bottom left
    gif "hf.gif"
    smooth
    translate -.5
    rotate Rot
    pigment {Pig}
    translate <-.6,-.6,0>
}
height_field {  // bottom right
    gif "hf.gif"
    //smooth
    translate -.5
    rotate Rot
    pigment {Pig}
    translate <.6,-.6,0>
}

Post a reply to this message