 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hello,
in my spare time I am part of an international community called LDraw.
We enjoy making computer images of Lego models.
http://www.ldraw.org
It was started by an Australian who wished to share his Lego creations
with friends by e-mail. He developed a data-format, a description of
Lego bricks using primitives (studs, boxes, cylinders, discs and
of course triangles) and made a Pascal program for building and
viewing models.
I discovered the community in 1997, was very enthusiastic because
I have always had an interest in both Lego and computer graphics.
I had tried POV a little, mostly with small geometric scenes to enjoy
the amazingly realistic and accurate renderings.
So I made a small converter program from the LDraw data format to POV,
and could offer the community photorealistic images of their models.
I have always been most keen on the technical aspect (I'm a programmer),
so I experimented a while to find some suitable POV settings for colors
and lights and settled for those.
http://home16.inet.tele.dk/hassing/l3p.html
But the other day I got intrigued by this image:
http://www.nikclark.com/BRAZIL/2002/lego1.jpg
It is made by a "Brazil renderer" in 3ds max.
I find it VERY realistic!
It has focal blurring and the lightsetting is phenomenal.
Perhaps radiosity is used?
And then I thought - it must be possible to do that in POV too!
Having seen so many fantastic POV renderings while surfing.
But how ?
I hope you can give me some good advice on how to obtain
a look similar to the Brazil rendering.
Most important, I think, the lightsetting, but perhaps also the blurring.
If you have the time and if you like,
please have a go with my POV scene of the Ferrari:
http://home16.inet.tele.dk/hassing/ks2556.zip
Best regards from Denmark
Lars C. Hassing
http://home16.inet.tele.dk/hassing/index.html
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Lars C. Hassing" <lar### [at] ofir dk> wrote in message
news:web.3d7018cb838e641f74c8561c0@news.povray.org...
> in my spare time I am part of an international community called LDraw.
> We enjoy making computer images of Lego models.
> http://www.ldraw.org
Remarkable. You have a fine thing going there, a great combination of fun
and work.
I tried your pov file and got it looking a little Brazilesque I think.
Trouble is, I encountered a problem with focal blur. If I use focal_point
nothing happened, but if I left it out entirely not just say <0,0,0> it
blurred seemingly uniformly. Looks like only exagerated AA applied.
Couldn't figure out what I needed to do to get it working right, thought
maybe it was due to the sky -y or the location being vaxis_rotate. Must be
something I'm not doing right but I tried several different focal_points,
the demo scene focalblur.pov is okay.
Here's the rendering I did of it anyway, hopefully I can get it fixed up
better. Again, I really like what you have done at your descriptive web
page. http://webpages.charter.net/omniverse/various/legocarbrazil.jpg
Bob Hughes
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Oh heck. I was so confounded by the mixed up focal blur that I forgot to say
what the setup was. So here is the changed parts:
// near beginning
#ifndef (Color4)
#declare Color4 = #if (version >= 3.1) material { #end texture {
pigment { rgb <0.968627,0.160784,0.054902>*<0.9,1.5,5.0> }
finish { ambient AMB diffuse DIF-0.05 }
#if (QUAL > 1)
finish { phong 0.5 phong_size 40 reflection 0.08 }
#if (BUMPS) normal { BUMPNORMAL } #end
#end
} #if (version >= 3.1) } #end
#end
// near end
// Floor:
object {
plane { y, 19 hollow }
texture {
pigment { color rgb <0.8,0.8,0.8> }
finish { ambient 0.14 diffuse 0.84 }
}
}
global_settings {
radiosity {
error_bound 1
recursion_limit 1
gray_threshold 0.2
brightness 1.7
}
}
// Background:
//background { color rgb <1,1,1>*<0.933,0.967,0.99>}
sphere {-12000*y,12345 pigment {rgb <0.9,0.95,0.99>} finish {ambient 1
diffuse 0}}
// Camera (Latitude,Longitude,Radius = 11,52,-5)
#declare PCT = 5; // Percentage further away
#declare STEREO = 0; // Normal view
//#declare STEREO = degrees(atan2(1,12))/2; // Left view
//#declare STEREO = -degrees(atan2(1,12))/2; // Right view
camera {
location
<835.966,-194.592,-576.74>//vaxis_rotate(<835.966,-194.592,-576.74> +
PCT/100.0*<803.903,-198.3,-628.078>,
// <-159414,-1.04074e+006,124548>,STEREO)
sky -y
right -4/3*x
look_at <32.0636,3.70819,51.3373> // calculated
angle 45
//orthographic
//rotate <0,1e-5,0> // Prevent gap between adjecent quads
blur_samples 70
aperture .025
//focal_point <0,0,-9>
confidence 0.9999
variance 0
}
/*
// Lights:
light_source {
<-28.8756,-815.605,-734.869> // Latitude,Longitude,Radius: 45,0,1039.26
color rgb <1,1,1>
area_light <99,0,0>,<0,0,99>,6,6 adaptive 1 jitter circular orient
fade_distance 500 fade_power 1
}
light_source {
<750.57,-600.367,450.013> // Latitude,Longitude,Radius: 30,120,1039.26
color rgb <1,1,1>
area_light <0,99,0>,<0,0,99>,6,6 adaptive 1 jitter circular orient
fade_distance 500 fade_power 1
}
light_source {
<-478.889,-980.763,259.815> // Latitude,Longitude,Radius: 60,-120,1039.26
color rgb <1,1,1>
area_light <99,0,0>,<0,0,99>,6,6 adaptive 1 jitter circular orient
fade_distance 667 fade_power 1
}
*/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Please add to that:
#declare AMB = 0.15;
#declare DIF = 0.45;
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
I don't have the time to render a focal blurred version right now. Anyway that looks
like post processed FB.
I didn't spend much time in tweaking, actually there was nothing to tweak: I changed
the colors with those ones that I usually use and was satisfied with them.
Sure it could use some work on the colors or finishes choice, but you got the idea:
http://digilander.libero.it/jrgpov/images/ks2556_no_blur.PNG.
Sure, focal blur would add so much to the realism but it's a start, and it's too late
(3:10 am ;-).
BTW, very nice model!
--
Jonathan.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
//So here we go:
#declare AMB = 0;
#declare DIF = 1;
global_settings {
assumed_gamma 1
ambient_light 0
max_trace_level 25
adc_bailout 1/150
radiosity {
pretrace_start 0.08
pretrace_end 0.01
count 300
error_bound 0.1
recursion_limit 1
}
}
sky_sphere {
pigment {
gradient -y //weird sky vector...
color_map {
[0.5 rgb 1.25]
[1 rgb <.5,.7,1>*1.1]
}
}
}
#declare fin =
finish {
ambient 0
diffuse 1
reflection {0.025,.7 falloff 4}
brilliance 1.2
}
#declare Color7 =
material {
texture {
pigment {rgb 0.5}
finish {fin}
}
}
#declare Color4 =
material {
texture {
pigment {rgb .5*x}
finish {fin}
}
}
#declare Color0 =
material {
texture {
pigment {rgb 0.01}
finish {fin}
}
}
#declare Color15 =
material {
texture {
pigment {rgb .8}
finish {fin}
}
}
#declare Color14 =
material {
texture {
pigment {rgb <.8,.81,0>}
finish {fin}
}
}
#declare Color47 =
material {
texture {
pigment {rgb 0.7}
finish {fin}
}
}
#declare Color1 = // I couldn't find this one...
material {
texture {
pigment {rgb 0.8}
finish {fin}
}
}
//Get rid of your lights. We don't need them.
// Change your floor with this one:
object {
plane { y, 19 hollow }
texture {
pigment { color rgb 1 }
finish { ambient 0 diffuse 1 }
}
}
//-----finally if you want to test FB:
camera {
#declare PCT = 5; // Percentage further away
#declare STEREO = 0; // Normal view
//#declare STEREO = degrees(atan2(1,12))/2; // Left view
//#declare STEREO = -degrees(atan2(1,12))/2; // Right view
location vaxis_rotate(<835.966,-194.592,-576.74> +
PCT/100.0*<803.903,-198.3,-628.078>,
<-159414,-1.04074e+006,124548>,STEREO)
sky -y
right -4/3*x
look_at <32.0636,3.70819,51.3373> // calculated
angle 45
rotate <0,1e-5,0> // Prevent gap between adjecent quads
//orthographic
focal_point <150,-50,-150>
aperture 25
blur_samples 70 //good luck
variance 1/1000 //even better: 0.0
}
//hmm did I miss anything?
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Focal blurred version: http://digilander.libero.it/jrgpov/images/ks2556_yes_blur.PNG
--
Jonathan.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
A variation of the overused light dome/light tent setup.
http://luxlab.com/tmp/lego.jpg
_____________
Kari Kivisalo
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Kari Kivisalo" wrote:
>
> A variation of the overused light dome/light tent setup.
> http://luxlab.com/tmp/lego.jpg
Very nice variation on the theme!
Again you have proved that POV-Ray has nothing to envy to Brazil, when it comes to
quality.
--
Jonathan.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"hughes b" <omn### [at] charternet> wrote...
> "Lars C. Hassing" <lar### [at] ofirdk> wrote in message
> news:web.3d7018cb838e641f74c8561c0@news.povray.org...
> > in my spare time I am part of an international community called LDraw.
> > We enjoy making computer images of Lego models.
> > http://www.ldraw.org
>
> Remarkable. You have a fine thing going there, a great combination of fun
> and work.
>
> I tried your pov file and got it looking a little Brazilesque I think.
> Trouble is, I encountered a problem with focal blur. If I use focal_point
> nothing happened, but if I left it out entirely not just say <0,0,0> it
> blurred seemingly uniformly. Looks like only exagerated AA applied.
> Couldn't figure out what I needed to do to get it working right, thought
> maybe it was due to the sky -y or the location being vaxis_rotate. Must be
> something I'm not doing right but I tried several different focal_points,
> the demo scene focalblur.pov is okay.
>
> Here's the rendering I did of it anyway, hopefully I can get it fixed up
> better. Again, I really like what you have done at your descriptive web
> page. http://webpages.charter.net/omniverse/various/legocarbrazil.jpg
>
> Bob Hughes
Hi Bob,
thank you very much for taking the time to experiment with the Ferrari.
I think you got it very Brazilesque.
For convenience I use the LDraw coordinate system in POV too,
so "sky -y" may look strange. See the coordinate system here:
http://home16.inet.tele.dk/hassing/l3p_i/L3GLOBE2.jpg
http://home16.inet.tele.dk/hassing/l3p.html#l3globe
In the CAD program I can read the coordinate of the right
front wheel to <190, -46, -170> which can be used as the focal_point.
(though your settings didn't seems to give much blur...)
/Lars
PS. thanks for the nice comments about my LDraw work.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
