I cannot get POV-Ray to so much as acknowledge the media statement in this scene
file:
___________________________________

global_settings { assumed_gamma 1 }

light_source
{  10000 * z
   rgb 1
   rotate <-45, 135, 0>
}

camera
{  angle 40
   location <0, 1, -10>
   up image_height * y
   right image_width * x
}

sphere { y, 1 pigment { rgb 1 } }

background { rgb 1 }

plane
{  y, 0
   texture { pigment { rgbf 1 } }
   interior
   {  media
      {  absorption rgb <0, 1, 1>
         scattering { 3, rgb 1 }
      }
   }
   hollow
}
___________________________________

The scene renders as if the media statement weren't even there.  The funny thing
is that I've done this sort of thing before, and it always worked.  I'm hoping
that more sets of eyes will spot my obvious mistake.  Thanks!

Post a reply to this message

Wasn't it Cousin Ricky who wrote:
>I cannot get POV-Ray to so much as acknowledge the media statement in 
>this scene

You've got the sphere and the media on the opposite side of the plane, 
so your view of the sphere isn't affected by the media. With those 
settings, you don't see anything if there's only background behind the 
media.

Either move the sphere down into the media
  sphere { -y, 1 pigment { rgb 1 } }
or move the media up around the sphere
  plane { -y, 0

-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message

Mike Williams <nos### [at] econymdemoncouk> wrote:
> You've got the sphere and the media on the opposite side of the plane,
> so your view of the sphere isn't affected by the media.

That wasn't my intention.  Sorry, I should have been clear about that.

> With those
> settings, you don't see anything if there's only background behind the
> media.

Oh.  I need a surface behind the media for it to show up?  I wonder how long it
would have taken for me to figure that out.  *Makes a note to review the
documentation.*

Putting a second plane below the media plane did the trick.  Thank you, much.

Post a reply to this message

Cousin Ricky nous illumina en ce 2008-09-10 14:50 -->
> Mike Williams <nos### [at] econymdemoncouk> wrote:
>> You've got the sphere and the media on the opposite side of the plane,
>> so your view of the sphere isn't affected by the media.
> 
> That wasn't my intention.  Sorry, I should have been clear about that.
> 
>> With those
>> settings, you don't see anything if there's only background behind the
>> media.
> 
> Oh.  I need a surface behind the media for it to show up?  I wonder how long it
> would have taken for me to figure that out.  *Makes a note to review the
> documentation.*
> 
> Putting a second plane below the media plane did the trick.  Thank you, much.
> 
> 
If the ray that enters the media have an "infinite" lenght (reatch the 
background before anything else), you can't eveluate the media. On an infinite 
ray, you can't find the needed sampling points.

-- 
Alain
-------------------------------------------------
  My bologna has a first name.

                    Oscar Mayer

Post a reply to this message