Figure this out...Any clue?

I have the torch mounted on a wall (plane)...looking at it from a
45 degree angle.  With just the torch, and the wall behind it,
the flame is visible.  However...when I put another wall, perpendicular
to the back wall, and back  a ways from the torch (so as to give a
corner type backdrop to the torch lighting), for some unexplicable
reason, the torch stays visible, but the flame vanishes.

I've tested this back and forth.  I remove the corner forming plane, and
the flame reappears.  Put it back...flame disappears.  Can't figure this
out.

And no...the plane is not in between the camera and the flame, otherwise
the torch wouldn't be visible.  it's just the flame that vanishes.

and I checked the light source as well...it's behind the camera, not blocked
out at all by the plane.

Anyone ever seen this behavior before?  Material being affected by objects
around it?  outside of its boundaries?


"Marc Jacquier" <jac### [at] wanadoofr> wrote in message
news:3f78526c@news.povray.org...
>

> 3f77511c@news.povray.org...
> >   That is, you can't use it as texture but you have to use it as media
> > inside a hollow sphere, as in my code.
> >
> Yes, as wrote Warp, the key word is "hollow"
> in the modify tab of your sphere, check the hollow checkbox
>
> Marc
>
>

Post a reply to this message

Try this also:

#macro FireMap(Type)
 #local Inverse = 0;
 #switch (Type)
  #case (1) // Brightest flames, bright red to pale yellow
   #if ( Inverse )
    color_map {
     [ 0.0 rgb <0.0, 0.0, 0.0> ]
     [ 0.2 rgb <0.0, 0.0, 0.0> ]
     [ 0.2 rgb <0.0, 0.6, 0.6> ]
     [ 0.6 rgb <0.0, 0.4, 0.8> ]
     [ 1.0 rgb <0.0, 0.0, 0.5> ]
    }
   #else
    color_map {
     [ 0.0 rgb <0.0, 0.0, 0.0> ]
     [ 0.2 rgb <0.0, 0.0, 0.0> ]
     [ 0.2 rgb <1.0, 0.4, 0.4> ]
     [ 0.6 rgb <1.0, 0.6, 0.2> ]
     [ 1.0 rgb <1.0, 1.0, 0.5> ]
    }
   #end
  #break
  #case (2) // Slightly dimmer, with more red
   #if ( Inverse )
    color_map {
     [ 0.35 rgb <0.0, 0.0, 0.0> ]
     [ 0.40 rgb <0.0, 0.6, 0.6> ]
     [ 0.50 rgb <0.0, 0.6, 0.6> ]
     [ 0.65 rgb <0.1, 0.1, 1.0> ]
     [ 0.75 rgb <0.1, 0.1, 1.0> ]
     [ 0.80 rgb <0.0, 0.0, 0.8> ]
    }
   #else
    color_map {
     [ 0.35 rgb <0.0, 0.0, 0.0> ]
     [ 0.40 rgb <1.0, 0.0, 0.0> ]
     [ 0.50 rgb <1.0, 0.0, 0.0> ]
     [ 0.65 rgb <1.0, 1.0, 0.0> ]
     [ 0.75 rgb <1.0, 1.0, 0.0> ]
     [ 0.80 rgb <1.0, 1.0, 0.5> ]
    }
   #end
  #break
  #case (3) // Medium flames with red and orange
   #if ( Inverse )
    color_map {
     [ 0.25 rgb <0.0, 0.0, 0.0> ]
     [ 0.25 rgb <0.0, 0.5, 1.0> ]
     [ 0.50 rgb <0.0, 0.5, 1.0> ]
     [ 0.75 rgb <0.0, 0.3, 0.6> ]
    }
   #else
    color_map {
     [ 0.25 rgb <0.0, 0.0, 0.0> ]
     [ 0.25 rgb <0.8, 0.0, 0.1> ]
     [ 0.50 rgb <0.8, 0.0, 0.1> ]
     [ 0.75 rgb <1.0, 0.5, 0.0> ]
    }
   #end
  #break
  #case (4) // Mostly red with violet/orange mix
   #if ( Inverse )
    color_map {
     [ 0.00 rgb <0.0, 0.0, 0.0> ]
     [ 0.35 rgb <0.7, 0.3, 1.0> ]
     [ 0.65 rgb <0.7, 1.0, 0.3> ]
     [ 1.00 rgb <0.0, 1.0, 1.0> ]
    }
   #else
    color_map {
     [ 0.00 rgb <0.0, 0.0, 0.0> ]
     [ 0.35 rgb <0.3, 0.7, 0.0> ]
     [ 0.65 rgb <0.3, 0.0, 0.7> ]
     [ 1.00 rgb <1.0, 0.0, 0.0> ]
    }
   #end
  #break
  #case (5) // Dark red/orange embers
   #if ( Inverse )
    color_map {
     [ 0.0 rgb <0.0, 0.0, 0.0> ]
     [ 0.3 rgb <0.0, 0.0, 0.0> ]
     [ 0.3 rgb <0.0, 0.7, 0.7> ]
     [ 1.0 rgb <0.4, 0.8, 0.6> ]
    }
   #else
    color_map {
     [ 0.0 rgb <0.0, 0.0, 0.0> ]
     [ 0.3 rgb <0.0, 0.0, 0.0> ]
     [ 0.3 rgb <0.2, 0.1, 0.1> ]
     [ 1.0 rgb <0.4, 0.1, 0.2> ]
    }
   #end
  #break
 #end
#end

#macro Fire( Type, Size )
 interior {
  //ior 1.1
  media {
   emission 0.6
   method 3
   samples 5, 20
   intervals 1
   variance 1/1000
   confidence .995
   density {
    spherical
    turbulence 1.50
    omega 0.7
    lambda 1.7
    FireMap(Type)
    scale Size*0.5
   }
  }
 }
#end

#declare cFlame = sphere {
 y, 1
 scale <.8, 3, .8>
 pigment { rgbt 1 }
 hollow
 no_shadow
 Fire( 2, <1.5, 4, 1.5> )
}

Feel free to play with the color maps if you want.  I keep the inverse
option for when I need to make a negative image later.

Post a reply to this message

-s0da- <ske### [at] msncom> wrote:
> And no...the plane is not in between the camera and the flame, otherwise
> the torch wouldn't be visible.  it's just the flame that vanishes.

  The flame (and the camera) are probably inside the wall.
  Try inverting the wall (ie putting its normal to point to the opposite
direction, to the side where the fire is).

  Another solution is to make the wall "hollow", but I wouldn't recommend
that because it's conceptually the wrong solution (why would you want
your scene inside the plane when it clearly should be outside?).

-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message

In article <3f78699c@news.povray.org>, "-s0da-" <ske### [at] msncom> 
wrote:

> I have the torch mounted on a wall (plane)...looking at it from a
> 45 degree angle.  With just the torch, and the wall behind it,
> the flame is visible.  However...when I put another wall, perpendicular
> to the back wall, and back  a ways from the torch (so as to give a
> corner type backdrop to the torch lighting), for some unexplicable
> reason, the torch stays visible, but the flame vanishes.

Chances are, the plane is facing the wrong way. The camera and torch are 
inside it, and because it isn't hollow, there's no media in it. I bet 
you get a warning message, something like "camera in non-hollow object".

-- 
Christopher James Huff <cja### [at] earthlinknet>
http://home.earthlink.net/~cjameshuff/
POV-Ray TAG: chr### [at] tagpovrayorg
http://tag.povray.org/

Post a reply to this message

Bet that's it. DAMN, why didn't I think of that.

DOH!

hahahaha

thanks for you help!

"Christopher James Huff" <cja### [at] earthlinknet> wrote in message
news:cja### [at] netplexaussieorg...
> In article <3f78699c@news.povray.org>, "-s0da-" <ske### [at] msncom>
> wrote:
>
> > I have the torch mounted on a wall (plane)...looking at it from a
> > 45 degree angle.  With just the torch, and the wall behind it,
> > the flame is visible.  However...when I put another wall, perpendicular
> > to the back wall, and back  a ways from the torch (so as to give a
> > corner type backdrop to the torch lighting), for some unexplicable
> > reason, the torch stays visible, but the flame vanishes.
>
> Chances are, the plane is facing the wrong way. The camera and torch are
> inside it, and because it isn't hollow, there's no media in it. I bet
> you get a warning message, something like "camera in non-hollow object".
>
> -- 
> Christopher James Huff <cja### [at] earthlinknet>
> http://home.earthlink.net/~cjameshuff/
> POV-Ray TAG: chr### [at] tagpovrayorg
> http://tag.povray.org/

Post a reply to this message