When I use a stone texture and change the diffuse value, only one
element of the texture is changed:


#include "colors.inc"
#include "stones.inc"
camera{location z*-2}
light_source{z*-2 rgb 1}

plane
   {
   z, 0
   texture
      {
      T_Stone25
      }
   finish
      {
      diffuse 2
      }
   }


Why isn't the whole texture changed? What can I do to change the
diffuse value of the whole texture?
I use POV-Ray 3.5.

Felix Wiemann

Post a reply to this message

>Why isn't the whole texture changed? What can I do to change the
>diffuse value of the whole texture?
>I use POV-Ray 3.5.

plane {
  z, 0
  texture {
    T_Stone25
    diffuse 2
  }
}


Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] vipbg
TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message

Huh?  That's not logic!


Hugo


> plane {
>   z, 0
>   texture {
>     T_Stone25
>     diffuse 2
>   }
> }

Post a reply to this message

Felix Wiemann <Fel### [at] gmxnet> wrote:
:    texture
:       {
:       T_Stone25
:       }
:    finish
:       {
:       diffuse 2
:       }

  AFAIK this is actually a layered texture. You are not modifying the first
texture, but you are creating another texture on top of it.
  The effect you describe is strange, though.

-- 
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}//  - Warp -

Post a reply to this message

In article <3c55354b$1@news.povray.org>,
 "Felix Wiemann" <Fel### [at] gmxnet> wrote:

> Why isn't the whole texture changed? What can I do to change the
> diffuse value of the whole texture?
> I use POV-Ray 3.5.

What you are doing is creating another texture layer with the default 
texture used for everything but the diffuse. You want:
plane {z, 0
    texture {
        T_Stone25
        finish {
            diffuse 2
        }
    }
}

BTW, it also greatly helps readability if you neatly indent the code, 
indenting inner blocks more than their containing blocks, and it helps 
avoid this sort of problem later on. You don't necessarily have to do it 
the way I did it, just be consistent and use *some* indentation.

-- 
 -- 
Christopher James Huff <chr### [at] maccom>

Post a reply to this message

> What you are doing is creating another texture layer with the default
> texture used for everything but the diffuse. You want:
> plane {z, 0
>     texture {
>         T_Stone25
>         finish {
>             diffuse 2
>         }
>     }
> }

That doesn't work. It's still only one element with higher diffuse. I
wonder about that, too.

> BTW, it also greatly helps readability if you neatly indent the code,
> indenting inner blocks more than their containing blocks, and it
helps
> avoid this sort of problem later on. You don't necessarily have to do
it
> the way I did it, just be consistent and use *some* indentation.

I've tried so. Let me explain my indent "system":
1 (object or object modifier like union, pigment, plane, ...)
2       {
3       (some code)
4       }
(some code) can contain an object or object modifier.
It's better visible in an editor. I think it's a quite logical system.
But what do you suggest should I change?

Felix Wiemann

Post a reply to this message

Felix Wiemann wrote:
> 
> > What you are doing is creating another texture layer with the default
> > texture used for everything but the diffuse. You want:
> > plane {z, 0
> >     texture {
> >         T_Stone25
> >         finish {
> >             diffuse 2
> >         }
> >     }
> > }
> 
> That doesn't work. It's still only one element with higher diffuse. I
> wonder about that, too.

That's totally normal.
Check T_Stone25 definition....

It is a layered textured. so applying modifiers only works for one, not all of
them.

Solution for your problem : inline T_Stone25 and put the relevant finish
modifiers!

-- 
Non Sine Numine
http://grimbert.cjb.net/

Post a reply to this message

<jer### [at] atosorigincom> wrote:
> Solution for your problem : inline T_Stone25 and put the relevant finish
> modifiers!

There can be also some persons which don't want open, search, copy, close long
way (also becouse of respect to authors of code). For such persons there is
still workaround.

// START
#include "colors.inc"

camera{location z*-2}
light_source{z*-2 rgb 1}

#default{finish{diffuse 2}}
#include "stones.inc"

plane{
  z, 0
  texture{T_Stone25}
}

#default{finish{diffuse .6}} // default according to documentation
#include "stones.inc"

/* rest of scene */

// END

ABX

Post a reply to this message

> There can be also some persons which don't want open, search, copy, close long
> way (also becouse of respect to authors of code). For such persons there is
> still workaround.

Unless one also want an Unmodified T_Stone_27

Or already add loaded "stones.inc", may be due to another include...

So beware of that solution.
- 
Non Sine Numine
http://grimbert.cjb.net/

Post a reply to this message

<jer### [at] atosorigincom> wrote:
> > There can be also some persons which don't want open, search, copy, close long
> > way (also becouse of respect to authors of code). For such persons there is
> > still workaround.
>
> Unless one also want an Unmodified T_Stone_27

Have you checked my solution ? It leaves T_Stone_27 unmodified

> So beware of that solution.

But of course there are some danger situations. Mainly when other default are
changed somewhere.

ABX

Post a reply to this message