 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 20.07.2016 um 18:02 schrieb Stephen:
> Besides using an image map. You can add a normal map to give some depth
> and a spectacular map for the seas. You can find some here
> http://planetpixelemporium.com/earth.html
You mean specular, right? ;)
> The atmosphere is always tricky to do and I generally cheat and use a
> cone behind the planet in line with the camera.
I find atmosphere comparatively easy -- as long as I don't try to add
clouds.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 7/20/2016 5:27 PM, clipka wrote:
> Am 20.07.2016 um 18:02 schrieb Stephen:
>
>> Besides using an image map. You can add a normal map to give some depth
>> and a spectacular map for the seas. You can find some here
>> http://planetpixelemporium.com/earth.html
>
> You mean specular, right? ;)
>
Who rattled your cage? :P
>> The atmosphere is always tricky to do and I generally cheat and use a
>> cone behind the planet in line with the camera.
>
> I find atmosphere comparatively easy --
Yes you do, don't you. :(
> as long as I don't try to add
> clouds.
>
Clouds are problematic especially in an animation. The simplest way
would be to use an image map.
--
Regards
Stephen
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Mr. clipka,
Thank you for your detailed and useful advice.
Here's the new code I rewrote:
// sunlight
light_source {
<100, 0, 40>
color White*100
parallel
fade_distance 10
fade_power 2
point_at <0, 0, 0>
}
// Earth
sphere {
<0, 0, 0>, 3.5
texture {
pigment {
image_map {
jpeg "textures/earth.jpg"
map_type 1
}
}
finish {
emission 0.001
diffuse 0.5
}
rotate y*-135
rotate x*35
}
// rotation
rotate <0, 360*clock, 0>
}
// Earth clouds
difference {
sphere { <0, 0, 0>, 3.51 }
sphere { <0, 0, 0>, 3.5 }
material {
texture {
pigment {
image_map{
png "textures/earth_cloud.png"
map_type 1
}
}
}
}
hollow on
}
// Earth scattering
difference {
sphere { <0, 0, 0>, 3.54 }
sphere { <0, 0, 0>, 3.5 }
material {
texture{
pigment { rgbt 1 }
}
interior {
media {
scattering {
5
color White
eccentricity 0.56
}
density {
spherical density_map {
[ 0.0 rgb 0.0 ]
[ 0.5294*0.25e-6 rgb <0.02, 0.05, 0.2>*0.07 ]
[ 0.5294*0.4e-6 rgb <0.02, 0.07, 0.3>*0.32 ]
[ 0.5294*0.5e-6 rgb <0.08, 0.18, 0.4>*0.5 ]
[ 0.5412*0.6e-6 rgb <0.08, 0.18, 0.4>*0.9 ]
[ 0.5471*0.65e-6 rgb <0.08, 0.18, 0.4>*1.5 ]
[ 0.5471*0.675e-6 rgb <0.08, 0.18, 0.4>*4.5 ]
[ 0.5471*0.71e-6 rgb <0.08, 0.18, 0.4>*12 ]
}
scale 3.54
}
}
}
}
hollow on
}
And here I attach the brand new rendered image, with clouds added on the
surface.
Thank you very much for your advice.
Post a reply to this message
Attachments:
Download 'earth.png' (663 KB)
Preview of image 'earth.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 20.07.2016 um 19:06 schrieb Stephen:
> On 7/20/2016 5:27 PM, clipka wrote:
>> Am 20.07.2016 um 18:02 schrieb Stephen:
>>
>>> Besides using an image map. You can add a normal map to give some depth
>>> and a spectacular map for the seas. You can find some here
>>> http://planetpixelemporium.com/earth.html
>>
>> You mean specular, right? ;)
>>
>
> Who rattled your cage? :P
OOoooh -- careful! This Code Monkey could accidently type a few lines of
code that make POV-Ray crash specifically on /your/ computer. So stop
talking, human, and hand over the bananas! ;)
>>> The atmosphere is always tricky to do and I generally cheat and use a
>>> cone behind the planet in line with the camera.
>>
>> I find atmosphere comparatively easy --
>
> Yes you do, don't you. :(
>
>> as long as I don't try to add
>> clouds.
>>
>
> Clouds are problematic especially in an animation. The simplest way
> would be to use an image map.
Tried that, and found it looking unconvincing. The best thing I've
managed to come up with so far was a combination of an image map and a
spherical function to create media with a cloud-ish density distribution.
It would be cool if we had a set of cloud image maps epresenting cloud
densities at different altitudes, but I guess such a thing doesn't exist
(yet).
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 20/07/16 18:09, Kuangy wrote:
> Mr. clipka,
>
> Thank you for your detailed and useful advice.
> Here's the new code I rewrote:
>
<snip>
>
> And here I attach the brand new rendered image, with clouds added on the
> surface.
> Thank you very much for your advice.
>
Looking good, Kuangy. If you intend to use this as an animation, don't
forget to rotate the clouds (possibly at a slightly different rate to
the earth).
John
--
It's not about bravery.
It's about doing what I need to do to win
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 20.07.2016 um 19:09 schrieb Kuangy:
> And here I attach the brand new rendered image, with clouds added on the
> surface.
Hey, wow -- that actually looks really good.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Doctor John <j.g### [at] gmail com> wrote:
> If you intend to use this as an animation, don't
> forget to rotate the clouds (possibly at a slightly different rate to
> the earth).
And spin Earth west to east, note the "-" for that: rotate -360*clock
Unless there's another reason to have the atmosphere not show below Earth's
surface you won't need to use CSG difference, a single sphere alone will be
okay.
I think the answers given already have helped solve the problem.
Texture finish was trouble, as said, and scaling can be done other ways. I would
have began with a sphere {0,1 and then scaled them after image map and media.
Just be aware that media scaled after applied can change the affect,
historically anyway:
sphere {0,1 ... media { ... scale 0.5} scale 10}
Unfortunately I haven't kept up with that subject, I have not done much in
recent years, so please excuse me if media now retains original qualities when
scaling it's containing objects. Maybe it still scales (thickness or thinness).
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 7/20/2016 6:18 PM, clipka wrote:
> Am 20.07.2016 um 19:06 schrieb Stephen:
>
> OOoooh -- careful! This Code Monkey could accidently type a few lines of
> code that make POV-Ray crash specifically on /your/ computer. So stop
> talking, human, and hand over the bananas! ;)
>
Interesting that you say that.
When I was working at Taronga Zoo, in Sydney. The keepers in the Monkey
house used bananas as part of their alarm system. Every night they put a
banana beside a window. If in the morning the banana was gone. Then the
monkeys had gotten off of the inner enclosure.
>>
>> Clouds are problematic especially in an animation. The simplest way
>> would be to use an image map.
>
> Tried that, and found it looking unconvincing. The best thing I've
> managed to come up with so far was a combination of an image map and a
> spherical function to create media with a cloud-ish density distribution.
>
> It would be cool if we had a set of cloud image maps epresenting cloud
> densities at different altitudes, but I guess such a thing doesn't exist
> (yet).
>
The big problem that I come up against is that All of these types of
animations are cyclic and our weather system does show the same behaviour.
--
Regards
Stephen
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> I'm now working hard on my assignment for my CG class at college, in which I'm
> trying to make a realistic earth animation.
> I used "difference" to create something like atmosphere right outside earth, and
> in which I also used emission for making the atmosphere glow. And this is where
> I'm facing a problem.
>
> When I set a light_source from a distance, there is no shadow cast on earth.
> Here I paste the source code:
>
> light_source {
> <100, 0, 50>
> color White
> spotlight
> fade_distance 100
> fade_power 10
> point_at <0, 0, 0>
> }
Why use a spotlight?
Why use fading?
Given the distance from the Sun to the Earth, you are better using a
parallel light without any fading. Think about it, the Sun-Earth
distance is over 10000000 times the Earth's radius.
The difference in the illumination over the moon's orbit 's diameter is
effectively negligible.
fade_power ONLY realistic value is 2.
fade_sidtance should be about the appearent diameter of a light's diameter.
If the light becomes to dark, you can increase it's intensity
arbitrarily by as much as you need.
Try this one:
light_source{<100, 0, 50>*10 rgb 2 parallel}
>
> // earth
> sphere {
> <0, 0, 0>, 3.5
> texture {
> pigment {
> image_map {
> jpeg "textures/earth.jpg"
> map_type 1
> }
> scale 3.5
This scalling is useless.
> }
>
> finish {
> ambient 1
> diffuse 3
Beter use ambient 0, diffuse 0.6 here.
ambient 1 mean that your earth is actualy glowing.
diffuse 3 mean that it give off 3 times as much light as it receive from
the Sun.
> }
>
> rotate y*-135
> rotate x*35
> }
> // rotation
> rotate <0, 360*clock, 0>
> }
>
> // atmosphere emission
> difference {
> sphere { <0, 0, 0>, 3.54 }
> sphere { <0, 0, 0>, 3.0 }
>
> material {
> texture{
> pigment { rgbt 1 }
> }
>
> interior {
> media {
> emission 0.5
A GLOWING atmosphere? Last time I checked, Earth's atmosphere scatters
the light and don't emit any.
> //scattering { 5 color rgb 0.01 eccentricity 0.56 }
The proper model is scattering{4 rgb 0.01}
> density {
> spherical density_map {
> [ 0.0 rgb 0.0 ]
> [ 0.5294*0.25e-6 rgb <0.02, 0.05, 0.2>*0.07 ]
> [ 0.5294*0.4e-6 rgb <0.02, 0.07, 0.3>*0.32 ]
> [ 0.5294*0.5e-6 rgb <0.08, 0.18, 0.4>*0.5 ]
> [ 0.5412*0.6e-6 rgb <0.08, 0.18, 0.4>*0.9 ]
> [ 0.5471*0.65e-6 rgb <0.08, 0.18, 0.4>*1.5 ]
> [ 0.5471*0.675e-6 rgb <0.08, 0.18, 0.4>*4.5 ]
> [ 0.5471*0.71e-6 rgb <0.08, 0.18, 0.4>*12 ]
> }
> scale 100
> }
> }
> }
> }
>
> hollow on
> }
>
> And below I attach the rendered result for now.
>
> How can I solve this problem? I'd appreciate it if someone could help.
> I'm not a native English speaker, so I'm very sorry for my poor English... I
> really wish I didn't use impolite expressions!
>
> Thanks.
>
Alain
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Alain <kua### [at] videotronca> wrote:
> Think about it, the Sun-Earth
> distance is over 10000000 times the Earth's radius.
I get 23481 times, a far cry from 10 million.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
