Because the previous thread has become so large, it is hard to keep an
overview. Thus I am starting now this thread as part 2 of that
remarkable thread.

THE PROJECT

To develop a scene where tall futuristic skyscrapers rise above cloud
level, not necessarily on Earth.

PUBLIC DOMAIN

Such scenes can be very beautiful. My original intention was to make
this scene public domain, allowing everyone to use it. But the scene
received so much valuable input of so many members of our great
community that I feel I need to ask everyone who helped for their
permission - a lot of source code was submitted by so many members.

I can even imagine, each POV-Ray community member with interest in this
project can design the interior of his/her own flying home (a flattened
bubble with a diameter of 20 meters) and submit it to this thread as
self-sustaining INCLUDE file. Those home bubbles hover above or below
the clouds or can land or even swim on the water, or they are anchored
in large swarms along the futuristic skyscrapers). The bubble design
will at one point be submitted by me into this thread or an own thread
for you to use. Basically, it has one round floor and a transparent
wall/roof. Only the bottom is non-transparent, it hosts the antigrav
modules in a ring along the lower bubble inside. The center of the
bubble has one lowered floor and one raised floor. On three sides, the
bubble will have docking mechanisms for towers or other bubbles.

WHERE WE ARE NOW

The basic scene layout is there: a layer of clouds, two suns, even a gas
planet.
1
At the moment, there is a big problem to set the colors correctly for
this scene, as each color change causes many other colors to change
unpredictably, too. This need to be fixed, then everyone using this
scene can easily use the own colors of desire.
2
The two suns don't look like suns but just like luminescent discs. No
glow, and their colors are not correct, too: the large sun should be dim
red, and the small sun should be white-glowing blue, each having a glow
around them.
3
The illumination doesn't come from these two suns, but from a
traditional light_source. making it come from these two suns, and using
their own light color, would be more authentic.
4
The large gas planet needs some overhaul, but that is a fairly easy task
I can do on my own. Priority for that, however, is low at this moment
(as I can solve that at any given time by myself).




---------------------------------------

#version 3.8;

#declare MyRadiosity = on;

global_settings
{
 assumed_gamma 1.4
 #if(MyRadiosity=on)
  radiosity { media on }
 #end
}

#default
{
 finish { ambient 0.0 diffuse 1.0 }
}

//------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
//------------------------------------------------------------------------

camera
{
 /*ultra_wide_angle*/ //angle 20
 location  < -35.0 , 11.0 , 0.0 >
 //right     x*image_width/image_height // not needed for v3.8
 look_at   < 0.0 , 5.0 , 0.0 >
}

// sun
-------------------------------------------------------------------

light_source
{
 -z*9999.0//< 50, 100, -250 >*10e4
 color 1.0 * 1.3//< 1.0,  0.62353,  0.46667 >*2
 rotate < 20.0, 240.0, 0.0 > // altitude, azimuth, tilt
}

// sky -------------------------------------------------------------------
background { color rgb 0.0 }

disc
{
 0.0, y, 1.0, 0.0
 hollow on
 no_shadow
 pigment { rgb < 0.5, 0.75, 1.0 > }
 scale 100.0
 translate y*100.0
}

// ground -----------------------------------------------------------------

box
{
 < -1.0, -1.0, -1.0 > < 1.0, 1.0, 1.0 >
 pigment { color rgb 1.0 }
 scale < 555.0, 497.0, 555.0 >
 translate -y*494.0
}

//--------------------------------------------------------------------------
// Clouds
#local Scale = 5.0;

#declare Clouds = density
{
 ripples   // controls the cloud formation
 color_map
 {
  [ 0.33 rgb  10.0 ]
  [ 0.67 rgb 100.0 ]
 }
 scale < 3.0, 1.0, 10.0 >*0.5
 warp { turbulence < 2.5, 1.0, 1.6 > }
 rotate 45.0*y
}

//cloud layer:
box
{
 < -1.0, -1.0, -1.0 > < 1.0, 1.0, 1.0 >
 pigment { rgbt 1.0 }
 hollow
 interior
 {
  media
  {
   samples 20
   absorption < 3.0, 4.0, 0.5 >*1.0/(Scale*100.0)
   emission   < 1.0, 1.0, 1.0 >*0.5/(Scale*100.0)
   scattering
   {
    1
    < 0.5, 0.75, 1.5 >*3.0/(Scale*100.0)
    extinction 0.5
   }
   density
   {
    boxed
    density_map
    {
     [ 0.000 rgb 0.0 ]
     [ 0.001 Clouds scale 1.0/100.0 ]
    }
   }
  }
 }
 scale Scale*100.0
 translate -y*494.0
}

//-------------------------------------------------------------
//atmosphere:
sphere
{
 < 0.0, 0.0, 0.0 >, 1.0
 pigment { rgbt 1.0 }
 hollow
 interior
 {
  media
  {
   samples 20
   absorption 0.5
   scattering
   {
    5
    < 1.25, 1.0, 1.5 >*2.0/Scale
    extinction 0.67
    eccentricity 0.2
   }
   density
   {
    gradient y
    color_map
    {
/*
     [ 0.00 rgb 1.0 ]  //base ground fog
     [ 0.10 rgb < 9.0, 0.3, 0.10 > ]  //top ground fog
     [ 0.30 rgb < 0.9, 0.3, 0.10 > ]  //top ground fog
     [ 0.50 rgb < 0.5, 0.1, 0.09 >*0.100 ] //base atmospheric haze
     [ 0.67 rgb < 0.1, 0.2, 0.90 >*0.100 ] //top atmospheric haze
     [ 1.00 rgb < 0.1, 0.3, 0.90 >*0.001 ] //top atmospheric haze
*/
     [ 0.00 rgb < 1.0, 1.0, 1.00 >*1.000 ] //base ground fog
     [ 0.10 rgb < 3.0, 0.3, 0.10 >*1.000 ] //top ground fog
     [ 0.30 rgb < 0.3, 0.3, 0.10 >*1.000 ] //top ground fog
     [ 0.50 rgb < 0.5, 0.1, 0.09 >*0.100 ] //base atmospheric haze
     [ 0.67 rgb < 0.3, 0.7, 1.00 >*0.100 ] //top atmospheric haze
     [ 1.00 rgb < 0.3, 0.7, 1.00 >*0.001 ] //top atmospheric haze
    }
    rotate -x*15.0
    warp { spherical }
    scale Scale*2.0*y
   }
  }
 }
 scale Scale*111.0
 translate -y*535.0
}


//-------------------------------------------------------------
// Planet:

union
{
 sphere
 {
  < 0.0, 0.0, 0.0 > 7.0
  pigment
  {
   gradient y
   color_map
   {
    [ 0.00 rgb < 1.0, 1.0, 1.0 >*0.05 ]
    [ 0.10 rgb < 1.0, 1.0, 1.0 >*0.05 ]
    [ 0.12 rgb < 1.0, 1.0, 1.0 >*0.05 ]
    [ 0.15 rgb < 0.80392, 0.66275, 0.47059 >*0.05 ]
    [ 0.20 rgb < 0.80392, 0.66275, 0.47059 >*0.05 ]
    [ 0.22 rgb < 0.63922, 0.55686, 0.31373 >*0.05 ]
    [ 0.27 rgb < 0.63922, 0.55686, 0.31373 >*0.05 ]
    [ 0.40 rgb < 0.47451, 0.30980, 0.14118 >*0.05 ]
    [ 0.43 rgb < 0.47451, 0.30980, 0.14118 >*0.05 ]
    [ 0.45 rgb < 0.20392, 0.24314, 0.41176 >*0.05 ]
    [ 0.55 rgb < 0.20392, 0.24314, 0.41176 >*0.05 ]
    [ 0.57 rgb < 0.47451, 0.30980, 0.14118 >*0.05 ]
    [ 0.60 rgb < 0.47451, 0.30980, 0.14118 >*0.05 ]
    [ 0.73 rgb < 0.63922, 0.55686, 0.31373 >*0.05 ]
    [ 0.78 rgb < 0.63922, 0.55686, 0.31373 >*0.05 ]
    [ 0.80 rgb < 0.80392, 0.66275, 0.47059 >*0.05 ]
    [ 0.85 rgb < 0.80392, 0.66275, 0.47059 >*0.05 ]
    [ 0.88 rgb < 1.0, 1.0, 1.0 >*0.05 ]
    [ 0.90 rgb < 1.0, 1.0, 1.0 >*0.05 ]
    [ 1.00 rgb < 1.0, 1.0, 1.0 >*0.05 ]
   }
   turbulence 0.3
   translate < 0.0, -7.0, 0.0 >
   scale 14.0
  }
 }
 difference
 {
  cylinder { < 0.0, -0.00001, 0.0 > < 0.0, 0.00001, 0.0 > 16.0 }
  cylinder { < 0.0, -0.00002, 0.0 > < 0.0, 0.00002, 0.0 > 10.0 }
  pigment
  {
   onion
   color_map
   {
    [ 0.00 rgbt < 0.47451, 0.30980, 0.14118, 0.7 > ]
    [ 0.60 rgbt < 0.47451, 0.30980, 0.14118, 0.7 > ]
    [ 0.62 rgbt < 0.47451, 0.30980, 0.14118, 0.7 > ]
    [ 0.63 rgbt < 0.80392, 0.66275, 0.47059, 0.7 > ]
    [ 0.66 rgbt < 0.80392, 0.66275, 0.47059, 0.7 > ]
    [ 0.67 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 0.71 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 0.73 rgbt < 0.47451, 0.30980, 0.14118, 0.7 > ]
    [ 0.76 rgbt < 0.47451, 0.30980, 0.14118, 0.7 > ]
    [ 0.80 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 0.81 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 0.82 rgbt < 0.47451, 0.30980, 0.14118, 0.7 > ]
    [ 0.83 rgbt < 0.47451, 0.30980, 0.14118, 0.7 > ]
    [ 0.86 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 0.88 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 0.89 rgbt < 0.80392, 0.66275, 0.47059, 0.7 > ]
    [ 0.91 rgbt < 0.80392, 0.66275, 0.47059, 0.7 > ]
    [ 0.97 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 0.99 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
    [ 1.00 rgbt < 0.63922, 0.55686, 0.31373, 0.7 > ]
   }
   scale 16.0
  }
  finish { emission 0.1 }
 }
 scale 250.0
 rotate < -10.0, -20.0, 50.0 >
 translate < 160.0, 50.0, -100.0 >*33.0
}

// Big Sun
#declare SunLarge = union
{
 sphere
 {
  < 0.0, 0.0, 0.0 > 1.0
  pigment
  {
   gradient y
   color_map
   {
    [ 0.00 rgb < 0.0, 0.0, 0.0 > ]
    [ 0.50 rgb < 1.5, 0.0, 0.1 > ]
    [ 1.00 rgb < 3.0, 0.0, 0.1 >*5.0 ]
   }
   translate < 0.0, -0.5, 0.0 >
   scale 2.0
  }
  finish { emission 1.0 }
  scale 12.0
 }
 scale 66.0
 translate < 160.0, 0.0, 78.0 >*33.0
}

// Small Sun
#declare SunSmall = union
{
 sphere
 {
  < 0.0, 0.0, 0.0 > 1.0
  pigment { color rgb < 0.23529,  0.11373,  0.46275 >*1.0 }
  finish { emission 0.0 }
 }
 scale 66.0
 translate < 160.0, 25.0, 112.0 >*33.0
}

object { SunLarge }
object { SunSmall }


//-------------------------------------------------------------
//artefact:
#local S=seed(4132);
union
{
 #for (It,1.0,8.0,1.0)

  #local xR=rand(S);
  #local yR=rand(S);
  #local zR=rand(S);

  #local xR2=rand(S);
  #local yR2=rand(S);
  #local zR2=rand(S);

  box
  {
   0.0, 1.0
   scale < 1.0+xR, 8.0+yR*4, 1.0+zR >/2.0
   pigment
   {
    checker
    color rgb 0.1 color rgb 0.9 scale 0.5
   }
   translate (-< xR*20.0,0.0,zR*20.0 > + <xR2*40.0, 0.0, zR2*40.0 >)/2.0
  }
 #end
 rotate y*90.0
 translate < -20.0, 2.0, 5.0 >
}


---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com

Post a reply to this message

Attachments:
Download 'sl - cloud cities.jpg' (86 KB)

Preview of image 'sl - cloud cities.jpg'

Sven Littkowski <I### [at] SvenLittkowskiname> wrote:
> THE PROJECT
>
> To develop a scene where tall futuristic skyscrapers rise above cloud
> level, not necessarily on Earth.
>
> PUBLIC DOMAIN
>
> I can even imagine, each POV-Ray community member with interest in this
> project can design the interior of his/her own flying home (a flattened
> bubble with a diameter of 20 meters) and submit it to this thread as
> self-sustaining INCLUDE file.

I think anyone offering help considers their SDL freely given, only nice to
mention if you feel the need. If I'm wrong maybe we will hear differently.

Ambitious goal, not sure I could do more but it has potential.

There could be inherent problems with the realism aspect of the suns and
atmosphere. I know some people have attempted it in the past with some good
results, but I don't remember how simple time of day or motion changes affected
them. A scene can become unexpectedly different due to even slight changes of
camera/light/objects.
I think of POV-Ray as not being a reality simulator, more of a simulation of
reality. If that makes sense.

I suppose a good enough facsimile should be possible anyhow, sun orb auras and
all. Once the formulation is found anyway. If the idea is to forego any tricks,
such as halo disc objects, in lieu of pure 'media' it might prove difficult as
you've no doubt seen already.

Bob

Post a reply to this message

This is really impressive. The choice of using lighting at dusk (or dawn?)
instead of 'mid-day' makes the entire scene look magical. The same goes for the
very nice hazy cloud effect.

Thanks for posting your code. I've been playing around with it, and made an
area_light to replace your point light... which makes the scene even SLOWER to
render, of course, but I noticed that your test-building on the left was casting
too 'sharp' of a shadow through the foggy atmosphere, compared to the size of
the large Sun. (I only noticed the sharpness re: that one building, so *maybe*
the area light could be assigned to *just* that building, in a light_group, to
save rendering time. I haven't tried that yet, though.) Anyway, here's the
light...

light_source
{
-z*9999.0//< 50, 100, -250 >*10e4
  color 1.3//< 1.0,  0.62353,  0.46667 >*2
  area_light
 <450, 0, 0> <0, 0, 450>
  6, 6                // total number of lights in grid (4x*4z = 16 lights)
  adaptive 1          // 0,1,2,3...
  // area_illumination on
  jitter              // adds random softening of light
  circular            // make the shape of the light circular
  orient              // orient light
  rotate < 20.0, 240.0, 0.0 > // altitude, azimuth, tilt
}

Sven Littkowski <I### [at] SvenLittkowskiname> wrote:

> 2
> The two suns don't look like suns but just like luminescent discs. No
> glow, and their colors are not correct, too: the large sun should be dim
> red, and the small sun should be white-glowing blue, each having a glow
> around them.

Surrounding the Sun(s) with a sphere of emission media (not too dense, and with
a 'spherical'-pattern color-map bleeding off to transparency) might work for the
glow(s).

Over the years, I've discovered that media colors do indeed change the
appearance of background object colors; it's a typical (and expected)
side-effect of media's color filtering. My own workaround for that has been to
radically change the colors of the background objects (your Suns, for example)
to try and 'compensate' for the color change. I usually have to do it 'by eye'
with test renders and experimentation. BTW, you can even use *negative* color
values for those objects-- like rgb <-.5,.3,-.7> for example -- to 'subtract'
unwanted media colors there, if you need to.

Post a reply to this message

I tried rendering cloud these days.
Using media is easy to get not bad result.

This picture is subsurface material version. When translucency rise. It is not
 like cloud enough. I'm not very knowing why. Cause when cloud is not dense it
should like be.

Post a reply to this message

Attachments:
Download 'subsurface cloud test.png' (403 KB)

Preview of image 'subsurface cloud test.png'

Then change to media:

Post a reply to this message

Attachments:
Download 'media 1 dens3.0 rad.png' (102 KB)

Preview of image 'media 1 dens3.0 rad.png'

Am 30.11.2017 um 17:14 schrieb And:

> This picture is subsurface material version. When translucency rise. It is not
>  like cloud enough. I'm not very knowing why. Cause when cloud is not dense it
> should like be.

My best guess is that it doesn't look anything like clouds because in
clouds you have a somewhat gradual change in the density of water
droplets, whereas the subsurface light transport model is designed for
cases where the density of the scattering agent changes abruptly at a
well-defined surface.

Directionality of scattering may also play a role (POV-Ray's current
implementation only supports isotropic scattering), but I don't think it
matters much in this case.

Post a reply to this message

Media is easy to get not bad result, but still have some limit.
This time I used the correct scattering color of cloud, and added some emission
to simulate multiple scattering effect(emission strength should proportion to
the sun power) , emission color I just guess.

For this cloud size this simulation is not bad.

Post a reply to this message

Attachments:
Download 'media 4 top_view.png' (154 KB)

Preview of image 'media 4 top_view.png'

"And" <49341109@ntnu.edu.tw> wrote:
> I tried rendering cloud these days.
> Using media is easy to get not bad result.
>
> This picture is subsurface material version. When translucency rise. It is not
>  like cloud enough. I'm not very knowing why. Cause when cloud is not dense it
> should like be.

This is a cotton candy machine  :)

Post a reply to this message

bottom view:

Post a reply to this message

Attachments:
Download 'media 4 bottom_view.png' (132 KB)

Preview of image 'media 4 bottom_view.png'

"And" <49341109@ntnu.edu.tw> wrote:
> Then change to media:

This is a hammer mill pulverizing plastic or mica

Post a reply to this message