 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hello,
I have a problem with interior's media with official Pov, in the image
we can see a all white media when rendered with Pov 3.7, and the good
colors with Uberpov.
Can someone explain this?
--
Lionel
<b>Do not judge my words, judge my actions.</b>
---
parce que la protection avast! Antivirus est active.
http://www.avast.com
Post a reply to this message
Attachments:
Download 'comparaison.png' (1186 KB)
Preview of image 'comparaison.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 30/11/2014 22:22, FractRacer wrote:
> Hello,
> I have a problem with interior's media with official Pov, in the image
> we can see a all white media when rendered with Pov 3.7, and the good
> colors with Uberpov.
> Can someone explain this?
>
Your code would help. ;-)
--
Regards
Stephen
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 1-12-2014 0:47, Stephen wrote:
> On 30/11/2014 22:22, FractRacer wrote:
>> Hello,
>> I have a problem with interior's media with official Pov, in the image
>> we can see a all white media when rendered with Pov 3.7, and the good
>> colors with Uberpov.
>> Can someone explain this?
>>
>
> Your code would help. ;-)
>
[start mumbling in background]
What happened to Mickey's ear?
[stop mumbling in background]
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Le 01/12/2014 00:47, Stephen a écrit :
> On 30/11/2014 22:22, FractRacer wrote:
>> Hello,
>> I have a problem with interior's media with official Pov, in the image
>> we can see a all white media when rendered with Pov 3.7, and the good
>> colors with Uberpov.
>> Can someone explain this?
>>
>
> Your code would help. ;-)
>
Here is the problem !
#version 3.7;
global_settings{
assumed_gamma 1
max_trace_level 25
ambient_light 1
}
background { rgb <0.000000, 0.000000, 0.000000> }
#declare camera_location = <0, 0, -75>;
camera{
location camera_location
up y
right x*image_width/image_height
angle 45
look_at 0
}
#declare SZ = 1500;
#declare SR = 200;
#declare Sun = sphere{
<0,0,0>, 1.2
pigment { rgbt 1 filter 0.0 }
finish {
specular albedo 0.2
}
hollow
interior{
ior 1.8
media{
method 3
emission 2.26
scattering{
1,
<.1,.5,1>*3.00
extinction 1.50
}
density{
granite
turbulence 0.85
color_map {
[0.00 rgbf 0]
[0.05 rgbf 0]
[0.20 rgbf 0.2]
[0.30 rgbf 0.6]
[0.40 rgbf 0.8]
[0.50 rgbf 0.991]
[0.60 rgbf 0.8]
[0.70 rgbf 0.6]
[0.80 rgbf 0.2]
[0.95 rgbf 0]
[1.00 rgbf 0]
}
}
samples 1,1
intervals 3
confidence 0.9
}
}
}
object {
Sun
scale <200,200,10>
translate <0,0,SZ+50>
}
--
Lionel
Do not judge my words, judge my actions.
---
Ce courrier électronique ne contient aucun virus ou logiciel malveillant parce que la
protection avast! Antivirus est active.
http://www.avast.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Le 01/12/2014 09:13, Thomas de Groot a écrit :
> [start mumbling in background]
> What happened to Mickey's ear?
> [stop mumbling in background]
>
> Thomas
>
>
One ear is enough for Mickey. :)
--
Lionel
<b>Do not judge my words, judge my actions.</b>
---
Ce courrier électronique ne contient aucun virus ou logiciel malveillant parce que la
protection avast! Antivirus est active.
http://www.avast.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
I think the problem is with your use of intervals and samples. Using
method 3, intervals should always be 1 while only the first parameter of
samples is read by the program. The second one is ignored.
Replace:
samples 1,1
intervals 3
by:
samples 100
intervals 1
You may need to play with the emission value and the multiplicator for
the scattering value.
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
And there is more: the scaling of the Sun & scattering media. Those
should be coupled. For that do this:
#declare MyScale = <200, 200, 10>;
On the scattering media line do this (example):
scattering {
1, <.1,.5,1>*5000/MyScale
extinction 1.50
}
And in the object block for the Sun, set: scale MyScale.
In that way you can scale the Sun however you want without changing the
visual aspect of the media. One word of caution: I always am weary of
asymmetrical media scaling. So, I personally prefer to use <200,200,200>
instead of <200,200,10> when I can avoid it.
With all this I have not yet got the Uberpov aspect in official POV, but
I am working on it :-)
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Third Important Lesson ;-)
ALWAYS work on a *unit-sized* media sphere!
sphere {<0,0,0>, 1.0
instead of
sphere {<0,0,0>,1.2
because that plays havoc when scaling the object.
(You can also delete the filter statement in pigment by the way)
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
This is what I have got (see image).
Left render with Uberpov; Right render with Pov 3.7.
The only code difference is the emission value: In Uberpov it is 2; in
POV-Ray it is 0.2. Higher values will white out the render. The
difference remains and I think Clipka knows why :-)
This is the media code I used for both renders:
#declare SR = 200;
#declare Sun =
sphere {
<0,0,0>, 1
pigment { rgbt 1}
hollow
interior {
//ior 1.8
media {
method 3
samples 100
intervals 1
//confidence 0.9
emission 0.2 //change to 2 in Uberpov
scattering {
1, <0.1, 0.5, 1>*1000/SR
//extinction 1.50
}
density {
granite
turbulence 0.85
color_map {
[0.00 rgb 0]
[0.05 rgb 0]
[0.20 rgb 0.2]
[0.30 rgb 0.6]
[0.40 rgb 0.8]
[0.50 rgb 0.991]
[0.60 rgb 0.8]
[0.70 rgb 0.6]
[0.80 rgb 0.2]
[0.95 rgb 0]
[1.00 rgb 0]
}
}
}
}
}
object {
Sun
scale SR
translate <0,0,0>
}
Thomas
Post a reply to this message
Attachments:
Download 'lionelmediaproblem.jpg' (212 KB)
Preview of image 'lionelmediaproblem.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Le 02/12/2014 13:40, Thomas de Groot a écrit :
> This is what I have got (see image).
>
> Left render with Uberpov; Right render with Pov 3.7.
>
> The only code difference is the emission value: In Uberpov it is 2; in
> POV-Ray it is 0.2. Higher values will white out the render. The
> difference remains and I think Clipka knows why :-)
>
> This is the media code I used for both renders:
>
> #declare SR = 200;
>
> #declare Sun =
> sphere {
> <0,0,0>, 1
> pigment { rgbt 1}
> hollow
> interior {
> //ior 1.8
> media {
> method 3
> samples 100
> intervals 1
> //confidence 0.9
> emission 0.2 //change to 2 in Uberpov
> scattering {
> 1, <0.1, 0.5, 1>*1000/SR
> //extinction 1.50
> }
> density {
> granite
> turbulence 0.85
> color_map {
> [0.00 rgb 0]
> [0.05 rgb 0]
> [0.20 rgb 0.2]
> [0.30 rgb 0.6]
> [0.40 rgb 0.8]
> [0.50 rgb 0.991]
> [0.60 rgb 0.8]
> [0.70 rgb 0.6]
> [0.80 rgb 0.2]
> [0.95 rgb 0]
> [1.00 rgb 0]
> }
> }
> }
> }
> }
>
> object {
> Sun
> scale SR
> translate <0,0,0>
> }
>
>
>
> Thomas
>
A big thanks for you, Thomas, I think I have all tried except the
emission's value. And now I know how handle the render with Povray and
Uberpov.
--
Lionel
Do not judge my words, judge my actions.
---
Ce courrier électronique ne contient aucun virus ou logiciel malveillant parce que la
protection avast! Antivirus est active.
http://www.avast.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
