Hi everyone!
I have some trouble with a particule systeme called "rune".

So, I want to do a kind of power ball by putting a particule system in a
sphere. I wrote in the particule parameters that the sphere will have to
block the particules themselves, like that the particules shouldn't go out
of the sphere, but it's not working. I thought that it was because the
system was already un the sphere so it couldn't detect the collision, so i
changed the sphere by a difference of 2 sphere, like that the particule
emitter is not in the sphere really, but in the hole inside the sphere...
but it doesn't work neither, the particules a still going through the
sphere :(, so i wonder what's wrong, and what i can do...
if anyone has an idea...
thk a lot
J-E

Post a reply to this message

"chtisaxo" <cht### [at] gmailcom> wrote:
> Hi everyone!
> I have some trouble with a particule systeme called "rune".
>
> So, I want to do a kind of power ball by putting a particule system in a
> sphere. I wrote in the particule parameters that the sphere will have to
> block the particules themselves, like that the particules shouldn't go out
> of the sphere, but it's not working. I thought that it was because the
> system was already un the sphere so it couldn't detect the collision, so i
> changed the sphere by a difference of 2 sphere, like that the particule
> emitter is not in the sphere really, but in the hole inside the sphere...
> but it doesn't work neither, the particules a still going through the
> sphere :(, so i wonder what's wrong, and what i can do...
> if anyone has an idea...
> thk a lot
> J-E
Actually, Rune is the guy who wrote the particle system. His site is:
http://runevision.com/3d/

I used it a few years ago to make an animation of a bagatelle board so it
should work for what you want. I wonder since your particles are inside the
sphere to start with you should use the Inverse keyword in the sphere.




Stephen

Post a reply to this message

if you want i can put the source i'm trying to render:



light_source {<-500,500,150> color rgb 1.3 }

camera {location <0,0,-5> look_at <0,0,0>}


// sphere which stop particules
#declare bloqueur =
sphere {
  <0,0,0>, 2
 clipped_by{sphere {<0,0,0>,1.8 inverse}}

}



   // Include particle system include file
// ************************************

   #include "particle.inc"

// Clock settings
// **************

   #declare particle_start  = -1;
   #declare particle_end    = 1.0;
   #declare particle_cyclic = on;
   #declare particle_steps  = 20;

// General particle settings
// *************************

   #declare particle_frequency = 10;
   #declare particle_life      = 1.5;
   #declare particle_lifeturb  = 0.0;
   #declare particle_seed      = 120;
   //#declare particle_maxnumber = 50;

// Environment settings
// ********************

   #declare particle_drag      = 0.0;
   #declare particle_transfer  = 0.0;

   #macro particle_gravity  (Clock,Point) 0*y #end
   #macro particle_wind     (Clock,Point) <0,0,0> #end

// Emitter settings
// ****************

   #macro particle_emitter  (Clock) <0,0,0>  #end
   #macro particle_emitting (Clock) on      #end
   #macro particle_emitvect (Clock) <5,0,0> #end
   #macro particle_emitturb (Clock) 0     #end
 #macro particle_emitobj(Clock) sphere{<0,0,0>,1} #end

   #macro particle_emitobjn (Clock) 1.2 #end

// Collision settings
// ******************

#declare particle_blockobj =bloqueur;
#declare particle_bounce = 0.5;
#declare particle_bounceturb = 0.5;
#declare particle_friction = 0.0;
#declare particle_bounceoffset = 0.1;

// Particle element macro (optional)
// *********************************

   #include "glow.inc"

// These settings are constant in this example, so they can
// be #declared outside of the particle_element macro.
   #declare glow_color     = <2,2,0.5>/0.8;
   #declare glow_colorturb = <0.3,0.3,0.3>;
   #declare glow_size      = 0.3;
   #declare glow_samples   = 5;

   #macro particle_element ()
//    Do things with the particle data here. Available data:
//    p_id,        p_random,    p_location,  p_direction, p_life,
//    p_age,       p_birth,     p_state,     p_rotate
      glow_element()
   #end


// Call particle system
// ********************

   particle_system ("partsys")






so here it is.. i putted this inverse keyword, but it's still not working...
thx anyway for this very fast answer!
i hope you will be able to help me ;)
J-E

Post a reply to this message

Clipped_by is not really the same as difference. Try to use instead:

#declare bloqueur =
difference {
   sphere {<0,0,0>,2.0}
   sphere {<0,0,0>,1.8}
}

I hope that helps.

Rune
-- 
http://runevision.com

Post a reply to this message

"chtisaxo" <cht### [at] gmailcom> wrote:
> if you want i can put the source i'm trying to render:
>
>
>
> light_source {<-500,500,150> color rgb 1.3 }
>
> camera {location <0,0,-5> look_at <0,0,0>}
>
>
> // sphere which stop particules
> #declare bloqueur =
> sphere {
>   <0,0,0>, 2
>  clipped_by{sphere {<0,0,0>,1.8 inverse}}
>
> }
[snip]

>>
> so here it is.. i putted this inverse keyword, but it's still not working...
> thx anyway for this very fast answer!
> i hope you will be able to help me ;)
> J-E


all the settings but try the small change below. Note that the inverse is
not in the clipped_by sphere.

// sphere which stop particules
#declare bloqueur =
sphere {
  <0,0,0>, 2
 clipped_by{sphere {<0,0,0>,1.8 }}
inverse
}


then incorporate it in your scene


Stephen

Post a reply to this message

ok, rune's solution is working quiet well,it's exactly what i wanted to do.
thanks a lot Stephen, to answer also, you were very efficent, thx to both
of you!

Post a reply to this message