"Kenneth" <kdw### [at] gmailcom> wrote:
> Your final ship is really gorgeous, and the animation of the engine 'ion
> exhaust' looks great! It's a nice and sophisticated use of media. Btw, thanks
> for the description of your ship's surface texture; I had originally thought
> that you had used one of POV-ray's newer 'pavement' patterns (perhaps that is
> part of the mix), but your averaging(?) of simple box and rectangle
> shapes/images makes perfect sense. I look forward to experimenting with that
> technique.

Thanks Ken! Here's a quick scene file example that creates some random
rectangles to use as a base greeble texture (for bump and reflection mapping,
and as a base pigment layer):

// Command-line: +w1024 +h1024 +fn16 +a0.1
#include "rand.inc"
global_settings { assumed_gamma 1 }
#default { finish { ambient 1 diffuse 0 } }

#declare R = seed(1);

camera {
   orthographic
   location <0, 0, -1>
   look_at <0, 0, 0>
   right x*image_width/image_height
}

background { rgb 0.5 }

#declare Box = box { -0.5, 0.5 hollow scale z*0.01 }
#declare Border = 0.005;
#declare Max = 500;

#for (i, 1, Max)
   #local Scale = <RRand(0.05, 0.25, R)*(Max-i/Max)/Max, RRand(0.05, 0.25,
R)*(Max-i/Max)/Max, 0.005>/2;
   union {
      object { Box
         scale <Scale.x+Border, Scale.y+Border, 1>
         pigment { rgb RRand(0, 0.1, R) }
      }
      object { Box
         scale Scale
         pigment { rgb RRand(0.1, 0.9, R) }
         translate -z*0.01
      }
      translate <RRand(-0.5, 0.5, R), RRand(-0.5, 0.5, R), 2-0.01*i>
   }
#end

The attached image shows my process for taking the raw render resulting from
this code and making various greeble image maps from it. (A) is the image as
rendered, (B) is that same image with quadrants offset diagonally (this is
important for tiling). The others are composites of (B) layered over (A) using
the different blending modes Darker Color, Multiply and Overlay. This is easily
done in GIMP or PhotoShop, or even directly in POV-SDL using averaged pigment
functions for the die-hard purists out there (hey, I still do it). The cool
thing about this method is that the resulting images tile seamlessy (see the
example in the bottom right).


> Your work has really paid off! It's inspiring.

Thanks again, I really appreciate that. I like to think we all inspire each
other here. I've seen some really interesting discussion and code from you and
Thomas and Bald Eagle in this thread alone, and that's resulted in other new
threads that further expand on and propagate the inspiration. Go Team!

Cheers,
Rob

Post a reply to this message

Attachments:
Download 'creatinggreeblesimagemapsexample.jpg' (1153 KB)

Preview of image 'creatinggreeblesimagemapsexample.jpg'