hi,

clipka <ano### [at] anonymousorg> wrote:
> I've decided that the new tokenizer is here to stay and reasonably
> mature, so I thought I might just as well make it part of the official
> development branch:
> https://github.com/POV-Ray/povray/releases/tag/v3.8.0-alpha.10008988

the code below gives me a "Segmentation fault".


regards, jr.


(from the newsgoups last year but didn't keep the reference to the author)

// Hintergrund

plane { z,0.441
 pigment { checker color rgb 0.7 color rgb 0.3 }
}

light_source {
 <-33,66,-99> color 1
 area_light <16,0,0>, <0,16,0> , 5, 5 jitter
}

camera {
 orthographic
 right <8,0,0>*0.875
 up <0,6,0>*0.875
 location <0,0,-10>
 look_at <0,0,0>
}

#declare P3 = array[8] {0, 1, 1, 1, 3,  4,  12, 9999};
#declare P4 = array[8] {0, 1, 1, 2, 5, 12,  35, 9999};
#declare P6 = array[8] {0, 1, 1, 3, 7, 22, 999, 9999};

#declare N=1;
#declare T=6;
#declare P=1;
#declare SCL = 0.2;

#declare Y=-2;
#while(Y<=+2)
 #declare X=-3;
 #while(X<=+3)

// #declare S = concat("N", str(N,2,0), ", T", str(T,2,0), ", P", str(P,2,0) );
 #declare S = concat("T", str(T,2,0), ", P", str(P,2,0) );
 #if(T<7)

// sphere { <0,0,0> , 0.45
 cylinder { <0,0,-0.45>, <0,0,+0.45>, 0.45
  pigment { pavement
    number_of_sides 4
    number_of_tiles T
    pattern P

   color_map {
    [0.0 color rgb<1.0,1.0,1.0> ]
    [1.0 color rgb<0.2,0.1,0.6> ]
   }
  rotate x*-90
  scale 0.08
  }
  finish { phong 0.5 }

  translate <X,-Y,0>
 }

 text { ttf "arialbd.ttf"
  S
  0.001 0
  pigment { color rgb<1.0, 0.6, 0.2>*1.25 }
  no_shadow
  scale SCL
  translate <X-0.4, -Y-0.45, -0.55>
 }

 text { ttf "arialbd.ttf"
  S
  0.001 0
  pigment { color rgb 0.1 }
  no_shadow
  scale SCL
  translate <X-0.4, -Y-0.45, -0.55> + 0.0081*<1,-1,1>
 }
 #end

 #declare X=X+1;
 #declare N=N+1;
 #declare P=P+1;
 #if(P>P4[T])
  #declare T=T+1;
  #declare P=1;
 #end
 #end
#declare Y=Y+1;
#end

Post a reply to this message