"Kenneth" <kdw### [at] gmailcom> wrote:
>  The problem with using a sky_sphere is that my
> police car renders need a transparent background (for compositing later); I
> don't *think* a sky_sphere can be made no_image (?). But I could be wrong about
> that.

No, you are not wrong.  Luckily, POV-Ray has a built-in sphere primitive.  :-)
__________________________________________________

//+ua
#version 3.7;

global_settings { assumed_gamma 1 }

#include "colors.inc"
#include "skies.inc"

sphere
{ 0, 1
 //Substitute your image map
  texture
  { pigment
    { gradient y color_map
      { [0 rgb <0.4, 0.6, 1.0>]
        [1 rgb <0.10, 0.15, 0.30>]
      }
    }
    finish { ambient 0 diffuse 0 emission 1 }
  }
  texture { T_Cloud1 scale 0.1 }
 //
  scale 10000
  hollow
  no_image
}

light_source
{ <-1, 1, -1> * 5000, rgb <1.4716, 1.0775, 0.6379>
  parallel point_at 0
}

camera
{ location <0, 0.75, -5>
  look_at <0, 1, 0>
  angle 40
}

plane { y, 0 pigment { checker rgb 0.05 rgb 1 } }

sphere
{ y, 1
  pigment { rgb <0.61, 0.61, 0.64> }
  finish
  { reflection { 1 metallic }
    ambient 0 diffuse 0
    specular albedo 1 metallic roughness 0.0001
  }
}

Post a reply to this message

Attachments:
Download 'kenneth-alpha_sky.png' (53 KB)

Preview of image 'kenneth-alpha_sky.png'