Sure; glad to help. Here are the lights and the texture. This assumes that your
own square SEM model is lying flat horizontally, with the top surface exactly at
y=0 (and centered on the origin; but that's not critical.) Your own model might
not be the same size as mine (which is 1X1), so adjust the light distances and
the gradient y pigment scale if needed. BTW, the overall brightness will depend
on what assumed_gamma you use in your scene. (I used 2.2 for this test.)

// The lights...
light_source {
  <0, 0, 0>
  color rgb .7
  area_light
  <12, 0, 0> <0, 0, 12> // lights spread out across this distance (x * z)
  4, 4                // total number of lights in grid (4x*4z = 16 lights)
  adaptive 0          // 0,1,2,3...
  jitter              // adds random softening of light
  circular            // make the shape of the light circular
  orient              // orient light
  translate <-10, 7, 10>
}

light_source {
  <0, 0, 0>
  color rgb .9
  area_light
  <12, 0, 0> <0, 0, 12> // lights spread out across this distance (x * z)
  4, 4                // total number of lights in grid (4x*4z = 16 lights)
  adaptive 0          // 0,1,2,3...
  jitter              // adds random softening of light
  circular            // make the shape of the light circular
  orient              // orient light
  translate <10, 20, 10>
}

// The texture...
texture{
   pigment{
      gradient y
      pigment_map{
           [.01 // For the top surface only
           average
           pigment_map{
              [1 rgb .16]
              [1.5 bumps scale .003]
                      }
           ]
           [.01 rgb .9] // immediately under the surface
           [1 rgb .2]// for the indents
                 }
           scale .039*<1,-1,1> // Adjust the multiplier so
// the bottom of your SEM indents don't start showing the repeating
// gradient y pattern. The -1 for y just 'flips' the gradient y, as
// I specified the colors going 'up', not down.
         }
   finish{ambient 0 diffuse 1} // You might want to add a
// little bit of ambient.
       }

Post a reply to this message