I hope you don't mind, but your post inspired me to try this in an entirely
different way: Instead of placing spray particles through a mask, I just draw
the mask as an object pigment with some turbulence to create the spray effect.

Obviously this is far less realistic, but it's very quick to trace.

Here's the code in case you want to give it a try:
pigment {
 object {
  union {
   sphere_sweep {
    cubic_spline
    5,
    <-1,1>, .1,
    <-.5,0>, .2,
    // move away from the surface to thin out the spray
    <1,0,-.1>, .1,
    <2,1,-.2>, .1,
    <2,2,-.3>, .0
   }
   difference {
    cylinder { -z, z, 1 }
    cylinder { -z, z, .7 }
    #for ( a, 0, 360-45, 45 )
     box { -z, <.15,1,1> translate -x*.7 rotate z*a }
    #end
   }
  }
  rgb 1, rgb <1,0,1>
 }
 #local noiseScale = .004;
 scale 1/noiseScale
 warp { turbulence .1/noiseScale octaves 2 lambda 4 }
 scale noiseScale
}

--
Tek
http://evilsuperbrain.com

Post a reply to this message

Attachments:
Download 'spray_paint.png' (147 KB)

Preview of image 'spray_paint.png'