|
![](/i/fill.gif) |
"Mr" <nomail@nomail> wrote:
> Excellent, would it be possible to get an idea of your settings and rendertime
> for a frame?
> I have many troubles to find acceptable settings for caustics.
I used pretty high radiosity settings, an area light, EXR environment, and focal
blur (mostly for antialiasing) and was getting a render time of ~4min/frame
@1280x720px on my i7 with 8 render threads, but here is the bare bones scene
code for just the aqua water box:
#version 3.7
background { rgb 0.5 }
global_settings {
assumed_gamma 1
max_trace_level 20
radiosity {
//...
}
photons { spacing 0.02 }
}
camera {
location vnormalize(<-6, 8, -9>)*100
look_at <-20, 10, 0>
right x*image_width/image_height
angle 55
rotate <0, 20, 0>
}
light_source { <20, 30, 15> rgb 1
area_light <1, 0, 0>, <0, 0, 1>, 6, 6
orient
circular
area_illumination on
fade_distance 20
fade_power 2
}
// floor
plane { y, 0 hollow pigment { srgb <236,220,196>/255 } }
// aqua box
box { -0.5, 0.5
scale <10, 20, 5>
rotate <110, 90, 0>
translate <10, 15, 17>
texture {
pigment { rgbt 1 }
normal {
bozo
scale 1
turbulence 0.5
bump_size 2
}
finish { specular 0.2 roughness 0.2
reflection { 0, 1 fresnel on } conserve_energy }
}
interior { ior 1.33
fade_color srgb <223,248,255>/255
fade_power 1001
fade_distance 1
}
photons {
target
refraction on
reflection on
collect on
}
}
-------------------------------------------------
www.McGregorFineArt.com
Post a reply to this message
|
![](/i/fill.gif) |