Good job!

Here is a more modest code snippet with emission-only media in a simple ovus
container (could be an animatable blob)

#include "colors.inc"

global_settings
{
    assumed_gamma 1
}

#declare FLAME_COLOR1 = (2*Firebrick+Goldenrod)/3;
#declare FLAME_COLOR2 = (2*Orange+Goldenrod)/3;

camera
{
    location -10*z
    angle 40
    right x*image_width/image_height
}

sphere
{
    0, 1
    hollow
    pigment {brick scale 0.5*x scale 1/250 warp {spherical}}
    scale 30
}

ovus
{
    1, 0.6
    pigment {rgbt 1}
    hollow
    interior
    {
        media
        {
            samples 5
            emission 6
            //scattering {1, White}
            //absorption 4
            density
            {
                spherical scale 2
                translate -1.5*y
                color_map
                {
                    [0 FLAME_COLOR1]
                    [0.25 FLAME_COLOR2/8]
                    [0.30 FLAME_COLOR2/8]
                    [0.40 MediumBlue/4]
                    [0.45 MediumBlue/10]
                    [0.6 rgb 0]
                }
            }
        }
    }
    scale 1.5*y
    scale 1/(1.3*1.5)

}

Post a reply to this message

Attachments:
Download 'flame.png' (50 KB)

Preview of image 'flame.png'