More SSLT fun, and maybe I've got this all wrong, but I'm following Jaime's
wise ignorancia philosophy and this is working for me right now...

Please pardon the code here, but I think it's nice posted all in one spot like
this:

//==============================================================================
// Persistence of Vision Ray Tracer Scene Description File
//-----------------------------------------------------------------------------
// File        : sslt_spheres.pov
// Version     : 3.7
// Description : Playing with SSLT stuff
// Date        : 09/21/2010
// Author      : Robert W. McGregor, rob### [at] mcgregorFineArtcom
//==============================================================================

#version 3.7;   // beta 39
default { pigment { color rgb 0.75 } finish { ambient 0 diffuse 0.5 }}

#include "colors.inc"
#include "math.inc"
#include "rand.inc"

//------------------------------------------------------------------------------
// Globals and radiosity settings
//------------------------------------------------------------------------------

#declare R = seed(1234);

#declare Soft_Shadows  = 1;
#declare Use_Radiosity = 1;

#declare SCALE = 100;

global_settings {
   max_trace_level 5
   #if (Use_Radiosity)
      radiosity {
         brightness      1
         recursion_limit 2
         always_sample   off
         normal          off
         nearest_count   10
      }
   #end
}

//------------------------------------------------------------------------------
// Camera & lights
//------------------------------------------------------------------------------

background { color rgb 0 }

camera {
   location  <0, 0, -15>*SCALE
   look_at   <0, 0, 0>
   right <image_width/image_height, 0, 0>
   angle 30
}

#declare light_pos = <-1.5, 1.5, 1.5>*SCALE;
light_source {
   light_pos
   color rgb 3
   #if (Soft_Shadows)
      area_light <10, 0, 0>, <0, 0, 10>, 5, 5
      adaptive 2
      jitter
      orient circular
   #end
   fade_distance VDist(<0,0,0>,light_pos)
   fade_power 2
}

//------------------------------------------------------------------------------
// SSLT subsurface colors
//------------------------------------------------------------------------------

#local sslt_aqua    = <1, 0, 0>;
#local sslt_magenta = <0, 1, 0>;
#local sslt_yellow  = <0, 0, 1>;
#local sslt_blue    = <1, 1, 0> ;
#local sslt_red     = <0, 1, 1>;
#local sslt_green   = <1, 0, 1>;
#local sslt_grey    = <0, 0, 0>;

//------------------------------------------------------------------------------
// Macro: MakeSphere()
//        SSLT Sphere
//------------------------------------------------------------------------------
#macro MakeSphere(clr)

   #local AMT = 0.5;
   //#local amt = < 1.6732, 1.2806, 0.6947>;   // clipka's from subsurface.pov
   #local amt = < 0.001, 0.001, 0.001>*AMT;

   sphere { 0, 1
      texture {
         pigment {rgb 0}
         finish{
            #local AMT = 20;
            #local amt = < 0.001, 0.001, 0.001>*AMT;
            subsurface { amt, clr }
         }
      }
      texture {
         pigment {
            bozo
            color_map {[0 rgbt 0][1 rgbt 1]}
            scale 0.2
            turbulence 0.5
            rotate RRand(0, 360, R)
         }
         normal {
            bozo
            normal_map {
               [0 granite 1 scale 10]
               [1 agate 0.01 ]
            }
            turbulence 0.5
            scale 0.075
            bump_size -5
         }
         finish {
            ambient 0
            diffuse 0.6
            specular 0.25 roughness 0.02
         }
      }
      interior { ior 1.33 }
   }
#end

//------------------------------------------------------------------------------
// The spheres
//------------------------------------------------------------------------------
union {
   object { MakeSphere(sslt_green)   translate x*2.5 rotate z*360/7*0 }
   object { MakeSphere(sslt_aqua)    translate x*2.5 rotate z*360/7*1 }
   object { MakeSphere(sslt_blue)    translate x*2.5 rotate z*360/7*2 }
   object { MakeSphere(sslt_magenta) translate x*2.5 rotate z*360/7*3 }
   object { MakeSphere(sslt_red)     translate x*2.5 rotate z*360/7*4 }
   object { MakeSphere(sslt_yellow)  translate x*2.5 rotate z*360/7*5 }
   object { MakeSphere(sslt_grey)    translate x*2.5 rotate z*360/7*6 }
   scale SCALE
}
//end file======================================================================


Cheers,
Rob

-------------------------------------------------
www.McGregorFineArt.com

Post a reply to this message

Attachments:
Download 'sslt_spheres.png' (440 KB)

Preview of image 'sslt_spheres.png'