"s.day" <s.d### [at] uelacuk> wrote:
> Wow, great detail and the textures look excellent, the image is great as well,
> love the textures on the gas cylinders.. How did you get the glow effect on the
> numbers is it just high ambient or are they actual light sources?
>
> Sean

Thanks Sean, I really put a lot of time into this one (which made my elephant
shot over on TC-RTC suffer a bit unfortunately). Nice bugs in your shot BTW -  I
love the detail render :)

Each glowing number is basically simple emitting media with some faintly lit
point lights scattered along the vertices of the mesh. The internal reflections
and refractions are just ray-tracing gravy on my glass texture (which both
surprised and pleased me).

As an example, here's the first test I did last month as a proof-of-concept to
make sure I could actually create a believable Nixie tube for the shot [the hex
plate in front is just an image_pattern stencil mask created from the
Hex_Tiles_Ptrn() macro in "textures.inc" that I rendered, took into PhotoShop
and inverted colors, tightened the histogram using Levels, and applied a bit of
Gaussian blur].

Sample Code:
(And yes, I know, this is the *images* group, but it just makes more sense to me
to have it all in one place; mea culpa)

#version 3.7;
default { pigment {rgb 0.7} finish { ambient 0 diffuse 0.7 }}
global_settings { radiosity {} }

// camera & EXR environment lighting
camera {
   location <0, 0, -150>
   look_at  <0, 0, 0>
   right    x*image_width/image_height
   angle    30
}

sphere {0, 1000 hollow inverse
   pigment { image_map { exr "probe_stpeters.exr" map_type 1 interpolate 2} }
   finish { diffuse 0 ambient 0.5 }
}


// "Tube"
#declare Tube = difference {
   sphere { 0, 1.02 }
   sphere { 0, 1 hollow inverse}
   material {
      texture {
         pigment {rgb 0.35 transmit 0.85 filter 0.15}
         normal {bumps 0.01 scale 0.025 }
         finish {
            reflection {0.25, 0.95 fresnel on} conserve_energy
            specular 0.5 roughness 0.01
         }
      }
      interior {ior 1.01 dispersion 1.01 caustics 1}
   }
   scale <0.75, 1.25, 0.75>
}
object { Tube scale 30 }


// Number test
#declare Num = torus { 10, 1 hollow rotate x*90 scale z*0.35}

#local n = 0;
#local MAX = 40;

union {
   // media "number"
   object {Num hollow
      pigment {rgbt 0.95}
      finish {ambient 1 diffuse 0}
      interior {
         media {
            emission 1
            density {
               function{abs(z)}
               density_map {
                  [0 rgb 0]
                  [0.5 rgb <1, 0.25, 0>*6]
                  [0.7 rgb <1, 0.50, 0>*6]
                  [1 rgb 1]
               }
            }
         }
         media {
            emission 1
            density {
               bozo
               density_map {
                  [0 rgb <1, 0.25, 0>*2]
                  [1 rgb <1, 0.50, 0>*2]
               }
            }
         }
      }
      no_shadow
   }

   // some actual lights within the number
   #while (n<MAX)
      object {
         light_source { 0
            color rgb <255,180,80>/255*0.07
            fade_power 2 fade_distance 20
         }
         translate <10, 0, 0>
         rotate z*360/MAX*n
      }
      #local n = n + 1;
   #end

   // back plate
   box {-1, 1
      scale <15, 20, 0.5>
      translate z*5
      pigment { rgb 0.5 }
      normal {agate 0.075 scale 0.075}
      finish {reflection {0.2, 0.5 fresnel on} conserve_energy}
   }

   // Front "mesh" (an image_pattern stencil mask)
   box {-1, 1
      texture {
         image_pattern { png "hexagons.png" }
         texture_map {
            [0 pigment { transmit 1 } ]
            [1
               pigment { rgb 0.25 }
               finish {reflection {0.2, 0.5 fresnel on} conserve_energy}
            ]
         }
      }
      scale <15, 20, 0.1>
      translate -z*3
   }
   rotate y*20
}

Cheers,
Rob

Post a reply to this message

Attachments:
Download 'nixietubetest.png' (461 KB)

Preview of image 'nixietubetest.png'