Christian Froeschlin <chr### [at] chrfrde> wrote:
> The MegaPOV examples scene pat_aoi.pov rendered in my patched 3.7b31
>
> It's not 100% identical to the MegaPOV render but that was to
> be expected for a radiosity scene. Without radiosity I did not
> see any difference.
>
> If anyone has some made some nifty trick using the aoi
> pattern and wishes to provide the scene file I'd be happy
> to test whether it works.

I've used it to vary the blurriness of reflectivity based on the viewing angle,
so using aoi for the micronormals (this example is a bit contrived, but shows
the effect I want):

// Render at 640x480 with AA set waaay up high
#version unofficial MegaPov 1.21;

camera { perspective location <1,0.67,-4> angle 45 look_at <0,1,0> }
light_source { <200,180,-200> rgb 1 }
plane { <0,1,0>, 0 pigment { checker rgb 1 rgb 0 } }

#declare normal_scale = 0.0001;
#declare blur_size = 0.08;

sphere {
 <0.0, 0.0, 0.0>, 1
 translate y*1

 pigment { rgb <1,0.1,0.7> }
 finish { reflection {0, 1 fresnel on} metallic }
 normal {
  aoi
  normal_map {
   [ 0.00, bumps blur_size*1.00 scale normal_scale ]
   [ 0.05, bumps blur_size*0.99 scale normal_scale ]
   [ 0.10, bumps blur_size*0.98 scale normal_scale ]
   [ 0.15, bumps blur_size*0.96 scale normal_scale ]
   [ 0.20, bumps blur_size*0.92 scale normal_scale ]
   [ 0.25, bumps blur_size*0.87 scale normal_scale ]
   [ 0.30, bumps blur_size*0.80 scale normal_scale ]
   [ 0.35, bumps blur_size*0.70 scale normal_scale ]
   [ 0.40, bumps blur_size*0.56 scale normal_scale ]
   [ 0.45, bumps blur_size*0.34 scale normal_scale ]
   [ 0.50, bumps 0 ]
  }
 }
 interior { ior 2.2 }
}

// Just to add some pretty
sky_sphere {
 pigment {
  gradient y
  color_map {
   // http://povray.tashcorp.net/tutorials/qd_realskysphere/
   [  0/269 color rgb <120/255, 79/255, 51/255>]
   [  1/269 color rgb <141/255, 83/255, 46/255>]
   [  2/269 color rgb <177/255, 86/255, 41/255>]
   [  3/269 color rgb <235/255,128/255, 72/255>]
   [  5/269 color rgb <255/255,159/255, 72/255>]
   [  8/269 color rgb <255/255,203/255, 94/255>]
   [ 10/269 color rgb <255/255,218/255,112/255>]
   [ 13/269 color rgb <255/255,233/255,148/255>]
   [ 15/269 color rgb <251/255,241/255,172/255>]
   [ 20/269 color rgb <255/255,246/255,203/255>]
   [ 30/269 color rgb <255/255,240/255,219/255>]
   [ 40/269 color rgb <236/255,223/255,214/255>]
   [ 50/269 color rgb <205/255,204/255,212/255>]
   [ 55/269 color rgb <185/255,190/255,209/255>]
   [ 60/269 color rgb <166/255,176/255,201/255>]
   [ 65/269 color rgb <149/255,163/255,190/255>]
   [ 70/269 color rgb <129/255,149/255,182/255>]
   [ 80/269 color rgb <103/255,127/255,171/255>]
   [ 90/269 color rgb < 79/255,110/255,154/255>]
   [100/269 color rgb < 66/255, 97/255,143/255>]
   [110/269 color rgb < 52/255, 84/255,131/255>]
   [120/269 color rgb < 47/255, 75/255,122/255>]
   [140/269 color rgb < 37/255, 60/255,102/255>]
   [160/269 color rgb < 32/255, 51/255, 84/255>]
   [180/269 color rgb < 27/255, 42/255, 71/255>]
   [200/269 color rgb < 25/255, 36/255, 58/255>]
   [220/269 color rgb < 22/255, 31/255, 48/255>]
   [240/269 color rgb < 18/255, 27/255, 42/255>]
   [260/269 color rgb < 15/255, 21/255, 33/255>]
   [269/269 color rgb < 15/255, 21/255, 33/255>]
  }
 }
}


Cheers,
Edouard.

Post a reply to this message

Attachments:
Download 'aoi-micronormals.jpg' (35 KB)

Preview of image 'aoi-micronormals.jpg'