Paolo Gibellini <p.g### [at] gmailcom> wrote:
> Nice city!
> Are the cells generated with a normal in the texture or are random boxes
>   placed using the normal?
> Can I see the source?
> Thank you,
>  Paolo


-----------------
Hi, this may still be a bit obfuscated; I didn't check that every  single line
were critical to running the rendering.

-------------------


#declare SunPos=       <100,141.0,-.150>;

light_source{<30,100, -30> color rgb 0.4+0.2*x}
light_source{<-0,100, -30> color rgb 0.4+0.2*z}

#include "colors.inc"
#include "functions.inc"

#declare funky2=function{pigment{bumps scale 0.150}}

   #declare bozoy=pigment{bozo scale 0.05}
   #declare bozoy2=pigment{bozo scale 0.10 translate 11}
   #declare celly=pigment{cells   scale 0.008}
   #declare leopy=pigment{leopard scale 0.025 rotate 45*z}
   #declare celly2=pigment{cells scale 0.05  translate 11}
   #declare celly3=pigment{cells scale 0.025  translate 2*z}
   #declare bumpy=pigment{bumps scale 0.1}

   #declare hh=clock;

   #declare avey=pigment{average
                        pigment_map{
                                [1.0  bozoy]
                                [0.05 bumpy]
                                [0.08 celly]
                                }
                         }


   #declare funky=function{pigment{avey}}


#declare OceanBot=texture{pigment{rgb <0.22,0.40,0.48>} finish{reflection {
0.1,0.5 }} }
#declare OceanShal=texture{pigment{rgb <0.40,0.58,0.62>}finish{reflection {
0.1,0.5 }} }
#declare Shore=texture{pigment{rgb <0.71,0.71,0.69>} finish{ambient 0.5}}

#declare Brownness=texture{pigment{Brown/2+White/2} finish{ambient 0.25}}
#declare Whiteness=texture{pigment{rgb 0.8} finish{ambient 0.25}}

#declare Shoremix=texture{      bumps
                                texture_map{
                                        [0.0 Brownness]
                                        [1 Whiteness]
                                        }
                                scale 0.001
                                }

#declare Forest=texture {

                        pigment{slope {SunPos}
                                pigment_map{
                                        [0.0 rgb 0.20*<0.84,1.0,0.55>]
                                        [1.0 rgb 0.48*<0.84,1.0,0.51>]
                                         }
                                }
                        }



#declare Oceanmix=texture{ bumps
                           texture_map{
                                        [0 OceanBot]
                                        [1 OceanShal]
                                        }
                           scale 0.1
                           }

 #declare hfqual=700;

     height_field {
  function hfqual,hfqual {pow(funky(x,y,z).grey,3)}  //smooth
     texture{gradient y
                texture_map{
                        [0.00 Oceanmix]
                        [0.07 Oceanmix]
                        [0.07 Shoremix ]
                        [0.09 Shoremix ]
                        [0.09 Forest]
                        [0.22 Forest]
                        [0.22 Shoremix]
                        [1.00 Shoremix]
                        }
                }    translate <-0.5,0,-0.5>  scale <5,1,5> }

camera{
       location <0,4.5,-2.>
       look_at 0
       angle 35

       }

Post a reply to this message