"Kirk Andrews" <kir### [at] tektonartcom> wrote:
> "Welcome to the Island.  I hope you enjoy your stay.  Please place lots of
> suggestions for improvements in the box below..."
>
>
> Island is isosurface with a wrinkles pattern.  There are no actual trees or
> vegetation on the Island for now, just textures.  The sky is merely a sky
> sphere at this point.
>
> I'm having trouble with the water:  I would like to get the effect of the
> turquoise color around shallow waters and sandy beaches, so I'm using ior and
> fade_power setting, but I can't seem to get them right.  If someone has more
> experience using the interior fade settings, I'd appreciate some
> recommendations.

To get the water effect you are looking for, you really should use scattering
media.  Light fading will only darken rays, which will not achieve the effect
you want as what you see in real life is actually scattered light.  Have a look
at the water material below for example.

One alternative would be to use a negative filter
eg: rgbf <0.51373, 0.70588, 0.70588,-2>
But this would make all your water seem to glow unaturally.

-tgq


//START
#declare WCol=rgb <0.51373, 0.70588, 0.70588>;
#declare MWater=
  material{
    texture{
      pigment{rgbt 1}
      finish{conserve_energy  diffuse 0.0  ambient 0  reflection{0 1 fresnel on
metallic 0}}
      normal{P1}
    }

    #local FD=-(1000/(6*25.4))/ln(0.58);
    interior{
      ior 1.33
      media{
        absorption rgb 1-WCol //coastal
        density{rgb 1/FD}
      }
      media{
        method 3
        //intervals 12
        //samples 60,100
        jitter 0.5
        scattering{4,rgb <0.74118, 0.71765, 0.41961>}
        density{
          bozo
            color_map {
              [0.0 rgb 1/100]
              [1.0 rgb 1/200]
            }
            scale 1/2
        }
      }
    }
  }
//END

Post a reply to this message