Not inspired by any building in particular.  I intend to improve it,
eventually.  As it is, it began very simply.

source:


// sky
sphere { 0, 1
 texture {
 pigment { gradient -y color_map {[0 rgb z*.7][1 rgb <.8,.9,1>]} }
 finish { ambient 1 diffuse .01 }
 scale 2.1
 translate -y/2
 }
 texture {
 pigment { bozo turbulence .6 omega .6 lambda 3
     color_map {[0 rgbt 1][.56 rgbt 1][.6 rgb 1][1 rgb 1]} scale .5
 }
 finish { ambient 1 diffuse .002 }
 scale 2.1
 translate -y/2
 }
 no_shadow
 scale 1000
}

#local p_concrete = pigment {
    checker rgb .9 rgb .86 turbulence .1 omega .56 scale 10
}

// scene
union {
 light_source { 300*(1-2*z) <1,1,.8>*1.2 }
 plane { y, 0 pigment { rgb 1 } finish { ambient .2 diffuse .5 } }

 #local building_s = <36,90,18>;
 #local building =
 union {
     box { -1,1 scale building_s/2
         pigment { rgb .1*y }
         normal { average
             normal_map {
                 [1 quilted .07 control0 .06 control1 .06 scale 2]
                 [.5 cells scale 2 slope_map {[0 .1][.7 .1][.7 0][1 0]}]
             }
         }
         finish { diffuse .007 ambient .01 brilliance 1.4
             specular .9 roughness .01 metallic .2
             reflection { .02,3.96 metallic .2
                 fresnel on exponent 3 falloff 20
             }
             conserve_energy
         }
         hollow
         interior { ior 1.5 fade_power 2 fade_distance 3 }
     }
     box { -1,1 scale <7,building_s.y+5,building_s.z+4>/2
         pigment { p_concrete }
         translate y*5/2 -x*8
     }
     box { -1,1 scale <7,building_s.y+5,building_s.z+4>/2
         pigment { p_concrete }
         translate y*5/2 +x*8
     }
     finish { ambient .01 diffuse .5 }
     translate y*building_s/2
 }

 union {
     object { building rotate y*90 translate -x*(building_s.z/2+10) }
     object { building rotate y*90 translate x*(building_s.z/2+10) }
     //rotate y*70
 }

 //box { -1,1 scale 20 pigment { rgb .8 } translate -z*60-x*20 }

 rotate -y*30
}

#local cam1 =
camera {
 location -z*80*2+y*1.6
 look_at y*50
 angle 50
}

#local cam2 =
camera {
 location -z*60 + y*1.6
 look_at y*60
 angle 50
}

camera { cam2 }

global_settings {
    radiosity { brightness .7 count 80 error_bound .5 normal on }
}

Post a reply to this message

Attachments:
Download 'predio-wip1.jpg' (38 KB)

Preview of image 'predio-wip1.jpg'