|
![](/i/fill.gif) |
"Trevor G Quayle" <Tin### [at] hotmail com> wrote:
> Warp <war### [at] tag povray org> wrote:
> > aaglo wrote:
> > > - metal texture on the screws & screwdriver
> >
> > I have to admit that I have no idea how to make a realistic-looking
> > metallic texture for the screwdriver...
>
> If you want a reflective clean metal, like crome or polished stainless
> steel, the material is basically defined by what it reflects. Using
> environment mapping and real reflections rather than phong or specular
> highlighting (which tend to look more plasticky) can help considerably.
> You can also overlay a simple reflective chrome with layers of grease,
> dust, dirt, rust etc and still have the reflectivity partially revealed.
>
> -tgq
A shiny, denty, rusty, dusty chrome:
#declare TChrome=
texture{
pigment{rgb 0.8}
finish{ambient 0
conserve_energy
diffuse 0.0
reflection{0 1 fresnel on metallic 0}
}
normal{dents 0.25 scale 1/15}
}
#declare TRust=
texture{
pigment {
granite
color_map {
[0.08 rgb <0.89, 0.51, 0.28>]
[0.15 rgb <0.70, 0.13, 0.00>]
[0.30 rgb <0.69, 0.41, 0.08>]
[0.30 rgb <0.49, 0.31, 0.28>]
[0.40 rgb <0.89, 0.51, 0.28>]
[0.40 rgbt 1]
}
}
finish {ambient 0 diffuse 0.4}
normal{
granite
normal_map{
[0.40 average normal_map{[1 granite -0.3][1 granite 0.2 scale 1/5]}]
[0.40 granite 0]
}
}
}
#declare TDusty=
texture{
pigment{
#declare PW=1;
slope y
color_map{
[pow(0.5,PW) rgbt 1]
[1.0 rgbt <0.40784, 0.39216, 0.18431,0.1>]
}
poly_wave PW
}
finish{
ambient 0
diffuse 0.6
}
normal{
slope y
normal_map{
[0.50 granite 0]
[1.00 granite 0.2 scale 1/10]
}
}
}
#declare M1=
material{
texture{TChrome}
texture{TRust}
texture{TDusty}
interior{ior 15}
}
-tgq
Post a reply to this message
|
![](/i/fill.gif) |