I haven't gotten to play with Pov much at all for a long time. :-(

I wanted to play with photons, so I added a shiny box. :-)



#default {finish {ambient 0}}

// global_settings + photons added by William
global_settings {
  photons {
    count 10000
    autostop 0
    jitter 0
  }
}
// end global_settings

// Begin additions by Yadgar

#declare s1=seed(1979);

#declare Silver_Ball=
sphere
{
   0, 0.04
   texture
   {
     pigment { color rgb 0.75 }
     finish { brilliance 0.7 diffuse 1 reflection 0.5 specular 0.8
roughness 0.001 }
   }
}

// End additions by Yadgar

camera {
  location <-5,10,-20>
  look_at 0
}

light_source {
  <1,1,-1>*10 color rgb 1
  spotlight point_at y*3  radius 15 falloff 25
  area_light  x*2,y*2,25,25 circular    orient    adaptive 0
  photons {
    reflection on
  }
}

plane {
  y, 0
  pigment {checker color rgb 2, color rgb 0.5 scale 2}
  finish {specular 1 reflection 1/3}
}

#macro rubber(col)
  texture {
    pigment {color col}
    finish {specular 1/4}
    normal {bumps 1/50 scale 1/100}
  }
#end

sphere {<0,3,0>, 3  rubber(rgb x)}
sphere {<4,2,-3>, 2 rubber(rgb x+y)}
sphere {<-2,1,-4>, 1  rubber(rgb z)}

// Box added by William
box {
  <0, 0, 0>
  <1, 1, 1>
  rotate y * 45
  translate z * -4
  texture
  {
     pigment { color rgb 0.75 }
     finish {
      brilliance 0.75
      diffuse 0.75
      reflection 0.75
      specular 0.75
      roughness 0.001
    }
  }

  photons {
    target
    reflection on
    collect on
  }
}

// End of William's box

// Begin additions by Yadgar

#declare n=0;

#while (n<1800)
   #declare r1=rand(s1)*360;
   #declare r2=asin(rand(s1)*2-1);
   object { Silver_Ball translate <0, 3, 0>+3*<sin(r1*(pi/180))*cos(r2),
sin(r2), cos(r1*(pi/180))*cos(r2)> }
   #declare n=n+1;
#end

#declare n=0;

#while (n<800)
   #declare r1=rand(s1)*360;
   #declare r2=asin(rand(s1)*2-1);
   object { Silver_Ball translate <4, 2,
-3>+2*<sin(r1*(pi/180))*cos(r2), sin(r2), cos(r1*(pi/180))*cos(r2)> }
   #declare n=n+1;
#end

#declare n=0;

#while (n<200)
   #declare r1=rand(s1)*360;
   #declare r2=asin(rand(s1)*2-1);
   object { Silver_Ball translate <-2, 1, -4>+<sin(r1*(pi/180))*cos(r2),
sin(r2), cos(r1*(pi/180))*cos(r2)> }
   #declare n=n+1;
#end

// End additions by Yadgar

Post a reply to this message

Attachments:
Download 'pingpong.png' (71 KB)

Preview of image 'pingpong.png'