Hello.  I've enjoyed povray off and on for a few years but never posted.
Lately, I've been enjoying all the images everyone has here and thought I'd
add a few of my own.  These where for the last irtc theme, absence, but I
never got around to sending them.

The first one, attached here, is a simple bit of negative space fun.

#version 3.6;

//+w640 +h240 +a0.03

#declare blur_on = true;
#declare color_on = true;

// ----------------------------------------

global_settings {
  assumed_gamma 1.0
}

#default {
 texture {
  pigment {
   color rgb 1
  }
  finish {
   ambient 0
   diffuse 1
  }
 }
}

// ----------------------------------------

camera {
 angle 35
 location <0.0, 0.0, -5.0>
 direction 1.5*z
 right x*image_width/image_height
 look_at <0.0, 0.0,  0.0>

 #if(blur_on=true)
  aperture 1
  variance 1/1000000
  confidence 0.999
  blur_samples 10
  focal_point <0.0, 0.0, 0.0>
 #end
}

// ----------------------------------------

#declare word =
 text {
  ttf "times.ttf" "Absent" 2, 0
 }
#declare word_min=min_extent( word )-<0.25,0.25,0>;
#declare word_max=max_extent( word )+<0.25,0.25,0>;

#declare word_scale = word_max-word_min;
#declare word_offset = word_min;

#declare R = seed( 213 );

union {
 #declare i = 0;
 #while (i < 25000)
  #local X = word_offset.x + word_scale.x*rand(R);
  #local Y = word_offset.y + word_scale.y*rand(R);
  #local Z = word_offset.z + word_scale.z*rand(R);

  #if (!inside( word, <X, Y, Z> ))
   box {
    <-1, -1, -1>
    < 1,  1,  1>
    scale 0.002 + 0.018*rand(R)
    rotate <0, 30 - 60*rand(R), 30 - 60*rand(R)>
    translate <X, Y, Z>
    #if (color_on = true )
     pigment { rgbt <0.25, 0.25+0.5*rand(R), 0.75+0.25*rand(R), 0> }
    #end
   }
  #end

  #declare i = i + 1;
 #end

 #if (color_on = false )
  pigment { rgbt <0.25, 0.75, 1.0, 0.9> }
 #end

 translate <-word_offset.x - word_scale.x/2.0, -word_offset.y -
word_scale.y/2.0, 0>
}

light_source {
 <0, 0, -10>
 1.0

 shadowless

 fade_distance 10.0
 fade_power 100
}

Post a reply to this message

Attachments:
Download 'spelling_boxes.jpg' (111 KB)

Preview of image 'spelling_boxes.jpg'