> Whatever techniques you're using,

Fairly straightforward use of df3 media, the key of course being the
mummy16.df3, 16 bit (short int) data converted from the DICOM slices.

#declare BRIGHT = 0.02;
#declare theinterior = interior {
   media {
      intervals 100
      ratio 0.5
      samples 4,4
      method 2
      emission BRIGHT * <1,1,1>
      absorption <0,0,0>
      scattering { 1, <0,0,0> }
      confidence 0.999
      variance 1/1000
      density {
         density_file df3 "mummy16.df3"
         interpolate 1
         color_map {
            [ 0.00 rgb <0,0,0> ]
            [ 0.20 rgb <0,0,0> ]
            [ 0.40 rgb <1,1,0> ]
            [ 0.60 rgb <1,0,0> ]
            [ 1.00 rgb <1,1,1> ]
         }
      }
   }
}

box {
   <0,0,0>, <1,1,1>
   hollow
   pigment { rgbt 1 }
   interior { theinterior }
   translate <-0.5,-0.5,-0.5>
   scale <NX,NY,-NZ>
   rotate <0,0,THETAZ>
}

-------------------------------------
P a u l   B o u r k e
http://local.wasp.uwa.edu.au/~pbourke/

Post a reply to this message