Hi all!

Here is a simple scene with photons and dispersion for a simple shape made
of glass. The dispersion coefficient is high (1.035) in order to produce a
desired exagerated effect.

I have one concern with this result: the shadow of the shape on the ground
does not seem to be anti-aliased. What's up?

I also see bandings and white spots near the Sphere/cylinder edge on the
shadow. Numerical artifacts for the latter, and too few photons for the
former?

The render time is about 1:15 hours, mainly taken by the shape, on Win, P4,
2.8 GHz for 1024*768 resolution.

The code is short so I can put it hereafter.

Comments and suggestions welcome.

    Regards.

         Bruno.

// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.5
// Desc: Basic Scene Example
// Date: mm/dd/yy
// Auth: ?
//

#version 3.5;

#include "colors.inc"
#include "stones.inc"


global_settings {
  assumed_gamma 1.0
  max_trace_level 20
  photons
  {
     spacing 0.003
  }
}

// ----------------------------------------

camera {
  location  <0.0, 0.5, -4.0>
  angle 50
  right     x*image_width/image_height
  look_at   <0.0, 0.,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 35, 30>
  photons
  {
    reflection on
    refraction on
  }
}

// ----------------------------------------

plane {
  y, -1
  pigment {rgb 0}
  normal {bozo 0.5 scale 0.0001}
  finish {specular 0.4 roughness 0.1}
}

merge
{
  sphere {0, 1}
  cylinder {0, 2*y, 0.25}
  sphere {2*y, 0.3}
  texture {
    pigment {rgbt 1}
    normal {bozo 0.75 scale 0.2}
    finish{
      specular 0.8 roughness 0.015
      reflection {0.2, 0.5 fresnel}
      conserve_energy
    }
  }
  interior
  {
    ior 1.3
    fade_color Green fade_power 1001 fade_distance 2
    dispersion 1.035 dispersion_samples 30
  }
  photons
  {
    target 1
    reflection on
    refraction on
    collect off
  }
  rotate 180*z
  rotate 60*z
  rotate -20*y
  translate <-1, 0.5, 3>
  //no_image
}

Post a reply to this message

Attachments:
Download 'photons_1.jpg' (174 KB)

Preview of image 'photons_1.jpg'