|
|
Artemia Salina <y2k### [at] sheayrightcom> wrote:
> On Tue, 18 Jul 2006 14:53:17 -0400, Trevor G Quayle wrote:
>
>
> > Depending on how you make the thing, you could add a slime layer
>
> Oh man, that is great! How did you do that? I'm guessing that it's a
> second, larger semi-translucent blob over the four white spheres?
>
> The creature (except for the eyeballs) is made of blobs with many
> small spherical components. I suppose I could re-work the code so
> as to make two copies of the creature's body, one slightly larger than the
> other, and use the larger one as the slime layer. That method would also
> allow me to experiment with having the slime drip off of the creature by
> adding components to the slime layer.
>
Yes it's blobs over spheres. The trick is to get the blobs so they are only
slightly larger than the underlying sphere over the main surface, but
thicker over the crevices. Code follows:
//START
global_settings {
assumed_gamma 1.0
ambient_light 1
adc_bailout 0.001
max_trace_level 10
}
camera {
location <1,2,-3>
look_at 0
}
#declare LB=
sphere{0 50 hollow no_image
texture{pigment{rgb 1} finish{ambient 20}}
}
light_source{0 rgb 1
looks_like{LB}
fade_power 2 fade_distance 300
translate <-100,100,-100>
}
union{
sphere{<-0.75,0,0> 1}
sphere{< 0.75,0,0> 1}
sphere{< 0,0,-0.5> 1}
sphere{< 0,0,0.5> 1}
material{
texture{
pigment{rgb 0.85}//rgb <0.038, 0.033, 0.202>
finish{ambient 0
conserve_energy
diffuse 0.4// brilliance 0.52
reflection{0 1 fresnel on metallic 0}
}
}
interior{ior 1.33}
}
}
blob{
threshold 0.12 //blob only ~0.01 units bigger than spheres
sphere { <-0.75,0,0>, 1.25, 1}
sphere { < 0.75,0,0>, 1.25, 1}
sphere { < 0,0,-0.5>, 1.25, 1}
sphere { < 0,0, 0.5>, 1.25, 1}
hollow
material{
texture{
pigment{rgbf 1} //texture clear, using interior only
finish{ambient 0
conserve_energy
diffuse 0.0
reflection{0 1 fresnel on metallic 0}
}
normal{bumps 0.2 scale 1/20}
}
interior{
caustics 0.1
ior 1.56
fade_distance 0.0075
fade_power 1001
fade_colour rgb <0.80784, 0.90588, 0.61176> //slime colour
}
}
}
plane{y, -1
material{
texture{
pigment{rgb 0.8}
finish{ambient 0
conserve_energy
diffuse 0.6
}
}
}
}
//END
-tgq
Post a reply to this message
|
|