> Awesome... shows me how long a way I still have to go! But how long did
> it take to render?
>

Rendered in 2min 14s at 512x384 on a 1.8GHz P4 (no antialiasing).
Antialiasing slows it down quite alot, depending on settings.
I think the version I posted took about 8min with +am1 +a0.3

Here is the code:

// Asteroid
#version 3.6;
// ==============================================================
#default{finish{ambient 0}}
#global_settings{assumed_gamma 1.0 max_trace_level 5}

#declare f_bozo1 = // similar to noise3d
function{
  pigment{
    bozo
    noise_generator 3
    scale 0.35
    turbulence 0.30
    color_map{
      [0 color rgb 0]
      [1 color rgb 1]
    }
  }
}

#declare f_craters =
function{
  pigment{
    crackle form <1.2, 0, 0> // never really played with this one, thaks
Yadgar!
    turbulence 0.1 omega 0.6
    scale 0.15
    color_map{
      [0.00 color rgb 1.00] // centre of crater, lowest part
      [0.25 color rgb 0.75]
      [0.33 color rgb 0.25]
      [0.40 color rgb 0] // crater rim
      [1.00 color rgb 0] // level of area outside the crater
    }
  }
}

#declare f_granite =
function{
  pigment{
    granite
    scale 0.08
    color_map{
      [0 color rgb 0]
      [0.5 color rgb 0]
      [1 color rgb 1]
    }
  }
}

// --------------------------------------------------------------
isosurface{
  function{
    (x*x)+(y*y*2.2)+(z*z*1.5)-1
    +f_bozo1(x,y,z).red*0.300
    +f_craters(x,y,z).red*0.030
    +f_craters(x*2,y*2,z*2).red*0.020
    +f_granite(x,y,z).red*0.01
  }
  contained_by{box{<-1, -1, -1>, <1, 1, 1>}}
  threshold 0
  accuracy 0.005
  max_gradient 7.5
  texture{
    pigment{color rgb 1}
    finish{diffuse 1 brilliance 2}
  }
}

light_source{<-10, 10, 5> color rgb 1.5}
light_source{< 10, -10, -5> color rgb<0.2, 0.5, 1.0>*0.15}

camera{
  location <0, 1, -4>
  up y*(image_height/image_width)
  right x
  sky y
  look_at <0, 0, 0>
  angle 36
}
// -------------------------------------------------- end of file

Post a reply to this message