"Sven Littkowski" <sve### [at] jamaica-focuscom> wrote:
> Hello Mike,
>
> thanks for your help and advice, and examples. I already read your own
> thread where you placed entire planets on your giant-sized patio (which I
> like, actually) and posted there a similar question.
>
> Do you know any way to create clouds like on the photo below with POV-Ray?
> And that blueish shine at the horizon?
>
> True thanks for your link, my browser has it open already. I am checking
> them today and tomorrow.
>
> Later,
>
> Sven
>
>

Hi Sven,

As for the blue shine, try this.  Unfortunately, the clouds look nothing
like your picture.  I think it would be difficult to reproduce the 3D
texture seen in the picture.  Although, you could try some layered spheres
with slightly different textures and normal maps.  That might do the trick.

Good luck,
Mike


// Planet
sphere{<0,0,0>,2000
  texture { agate
  texture_map{
      [0 pigment { color rgb <0,0,0.5>}  finish { ambient 0.2 diffuse 0.1 }]
      [0.45  pigment { color rgb <0,0,0.5>}  finish { ambient 0.2 diffuse
0.1 }]
      [0.5 pigment { color rgb <0.52,0.32,0.16>}  finish { ambient 0.2
diffuse 0.1 }]
      [0.56 pigment { color rgb <0.52,0.32,0.16>}  finish { ambient 0.1
diffuse 0.1 }]
      [0.7  pigment {
             granite
             color_map {
               [0 color rgb <0.12,0.32,0.16>]
               [0.5 color rgb <0.12,0.32,0.16>]
               [1 color rgb <0.42,0.22,0.16>]
             } turbulence 0.5 scale 0.5
             }
             finish { ambient 0.1 diffuse 0.1 }
             ]
    }  turbulence 0.3
   scale 200
  }
  rotate 40*x
}

//Clouds

sphere{<0,0,0>,2005
  texture { agate
  texture_map{
      [0 pigment { color rgbt 1}  ]
      [0.2 pigment { color rgbt 1}  ]
      [0.9  pigment { color rgbt <1,1,1,0>} finish { ambient 0.3 diffuse 0.5
}]
    }  turbulence 0.8
   scale 200
  }
  rotate 90*x
}

// Atmosphere

sphere{<0,0,0>,1
  pigment{
    color rgbt <1,1,1,1>
  }
  hollow
  interior {
   media {    // atmospheric media sample
    intervals 10
    emission 0.75
    density{
      spherical
      color_map {
        [0 rgb <0,0,0>]
        [1 rgb <0.1,0.1,0.5>]
      }
    }
    samples 1, 10
    confidence 0.9999
    variance 1/1000
    ratio 0.9
   }
  }
  scale 2035
}

Post a reply to this message

Attachments:
Download 'earth_atmosphere.jpg' (10 KB)

Preview of image 'earth_atmosphere.jpg'