hey, man, call me old fashioned, but i still believe textured bricks have a
lot going for it. :)

Your post has challenged me to produce an impacting textured brick wall.
Hope you guys like it...


code:

camera { location .6*<-4.1,4.3,-4.1> look_at <-.8,1.6,0> angle 20 }

light_source { <-2,1.6,-.4>*10 1 }
light_source { <-.2,3.4,-4>*12 .7
 area_light 3*x,3*y,3,3 adaptive .0001 jitter
}


#declare n_brick_wall =
normal { brick
 normal {brick normal{ granite .3 }, normal{ gradient y } bump_size 2.4 },
 normal { average
  normal_map {
   [1.1 granite bump_size -.6 ramp_wave scale .32]
   [.9 bumps bump_size .7 turbulence .6 scale .62]
   [1.4 quilted control0 .2 control1 .2 bump_size 4.8 scale <8,3,3.8> warp {
repeat 3*y offset x*4} ]
  }
 }
 mortar .2
 bump_size 2.4
}

#declare p0 = pigment { rgb .8 }
#declare p1 =
pigment { bozo
 color_map {
  [0 rgb 1]
  [.46 rgb <.95,.68,.71>]
  [1 rgb .8*<.94,.64,.59>]
 }
 turbulence 1.8 scale 6
}

#declare t_brick_wall =
texture {
 pigment { brick pigment { p0 }, pigment { p1 } mortar .34 turbulence .1 }
 normal { n_brick_wall turbulence .071 }
 finish { ambient .32 diffuse .34 specular .3 roughness .28 }
 scale .05
}

box { -.5,.5 scale <2.4,2,.2>
 texture { t_brick_wall }
 translate y
}

plane { y,0 pigment { rgb .9 } finish { ambient .3 diffuse .4 }}

Post a reply to this message

Attachments:
Download 'brickwall.jpg' (105 KB)

Preview of image 'brickwall.jpg'