Verm <pov### [at] thirteeendynucom> wrote:
> Bruno Cabasson wrote:
> > Hi there!
> >
> > I am hanging around the newsgroups since a while. It is time for me to make
> > my  RSCOP contribution. Here is an attempt. It could be named "H + 1
> > microsecond".
>
> Pretty. What are the spikes ? media or translucent cylinders?
>
> Two points....
> File size - if you'd jpeg compressed the image it could have been 30KB
> not 700+KB and you'd not have lost any noticable image quality. Some
> people feel quite strongly about this especially if they're not on
> broadband. My connections are 1Mb/sec at home and *far* faster at work
> so I'm not ppersonally bothered by download speed but the newsgroup
> server only has limited space.
>
> Secondly my newsreader (Thunderbird) has a bug where it confuses threads
> with the same name so I'd appreciate it if people came up with more
> descriptive (and hopefully unique) titles than "RSOCP" or "IRTC WIP". I
> know it's a bug in my newsgroup client but its probably generally a nice
> idea to give more descriptive names regardless.
>
> Anyway welcome to the group, and don't let the above two comments put
> you off (just try to keep file sizes down a tad.)
>
> Happy POVing
>
> Verm

OK. Next posts will be jpeg.

The spikes are true media effect: the sphere has an internal light_source
and the light comes throught the holes of the cracked sphere, which is
sourrounded by scattering media. BUT, in order to have well-defined
'spikes' I had to increase media samples up to 200 (yes, two hundred), and
only one interval.

Here is the code for the sphere:

// ------------------------------------------------------------------
#declare THICKNESS = 0.01; // Thickness of the sphere
#declare THRESHOLD = 0.03; // Threshold for the crackle pattern

#declare CM_Incandescent = color_map
{
    [0 White]
    [0.1 Yellow]
    [0.2 Coral]
    [0.3 Orange]
    [0.4 Red]
    [0.5 VioletRed]
    [0.6 Light_Purple]
}


#declare P_Crackle = pigment {crackle scale 0.5 turbulence 0.15 omega 0.5
color_map {[0 rgb 0][THRESHOLD rgb 0][1.1*THRESHOLD rgb 1]}}
#declare fn_Crackle = function {pigment{P_Crackle}}
#declare FOUND_MAX_GRADIENT = 20;
#declare MIN_FACTOR = 0.6;
#declare O_BaseSphere = isosurface
{
    function {f_sphere (x,y,z, (1-THICKNESS)) -
THICKNESS*fn_Crackle(x,y,z).red}
    max_gradient 20
    evaluate FOUND_MAX_GRADIENT*MIN_FACTOR,
sqrt(FOUND_MAX_GRADIENT/(FOUND_MAX_GRADIENT*MIN_FACTOR)), 0.7
    contained_by {sphere {0, 0.9999}}
}


#declare O_CrackedSphere = difference
{
    object {O_BaseSphere}
    sphere {0, 1.001*(1-THICKNESS)}
}


#declare O_Media = sphere
{
    0, 1
    pigment {rgbt 1}
    hollow
    interior
    {
        media
        {
            intervals 1 samples 200
            scattering {1, White}
            density {spherical color_map {CM_Incandescent}}
            density {spherical turbulence 0.2}
            density {spherical}
         }
    }
}

#declare O_ExplodingSphere = union
{
    object {O_CrackedSphere}
    object {O_Media scale 2}
}
// ------------------------------------------------------------------

I am curently rendering another try with radiosity and partially reflective
ground, and I'll post it as jpg.

   Cheers.

Post a reply to this message