"fls13" <fls### [at] netzeronet> wrote:
> Great job! Mind posting the code to your light setup?

Thanks. This is my light/radiosity setup so far, I know I'm going to add
more lights, so it's likely I'll have to adjust it.

// start of code

#local RAD = 1; // 0 = no radiosity,   1 = save,   2 = load
// render a small image with no anti-aliasing in pass 1, full size and aa in
pass 2

global_settings{
 assumed_gamma 1.8 // not physically correct, I know, but works best in my
workflow
 #if ( RAD > 0 )
  radiosity {
   #if ( RAD = 1 )
    error_bound 0.5 // decrease for better accuracy
    count 50 // increase for better accuracy
    recursion_limit 2
    low_error_factor 1
    always_sample off
    save_file "radiosity.rad"
   #else
    error_bound 1 // * 2 or * 4 of error_bound in pass 1
    recursion_limit 2
    load_file "radiosity.rad"
    pretrace_start 1
    pretrace_end 1
    low_error_factor 1
    always_sample off
   #end
  }
 #end
}
#local CeilingLight = light_source { // one in each room
 <0, 390, 0>
 color rgb <1, 1, 1> * 7.5
 area_light
 <40, 0, 0> <0, 0, 40>
 2, 2
 adaptive 0
 jitter
 fade_distance 50
 fade_power 2
}

sky_sphere { // for diffuse light from the sky
 pigment {
  gradient y
  color_map {
   [0.0 color rgb <0.8, 0.933, 1.0> * 7.5 ]
   [0.7 color rgb <0.42, 0.467, 0.7> * 7.5 ]
  }
 }
}

#local Sun = light_source { // not correct size and shape of the sun!
 <20000, 14000, 0>
 color rgb <0.8, 0.933, 1.0> * 1.5
 area_light
 <0, 2000, 0> <0, 0, 2000>
 3, 3
 adaptive 0
 jitter
 // should have added circular keyword here
}

// end of code

The rooms are approx. 400 by 400 units, 400 units high. There's a window in
the middle room, letting in the sunlight.

H

Post a reply to this message