"Cousin Ricky" <ric### [at] yahoocom> wrote:

> Speaking of versatile, how did you get such a shiny texture with the black
> background?  Are the fill lights part of technique?  (I can tell you used
> several.)

I used invisible sphere with special texture, to be reflected where nothing
located. While in real whorld we have a lot of background objects, which
are reflected by our main object, in CG we often have to use some trick to
provide some enfironment. May be, the piece of code will be better than a
long explanation, expecially remembering about my bad English. So, look at
this small
scene:

-----------------------------
sphere{0,1000
 texture{
  pigment{
   gradient y color_map{
    [0,color rgb <0.8,0.83,1>]
    [1,color rgb <0.4,0.7,1>]
    }scale 2 translate -y}finish{ambient .4 diffuse .8}scale 1000}

texture{
 pigment{average pigment_map{
 #declare gr=.8;
 #declare ge=3.5/(1+gr+gr);
 #declare t1=.1;
 #declare t2=.9;
 #declare tr1=-.5;
 #declare tr2=0;
  [1,bozo translate .3*y color_map{
   [t1,color rgbt < 1,gr,gr,tr1>*ge]
   [t2,color rgbt < 0, 0, 0,tr2>*ge]
  }]
  [1,bozo translate .3*z color_map{
   [t1,color rgbt < gr, 1,gr,tr1>*ge]
   [t2,color rgbt <  0, 0, 0,tr2>*ge]
  }]
  [1,bozo translate .3*x color_map{
   [t1,color rgbt < gr,gr, 1,tr1>*ge]
   [t2,color rgbt <  0, 0, 0,tr2>*ge]
  }]

 }}scale 0.25 finish{ambient .2 diffuse .8 brilliance 1.5}scale 2500}

 no_shadow
 no_image
 //no_reflection
 hollow double_illuminate scale 100}

#declare st=texture{pigment{color rgb<0.83,0.82,0.84>*1.2}
  finish{diffuse 0.2 ambient 0 specular 1.5 roughness 0.02 phong .5
phong_size 80
   reflection{0.6,1.0 metallic}
   }
  }

torus{1,.15 texture{st} rotate -30}

light_source{
 -10*z, color rgb <0.6,0.8,1.0>*1.25*.8
 parallel
 rotate x*15 rotate -y*25
 }

light_source{
 -10*z, color rgb <0.6,0.8,1>*1.0*.4
 parallel
 rotate x*45 rotate y*145
 }

light_source{
 -10*z, color rgb 0.5*.8
 parallel
 rotate x*15 rotate y*75
 }


camera{
 location -5*z
 look_at 0
 }
-----------------------------
Sincerely Yours,
Alex  Kluchikov.

Post a reply to this message