"Dre" <bla### [at] somewherecom> wrote:
> :-O WOW!
>
> Is there any chance at taking a peek at the code to that, I'm stunned!
>
> Cheers Dre

np.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
#default {finish {ambient 0 diffuse 0.25}}

camera {
  location <0,0,6>
  look_at 0
}

light_source {
  <0,.5,0>  color rgb <2,-.5,-.5>*5
  rotate x*60
  fade_distance 1.5 fade_power 2
}
light_source {
  <0,.5,0>  color rgb <-.5,2,-.5>*5
  rotate x*60 rotate z*-120
  fade_distance 1.5 fade_power 2
}
light_source {
  <0,.5,0>  color rgb <-.5,-.5,2>*5
  rotate x*60 rotate z*120
  fade_distance 1.5 fade_power 2
}

#declare p_Blah=
  pigment{
    leopard
    color_map{
      [0 color rgb 1]
      [1 color rgb 0]
    }
    scale .5
    turbulence .5
    octaves 6
    omega 2
    lambda .9
  }
#declare fn_Blah=function {
    pigment {
      p_Blah
    }
  }

isosurface{
  function {sqrt(pow(x,2) + pow(y,2) + pow(z,2)) - 2 +
fn_Blah(x,y,z).gray*.1}
  contained_by{sphere{0,2.5}}
  max_gradient 6.7
  pigment{p_Blah}
  no_shadow
  double_illuminate
  rotate y*60
}
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

Nothing too spectacular.  To get the second one just reverse the color_map
colors and subtract the fn_Blah instead of adding it to the isosurface.

Post a reply to this message