> I find the textures with the worn edges extremely impressive ! Do you
> mind showing an example of your slope texture ?
>
> Thibaut

Thank you for your comments. I appreciate it. Here is a sample of the
texture.


#macro WornWood(RGB,WearFlat,WearEdge,Norm,Rot,Tran)
        #declare Texture1 =
                texture {
                        pigment {
                            wood
                            turbulence <0.1, 0.5, 1>
                            octaves 5
                            lambda 3.25
                            scale <0.15, .5, 1>
                            rotate <5, 10, 5>
                            translate -x*2

                                color_map {
                                    [0.0 color RGB]
                                    [0.1 color RGB]
                                    [0.1 color 0.95*RGB]
                                    [0.9 color 0.95*RGB]
                                    [1.0 color RGB]
                                }


                        }
                        finish{
                                ambient 0
                                phong 0.35
                                phong_size 100

                        }
                }

        #declare TWood1 =
                        texture{T_Wood7}
                        texture {
                                pigment{color rgbt <255, 155, 23,
0.999999*256>/256*0.25}
                        }
        #declare TWood2 =
                        texture{T_Wood7}
                        texture {
                                pigment{color rgbt <255, 155,
23,1.5*256>/256*0.45}
                        }

        #declare PaintedWood1 =

          texture{
            bozo
            texture_map{
              [0 TWood1]
              [WearFlat TWood2]
              [WearFlat+0.1 Green1]
              [1.0 Green1]
            }

            warp{turbulence 0.2}
            scale <0.25,0.25,50>
          }

        #declare PaintedWood2 =

        texture{
                bozo
                texture_map{
                        [0 TWood1]
                        [WearEdge TWood2]
                        [WearEdge+0.1 Texture1]
                        [1.0 Texture1]
                }

                warp{turbulence 0.2}
                scale <0.25,0.25,50>
        }

         #declare DummyNum =0;

         texture{
                slope { <0,-1,0> }
                    texture_map{
                      [0 PaintedWood1]
                      //[0.1 PaintedWood1]
                      [0.1 PaintedWood2]
                      //[0.4 PaintedWood2]
                      [0.4 PaintedWood1]
                      [0.6 PaintedWood1]
                      [0.9 PaintedWood2]
                      //[0.9 PaintedWood2 ]
                      [1.0 PaintedWood1]
                    }
                warp{turbulence 0.2}
                                rotate Rot
                translate Tran
         }



#end

Hope this helps.

Tim

Post a reply to this message