OK, I thought I'd post an example of a media with fine structure.  This one
has even more than that used above, but it's just for illustrative purposes
since you asked.  Below is the SDL for the attached image.  No lights.  The
media uses default sampling etc and there are some artifacts in the image,
but you get the idea.  The scalings are set so that if you change the value
of T you get a nice scaling of the turbulence and brightness.  T=0 gives a
plain spherical distribution, and values over about 2 start to fade away
and break apart to nothing.  This could be animated with T=clock between 0
and about 4, but I haven't tried it so I don't know what it would come out
like.



#declare T = 1;

camera {
  location <0,0,-8>
  look_at 0
  angle 80
}


sphere {
  0,10
  texture {
    pigment { rgbt 1 }
  }
  interior {
    media {
      emission exp(-T/2)
      density {
        spherical
        poly_wave 5
        color_map {
          [0 rgbt <0,0,0,1>]
          [0.1 rgb <0.2,0,0>]
          [0.27 rgb <1,0.65,0.5>]
          [1 rgb <2,2,0.5>]
        }
        scale 2
        warp { turbulence T }
        scale 2
        warp { turbulence T }
        scale 2
        warp { turbulence T }
        scale 2
        warp { turbulence T }
      }
      scale 0.3*exp(pow(T,0.5))/(1+T)
    }
  }
  hollow
}


The real point is the multiple scale/warp levels.  That is where the fine
structure is added to the turbulence - it gives a fairly scale-free
turbulence, and can be tweaked for different effects.

Hope this helps.

L
-

Post a reply to this message

Attachments:
Download 'finestructure.jpg' (206 KB)

Preview of image 'finestructure.jpg'