|
|
Here's a chocolate shell, with a bit too much white chocolate for my taste.
:) Scene file may not exactly match image...
//POV-Ray 3.1+ Scene File. Classic Pickover shell.
global_settings{max_trace_level 9 assumed_gamma 1}
//Textures
#declare Clear = rgbf 1;
#declare DarkChoc = rgb <.165, .050, .0> * .45;
#declare LiteChoc = rgb <.925, .92, .7> * .9;
#declare CLite =.35;
#declare CFade =.05*1.5;
#declare ChocSwirl =
pigment{
bozo
scale 1.15
turbulence 0.425
translate <-3,4,5>
color_map{
[0 DarkChoc]
[CFade LiteChoc]
[CFade+CLite LiteChoc]
[2*CFade+CLite DarkChoc]
}
}
#declare CLite =.10;
#declare CFade =.20;
#declare ChocSwirlTrans =
pigment{
bozo
phase .05
translate <30,-40,-50>
scale 1.35
warp{turbulence 0.55}
color_map{
[0 Clear]
[CFade LiteChoc]
[CFade+CLite LiteChoc]
[2*CFade+CLite Clear]
}
}
#declare ChocShine =
finish{
specular .1 roughness 5e-2
phong .35 phong_size 360
reflection{ .015 }
//metallic
diffuse .725 ambient 0.05
}
#declare ChocSwirlT0 =
texture{
//pigment{blue .65}
//pigment{DarkChoc}
pigment{ChocSwirl}
finish{ChocShine}
}
#declare ChocSwirlT1 =
texture{
pigment{ChocSwirlTrans}
finish{ChocShine}
}
#declare N=99;#declare K=.75;#declare A=-2;#declare D=(11/3-A)/N;
#declare B=.15;#declare C=.35/B;
#declare Shell = union{#declare I=1;#while(I<=N)
#declare T=I/N;#declare TH=A*2*pi;#declare R=B*exp(A*K);
sphere{<R*cos(TH),R*sin(TH),C*R>,R}#declare I=I+1;#declare A=A+D;
#end
}
object{
Shell
//rotate x*8 translate<-4,4,10>
//Layered texture
texture{ChocSwirlT0}
texture{ChocSwirlT1}
}
light_source{<2,1.5,-8>rgb 1.45}
plane{y,-9 pigment{checker rgb 0 rgb 1 scale 5 rotate 45*y}
finish{reflection 1 ambient 0.075 diffuse .65}rotate -x*35}
//-----------------------------------------------
Post a reply to this message
Attachments:
Download 'shellquick7c.png' (230 KB)
Preview of image 'shellquick7c.png'
|
|