Neil,

It's really very simple, they're just the difference of a cylinder and an
isosurface.

#include "functions.inc"

#declare Column =
 union {
  box { <-0.625*ft, 0.0, -0.625*ft> <0.625*ft, 0.125*ft, 0.625*ft> }
  difference {
   box { <-0.5*ft, 0.125*ft, -0.5*ft> <0.5*ft, 2.0*ft, 0.5*ft> }
  #local cBd = 0 ;
  #while(cBd < 360)
   union {
    box { <-0.375*ft, 0.25*ft, -0.4375*ft> <0.375*ft, 1.875*ft, -0.53125*ft>
}
    box { <-0.28125*ft, 0.34375*ft, -0.375*ft> <0.28125*ft, 1.78125*ft,
-0.53125*ft> }
     rotate cBd*y
    }
  #local cBd = cBd + 90.0 ;
  #end
   }
  box { <-0.625*ft, 2.0*ft, -0.625*ft> <0.625*ft, 2.125*ft, 0.625*ft> }
  difference {
   cylinder { <0.0, 2.0*ft, 0.0> <0.0, 6.875*ft, 0.0> 0.5*ft }
   isosurface {
    function { f_helix1(x,y,z,3,0.34375,0.375*ft,0.78125*ft,1,1,0) }
    max_gradient 1.009
    threshold 0
    contained_by { box { <-0.625*ft, 1.875*ft, -0.625*ft> <0.625*ft,
7.125*ft, 0.625*ft> } }
    max_trace 3
    }
   }
  box { <-0.625*ft, 6.875*ft, -0.625*ft> <0.625*ft, 7.0*ft, 0.625*ft> }
   texture { T_Stone11 }
   texture { T_Grnt23a }
    photons { target reflection on refraction on }
  }

I absolutely love using spirals in my columns, I have another interesting
setup in my fountain image:

[ http://speedy.sdsmt.edu/~1305761/images/Art/Fountain5.jpg ]

the instructions for using the spiral are in functions.inc but I'll warn you
there was some trial and error involved in getting the columns to look
right.

ADB

"Neil Kolban" <kol### [at] kolbancom> wrote:
> ADB,
> I'm a newbie and am trying to learn as fast as I can.
>
> How did you make the spiral in the columns?  I am still at CSG theory and
> not much beyond that.  I can just about imagine how all else in the picture
> may have been done but, for the life of me, I can't imagine how you carved
> the columns... can you help?
>
> Neil

Post a reply to this message