Thanks for all the compliments!  :)

The brushed metal effect is done with the following macro:

#macro boxText( bwFlag )

 #local baseRotate = rand(seed90)*20;
 texture {
  pigment { color rgb <.85,.9,1> }
  finish { ambient .3 diffuse .5 specular 1 roughness .05 reflection .6  }
  normal { bumps .5 scale <.5,.015,.015> }
  rotate z*baseRotate
 }
 texture {
  pigment { color rgbf <1,1,1,.75> }
  finish { ambient .3 diffuse .5 specular 1 roughness .05 reflection .6 }
  normal { bumps .5 scale <.65,.015,.015> }
  rotate z*baseRotate
  rotate z*60
 }
 #if( bwFlag = 1 )
 texture {
  pigment { color rgbf <.1,.2,.4,.75> }
  finish { ambient .3 diffuse .5 specular 1 roughness .05 reflection .6 }
  normal { bumps .5 scale <.75,.015,.015> }
  rotate z*baseRotate
  rotate z*-85
 }
 #else
 texture {
  pigment { color rgbf <.85,.9,1,.75> }
  finish { ambient .3 diffuse .5 specular 1 roughness .05 reflection .6 }
  normal { bumps .5 scale <.5,.015,.015> }
  rotate z*baseRotate
  rotate z*-105
 }
 #end

#end

As you can see, it's merely using layered textures, with 'bwFlag' used to
indicate if it's a white tile or a blue tile.

--------------------
dan
Goofy Graffix - http://hometown.aol.com/goofygrafx
DanByersArt - http://www.huntel.net/goofygraffix

Post a reply to this message