On Mon, 24 Jan 2000 11:06:57 -0600, Eric Freeman wrote:
>Hey all,
>
>I'm working on a lamp that I saw in a waiting room the other day.  The
>problem is the lamp shade.  It should be opaque in that you can't see thru
>it but transparent in that it lets light out.  Is such a thing possible?  Is
>this a job for media???  I'm clueless.

As well as the other solutions others have offered, media might do the trick
if used (im)properly.  Render this and see if it approximates the effect you're
looking for.  In this case, it's not so much that the shade isn't translucent
as it is that the scattered light overwhelms anything you might see through 
the shade.  Real lampshades are like this, too, I think.

difference {
  cone {0,1,y,.75}
  cone {-.01*y,.95,1.01*y, .70}
  hollow
  texture {pigment {color rgbf <1,.9,.7,1>}}
  interior {
    media {
      scattering {2,rgb <20,18,14>}
      absorption 1
      samples 10,20
    }
  } 
}
torus { 1,.02 pigment {color rgb 0}}
torus { .75,.02 pigment {color rgb 0} translate y}

light_source { .5*y rgb 2*<1,.9,.6> }

plane {y,-1 pigment {color rgb 1}}
plane {-z,-1.01 pigment {color rgb 1}}
cylinder {-y,.2*y,.1 pigment {color red 1}}

camera { location .5*y-10*z look_at 0 }

-- 
These are my opinions.  I do NOT speak for the POV-Team.
The superpatch: http://www2.fwi.com/~parkerr/superpatch/
My other stuff: http://www2.fwi.com/~parkerr/traces.html

Post a reply to this message