POV-Ray : Newsgroups : povray.text.scene-files : Re: Cloud Surface Server Time
28 Mar 2024 20:06:17 EDT (-0400)
  Re: Cloud Surface (Message 1 to 3 of 3)  
From: Kontemplator
Subject: Re: Cloud Surface
Date: 24 Nov 2017 14:00:01
Message: <web.5a186b419a2a53c19ae32810@news.povray.org>
// PoVRay 3.7 Scene File " ... .pov"
// author:  ...
// date:    ...
//------------------------------------------------------------------------
#version 3.7;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }}
//------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
#include "stones.inc"
#include "woods.inc"
#include "shapes.inc"
#include "shapes2.inc"
#include "functions.inc"
#include "math.inc"
#include "transforms.inc"
//------------------------------------------------------------------------
#declare Camera_0 = camera {/*ultra_wide_angle*/ angle 15      // front view
                            location  <0.0 , 1.0 ,-40.0>
                            right     x*image_width/image_height
                            look_at   <0.0 , 1.0 , 0.0>}
#declare Camera_1 = camera {/*ultra_wide_angle*/ angle 20   // diagonal view
                            location  <20.0 , 15.0 ,-20.0>
                            right     x*image_width/image_height
                            look_at   <0.0 , 2 , 0.0>}
#declare Camera_2 = camera {/*ultra_wide_angle*/ angle 90  //right side view
                            location  <3.0 , 1.0 , 0.0>
                            right     x*image_width/image_height
                            look_at   <0.0 , 1.0 , 0.0>}
#declare Camera_3 = camera {/*ultra_wide_angle*/ angle 90        // top view
                            location  <0.0 , 3.0 ,-0.001>
                            right     x*image_width/image_height
                            look_at   <0.0 , 1.0 , 0.0>}
camera{Camera_1}
//------------------------------------------------------------------------
// sun -------------------------------------------------------------------
light_source{<0,100,-250> color <1,.75,.5> *2}
// sky -------------------------------------------------------------------
sky_sphere{ pigment{ gradient <0,1,0>
                     color_map{ [0   color rgb<1,1,1>         ]//White
                                [0.4 color rgb<0.14,0.14,0.56>]//~Navy
                                [0.6 color rgb<0.14,0.14,0.56>]//~Navy
                                [1.0 color rgb<1,1,1>         ]//White
                              }
                     scale 2 }
           } // end of sky_sphere
//------------------------------------------------------------------------

//------------------------------ the Axes --------------------------------
//------------------------------------------------------------------------
#macro Axis_( AxisLen, Dark_Texture,Light_Texture)
 union{
    cylinder { <0,-AxisLen,0>,<0,AxisLen,0>,0.05
               texture{checker texture{Dark_Texture }
                               texture{Light_Texture}
                       translate<0.1,0,0.1>}
             }
    cone{<0,AxisLen,0>,0.2,<0,AxisLen+0.7,0>,0
          texture{Dark_Texture}
         }
     } // end of union
#end // of macro "Axis()"
//------------------------------------------------------------------------
#macro AxisXYZ( AxisLenX, AxisLenY, AxisLenZ, Tex_Dark, Tex_Light)
//--------------------- drawing of 3 Axes --------------------------------
union{
#if (AxisLenX != 0)
 object { Axis_(AxisLenX, Tex_Dark, Tex_Light)   rotate< 0,0,-90>}// x-Axis
 text   { ttf "arial.ttf",  "x",  0.15,  0  texture{Tex_Dark}
          rotate<20,-45,0> scale 0.75 translate <AxisLenX+0.05,0.4,-0.10>
no_shadow}
#end // of #if
#if (AxisLenY != 0)
 object { Axis_(AxisLenY, Tex_Dark, Tex_Light)   rotate< 0,0,  0>}// y-Axis
 text   { ttf "arial.ttf",  "y",  0.15,  0  texture{Tex_Dark}
          rotate<10,0,0> scale 0.75 translate <-0.65,AxisLenY+0.50,-0.10>
rotate<0,-45,0> no_shadow}
#end // of #if
#if (AxisLenZ != 0)
 object { Axis_(AxisLenZ, Tex_Dark, Tex_Light)   rotate<90,0,  0>}// z-Axis
 text   { ttf "arial.ttf",  "z",  0.15,  0  texture{Tex_Dark}
          rotate<20,-45,0> scale 0.85 translate <-0.75,0.2,AxisLenZ+0.10>
no_shadow}
#end // of #if
} // end of union
#end// of macro "AxisXYZ( ... )"
//------------------------------------------------------------------------

#declare Texture_A_Dark  = texture {
                               pigment{ color rgb<1,0.45,0>}
                               finish { phong 1}
                             }
#declare Texture_A_Light = texture {
                               pigment{ color rgb<1,1,1>}
                               finish { phong 1}
                             }

object{ AxisXYZ( 4.50, 3.00, 5.00, Texture_A_Dark, Texture_A_Light)}
//-------------------------------------------------- end of coordinate axes


// ground -----------------------------------------------------------------
//---------------------------------<<< settings of squared plane dimensions
#declare RasterScale = 1.0;
#declare RasterHalfLine  = 0.035;
#declare RasterHalfLineZ = 0.035;
//-------------------------------------------------------------------------
#macro Raster(RScale, HLine)
       pigment{ gradient x scale RScale
                color_map{[0.000   color rgbt<1,1,1,0>*0.6]
                          [0+HLine color rgbt<1,1,1,0>*0.6]
                          [0+HLine color rgbt<1,1,1,1>]
                          [1-HLine color rgbt<1,1,1,1>]
                          [1-HLine color rgbt<1,1,1,0>*0.6]
                          [1.000   color rgbt<1,1,1,0>*0.6]} }
 #end// of Raster(RScale, HLine)-macro
//-------------------------------------------------------------------------


plane { <0,1,0>, 0    // plane with layered textures
        texture { pigment{color White*1.1}
                  finish {ambient 0.45 diffuse 0.85}}
        texture { Raster(RasterScale,RasterHalfLine ) rotate<0,0,0> }
        texture { Raster(RasterScale,RasterHalfLineZ) rotate<0,90,0>}
        rotate<0,0,0>
      }
//------------------------------------------------ end of squared plane XZ

//--------------------------------------------------------------------------
//---------------------------- objects in scene ----------------------------

box{ <-1,-0.5,-1>,<1,1,1>
    pigment{ rgbt 1 }
    hollow
 interior{ //-----------
 media{
  emission <.9,.9,1>*1.5
  absorption <0,0,.5>
  scattering{ 3, <1,1,1>
              extinction  2.0 }
  density{ gradient <1,.25,.5>  // controls the cloud formation
    turbulence 0.5
    frequency 5
    color_map {
     [0.0 rgb 0.0]//border
     [0.5 rgb 0.1]
     [1.0 rgb 1.0]//center
     } // end color_map
   } // end of density
  } // end of media ----
 } // end of interior


 translate <0,1,0>
 scale <5,1.5,5>
} //------- end of box

fog{ fog_type   2
     distance   2
     color      White *0.8
     fog_offset 0.1
     fog_alt    1.25
     turbulence 1.8
   } //----------------


Post a reply to this message

From: Thomas de Groot
Subject: Re: Cloud Surface
Date: 25 Nov 2017 07:14:15
Message: <5a195e97$1@news.povray.org>
Personally, I would change the cloud media to the following (in 
particular making them white; colour differences should come from the 
light and/or environment) and increase samples a bit to reduce artefacts:

box {
   <-1,-0.5,-1>,<1,1,1>
   pigment {rgbt 1}
   hollow
   interior {
     media {
       samples 10
       emission <0.9, 0.9, 1>*0.1
       absorption <1.0, 1.0, 1.0>*2
       scattering {1, <1, 1, 1>*1 extinction 1.0 }
       density {
         gradient <1, 0.25, 0.5>  // controls the cloud formation
         turbulence 0.5
         frequency 5
         color_map {
           [0.0 rgb 0.0]//border
           [0.5 rgb 0.1]
           [1.0 rgb 1.0]//center
         }
       }
     }
   }
   translate <0, 1, 0>
   scale <5, 1.5, 5>
}


-- 
Thomas


Post a reply to this message

From: Thomas de Groot
Subject: Re: Cloud Surface
Date: 27 Nov 2017 03:21:05
Message: <5a1bcaf1@news.povray.org>
My final Cloud Surface scene:


//-------------------------------------------------------------
#version 3.7;

global_settings {
   assumed_gamma 1.0
}

#default {
  finish { ambient 0.0 diffuse 1.0 }
}

//------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
//------------------------------------------------------------------------

camera {
   /*ultra_wide_angle*/ angle 20
   location  < -35.0 , 11.0 , 0.0 >
   right     x*image_width/image_height
   look_at   < 0.0 , 5.0 , 0.0 >
}

// sun -------------------------------------------------------------------
light_source {
   < 50, 100, -250 >*10e4
   color < 1.0,  0.62353,  0.46667 >*2
}

// sky -------------------------------------------------------------------
background { color rgb 0 }
/*
sky_sphere {
   pigment {
     gradient < 0, 1, 0 >
     color_map {
       [ 0.0 color rgb < 1.00000,  0.62353,  0.46667 > ] // Pink
       [ 0.4 color rgb < 0.64706,  0.30588,  0.59608 > ] // Purple
       [ 0.6 color rgb < 0.64706,  0.30588,  0.59608 > ] // Purple
       [ 1.0 color rgb < 1.00000,  0.62353,  0.46667 > ] // Pink
     }
     scale 2
   }
}
*/

// ground -----------------------------------------------------------------
disc {
  < 0, 1, 0 >, 0, 50
  texture { pigment { color rgb < 0.24706,  0.38431,  0.058824 > *1.0 }
  finish {diffuse 1.0 } }
  rotate< 0, 0, 0 >
}

//--------------------------------------------------------------------------
//---------------------------- objects in scene ----------------------------
#local Scale = 5;

//cloud layer:
cylinder {
   < 0.0, 0.0, 0.0 > < 0.0, 0.45, 0.0 > 10.0
   pigment {rgbt 1}
   hollow
   interior {
     media {
       samples 20
       absorption <1.0, 1.0, 1.0>*1/Scale
       scattering {1, <1, 1, 1>*1.5/Scale extinction 1.0 }
       density {
         ripples   // controls the cloud formation
         color_map {
           [0.5 rgb 0.02]
           [0.5 rgb 1.00]
         }
         scale <3, 1, 10>*0.5
         warp {turbulence <2.5, 1.0, 1.6>}
         rotate 45*y
       }
     }
   }
   scale Scale
   translate <0, 1, 0>
}

//-------------------------------------------------------------
//atmosphere:
sphere {
   <0.0, 0.0, 0.0 >, 10.0
   pigment {rgbt 1}
   hollow
   interior {
     media {
       scattering {1, <1, 1, 1,>*0.3/Scale extinction 1}
       density {
         gradient y
         color_map {
           [0.00 rgb 1.00]  //base ground fog
           [0.07 rgb 0.80]  //top ground fog
           [0.08 rgb 0.02] //base atmospheric haze
           [1.00 rgb 0.01] //top atmospheric haze
         }
         scale Scale*2*y
       }
     }
   }
   scale Scale
}

//-------------------------------------------------------------
//artefact:
union {
   cylinder {< 0.0, 0.0, 0.0 > < 0.0, 8.0, 0.0 > 0.25}
   sphere {< 0.0, 8.0, 0.0 > 0.25}
   texture { T01 }
   texture { T_Copper_1A }
}

//-------------------------------------------------------------
// Planet:
union {
   sphere {
     <0.0, 0.0, 0.0> 7.0
   }
   difference {
     cylinder { < 0.0, -0.00001, 0.0 > < 0.0, 0.00001, 0.0 > 20.0 }
     cylinder { < 0.0, -0.00002, 0.0 > < 0.0, 0.00002, 0.0 > 10.0 }
   }
   texture {pigment {White}}
   rotate < 20.0, 0.0, 4.0 >
   translate <80.0, -2.0, 13.0>
}

//-------------------------------------------------------------




-- 
Thomas


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.