|
 |
// Persistence of Vision Ray Tracer Scene Description File
// File: mediaskies.pov
// Vers: unofficial MegaPov 0.4
// Desc: sunbeams over wetlands
// Date: 00.26
// Auth: Bob Hughes
// Mail: inv### [at] aol com?Subject=Pov-Scene
// Note: Make the height_field first as a Png by using a command-line of
// +W500 +H500 +A +FN +Oc:\images\wetlands_hf.png (change all related scales
is modifying this)
// I needed to post-process this into grayscale increase contrast a lot and then
blur it some.
// The final render has the aspect ratio of 1:2 (height to width) so +w600 +h300
is needed.
#version unofficial MegaPov 0.4;
// to create the height field image say no here
#declare Go=no;
#if (Go=yes)
#declare SunDisk=
sphere {0,250 pigment {rgb <1,.9,.75>} finish {ambient 4}}
light_source {0,<1.5,1.4,1.3>
looks_like {SunDisk}
// spotlight radius 10 falloff 15 tightness 5
parallel point_at <0,0,100>
translate -9876*z rotate <158,40,0>
}
light_source {100*y,<.25,.5,.33> shadowless}
camera {
location <0, 19,-29>
up y right 2*x
angle 90
look_at <0, 21, 0>
}
// sphere {-10000*y,10500 pigment {rgbt 1} hollow}
fog {
fog_type 2
distance 1500
color rgbft <.65,.7,.725,.33,.125>
fog_alt 25
fog_offset 25
turbulence .6
turb_depth .8
}
// sky_sphere // morning
sphere {0,1 hollow
pigment
{
gradient y
color_map {
[0 color rgb<.9,.7,.6>] [.3 color rgb<.3,.6,.9>] }
}
finish {ambient .9 diffuse .9}
scale 10000
}
#else
// for making image to use as height field
camera {
orthographic
location -1000*z
up 500*y right 500*x
look_at 0
}
light_source {-1000*z,1 shadowless}
#end // Go yes or no
#declare Ground=
texture {
pigment {crackle color_map {
[0,.2 color rgb<.3,.5,.4> color rgb<.5,.8,.3>]
[.2,.9 color rgb<.5,.8,.3> color rgb<.3,.9,.5>]
} turbulence .3 }
normal {crackle .25 turbulence .3}
finish {diffuse .9 specular .2 roughness .08 reflection .1 crand .175}
scale .01
}
texture {
pigment {wrinkles color_map {
[0,.2 color rgb<.3,.5,.4> color rgb<.5,.8,.3>]
[.2,.9 color rgb<.5,.8,.3> color rgb<.3,.9,.5>]
} turbulence .3 }
normal {wrinkles .25 turbulence .3}
finish {diffuse .9 specular .2 roughness .08 reflection .1 crand .175}
scale .25
}
#declare Shore=
texture {
pigment {crackle color_map {
[0,.15 color rgb<.13,.125,.12> color rgb<.3,.25,.2>]
[.15,.25 color rgb<.3,.25,.2> color rgb<.7,.55,.35>]
[.25,.7 color rgb<.7,.55,.35> color rgb<.5,.3,.35>]
} turbulence .3 }
normal {crackle .25 turbulence .3}
finish {ambient .2 diffuse .8 specular .3 roughness .06 reflection .125
crand .225}
scale .01
}
#declare Water=
texture {
pigment {wrinkles color_map {
[0,.1 color rgb<.2,.25,.5> color rgb<.15,.3,.6>]
[.1,.5 color rgb<.15,.3,.6> color rgb<.3,.5,.7>]
} turbulence .2}
normal {wrinkles .19 turbulence .5}
finish {ambient .05 diffuse .5 specular .6 roughness .01 reflection .5
crand .075}
scale .009
}
texture {
pigment {crackle color_map {
[0,.1 color rgbt<.2,.25,.5,.5> color rgbt<.15,.3,.6,.5>]
[.1,.5 color rgbt<.15,.3,.6,.75> color rgbt<.3,.5,.7,1>]
} turbulence .15 }
normal {crackle .19 turbulence .5}
finish {ambient .05 diffuse .5 specular .6 roughness .01 reflection .1
crand .15}
scale .014
}
#declare WaterBlank=texture {pigment {rgb 0}}
#if (Go=no)
// this creates the height_field image
plane {y,0
texture {bozo turbulence .2 texture_map {
[.175 WaterBlank]
[.2 Shore]
[.275 Ground]
} triangle_wave scale <500,1,500> }
rotate -90*x
}
#else
union {
height_field {png "c:\images\wetlands_hf.png" smooth
translate <-.5,-.01,-.5> scale <300,4,300>
texture {bozo turbulence .2 texture_map {
[.175 Water]
[.2 Shore]
[.275 Ground]
} triangle_wave scale <300,1,300> }
}
plane {y,.01
texture {bozo turbulence .2 texture_map {
[.175 Water]
[.2 Shore]
[.275 Ground]
} triangle_wave scale <300,1,300> }
}
translate 250*z
}
#declare NoClouds=
texture {pigment { rgbf <1,1,1,1>}
}
#declare HighClouds=
texture {pigment {granite turbulence .3
color_map {
[0 rgbf <1,1,1,1>]
[.075 rgbf <1,1,1,1>]
[.125 rgbf <1,1,1,.33>]
[1 rgbf <.5,.5,1,0>]
} ramp_wave scale 3 }
}
#declare LowClouds=
texture {pigment {bozo turbulence .3
color_map {
[0 rgbf <1,1,1,1>]
[.1 rgbf <1,1,1,1>]
[.25 rgbf <1,1,1,.1>]
[1 rgbf <1,.5,.5,0>]
} ramp_wave scale 1.5 }
}
sphere {0, 1 hollow
scale 10000 translate -9876*y
texture {gradient z turbulence <.4,.6,.3>*2
texture_map {
[.33 HighClouds]
[.67 LowClouds]
// [.9 NoClouds]
} sine_wave scale <75,75,75>*1.333 rotate -36*y translate <250,0,125>
warp {
black_hole <1.25,1,1>*124, 150
falloff 9
strength 2
repeat <-.1,-.01,1>*12.4
turbulence <.125,.1,.15>*1.5
inverse
}
}
interior {
media {
method 3
intervals 2
samples 2, 3
absorption <.067,.075,.09>*.0125
scattering {5, <.0125,.01125,.01>*1.02 eccentricity .2
extinction 0.12}
density {rgb .5}
}
}
translate -25*z
}
// realistic bright rainbow
rainbow {
direction <.5,.5,.67>
angle 20
width 5
distance 15
color_map {
[ 0.0,0.19 color rgbt<2,0,2,1> color rgbt<0,0,3,.975> ]
[ 0.19,0.33 color rgbt<0,0,3,.975> color rgbt<0,2,2,.925> ]
[ 0.33,0.475 color rgbt<0,2,2,.925> color rgbt<0,3,0,.95>]
[ 0.475,0.6 color rgbt<0,3,0,.95> color rgbt<2,2,0,.925>]
[ 0.6,0.75 color rgbt<2,2,0,.925> color rgbt<2.5,1.5,0,.9125>]
[ 0.75,1.0 color rgbt<2.5,1.5,0,.9125> color rgbt<3,0,0,1>]
}
jitter 0.02
up <-0.25,-1,0> // 1*y is normal up (any x value will tilt)
arc_angle 140
falloff_angle 60
}
#end // Go yes or no
Post a reply to this message
|
|
