/* Here's the source code for the images posted to binaries.images.
    Toggle 'MirrorOn' from 0 to 1 to see the difference between the
    image with and without the mirror
*/


// Persistence of Vision Ray Tracer Scene Description File
// File: photon.pov
// Vers: 3.1 UV Patch
// Desc: test of photon mapping
// Date: 11/05/99
// Auth: Eric L. Freeman

#declare PhotonOn = 1;
#declare phd=5.75;
#declare MirrorOn = 0;
#declare Rotater = 10;

#include "colors.inc"
#include "metals.inc"
#include "glass.inc"

global_settings{
  max_trace_level 8
  #if (PhotonOn)
    photons{
      gather 20, 100
      radius phd, 2, 2//, 0.1*phd
      autostop 0
      jitter .4
      expand_thresholds 0.2, 40
    }
  #end
}

#declare Xer = 12;
#declare Yer = 5;
// LIGHTS
#declare LitePos = <-20,0,0>;
light_source {
  LitePos
  color White*1.5
  translate <-Xer,Yer,0>
}

// CAMERA VIEW
#declare CamPos = <0,31,-44>;
#declare CamLook = <0,0,0>;

camera {
  location CamPos
  look_at CamLook
  angle 43
}

background {Blue}

box { // BASE
  <-30,-1,-30>,
  <30,0,30>
  texture {
    pigment {checker}
    finish {ambient 0.12}
    scale 3
  }
  #if (PhotonOn)
    photons {
      separation phd
      refraction on
      reflection on
      // ignore_photons
    }
  #end
}

#declare SphereOffset = 4.6;
#declare SphereSc = 1.8;

intersection { // LENS
  sphere {
    <-SphereOffset,0,0>,
    5
  }
  sphere {
    <SphereOffset,0,0>,
    5
  }
  scale SphereSc
  texture {T_Glass2}
  interior {I_Glass}
  #if (PhotonOn)
    photons {
      separation phd
      refraction on
      reflection on
      ignore_photons
    }
  #end
  translate <-Xer,Yer,0>
}

difference { // LENS HOLDER WALL
  box {
    <-0.1,-50,-30>,
    <0.1,10,20>
  }
  cylinder {
    <-1,0,0>,
    <1,0,0>
    3.55
  }
  photons{ignore_photons}
  pigment {color White}
  finish {ambient 0.12}
  translate <-Xer,Yer,0>
}

#if (MirrorOn)
  box { // MIRROR
    <-0.25,-5,-3.5>,
    <0.25,5,3.5>
    texture {T_Chrome_1E}
    #if (PhotonOn)
      photons {
        separation phd
        refraction on
        reflection on
        // ignore_photons
      }
    #end
    rotate z*Rotater
    rotate y*-40
    translate <Xer,Yer,0>
  }
#end

Post a reply to this message

Start off the scene with the code below and you'll see pretty good results.

-Nathan

#declare PhotonOn = 1;
#declare phd=.3;
#declare MirrorOn = 1;
#declare Rotater = 10;

#include "colors.inc"
#include "metals.inc"
#include "glass.inc"

global_settings{
  max_trace_level 8
  #if (PhotonOn)
    photons{
      gather 20, 100
      radius 15*phd, 2, 15*phd
      autostop 0
      jitter .4
      expand_thresholds 0.2, 40
    }
  #end
}

Post a reply to this message