/*
  This is a little something I just threw together that
  I think has some potential.  Render it and see what
  you think.  Try it at 320x200 with AA .3 to start.

  Note: this requires the superpatch,
  http://www2.fwi.com/~parkerr/superpatch
*/

background {rgb .3}

camera { location <-3,3,-5> look_at y}
light_source {<-5,3,-5> rgb 1.5}
                       
#declare F1=function{pigment{cylindrical scale .25}}
#declare turb2=function{y*y*noise3d(x,y,z)/9}
#declare turb1=function{y*y*noise3d(x+turb2(x,y,z),
                           y+turb2(x+10,y,z+10),
                           z+turb2(x+20,y,z+20))/81}
#declare varturb=function {F1(x+y*turb1(x,y,z),
                           y+turb1(x+10,y,z+10),
                           z+turb1(x+20,y,z+20))}

                       
cylinder {0,4*y,1
  pigment {color rgbt 1}
  hollow
  interior {
    media {
      intervals 10
      density {function{varturb(x,y,z)}}
      scale <.3,.5,.3>
      scattering {0 rgb 2}
    }
  }
} 

cylinder {-.1*x, 1.9*x, .1
  texture {    
    pigment {
      gradient x
      pigment_map {
        [ .03 bozo 
              color_map {
                [0 rgb .3]
                [1 rgb .7]
              } 
              scale .001 
        ]
        [ .05 color rgb <2,.8,0>]
        [ .05 color rgb 1 ]
        [ .7 color rgb 1 ]
        [ .7 leopard 
             color_map {
               [0 rgb <.8,.5,0>]
               [1 rgb <1,1,0>]
             } 
             turbulence .5 
             scale .005 
        ]
      }
      scale 2.001
      translate -.1*x
    }
  }
}

Post a reply to this message

Cool!

ingo
--
Met dank aan de muze met het glazen oog.
Ron Parker heeft geschreven in bericht <376186b8@news.povray.org>...
>/*
>  This is a little something I just threw together that
>  I think has some potential.....

Post a reply to this message

The line below is in error, or so SuperPatch POV tells me. Float expected, pigment
found.

> #declare F1=function{pigment{cylindrical scale .25}}

Post a reply to this message

On Fri, 11 Jun 1999 23:53:33 -0500, Bob <inv### [at] aolcom> wrote:

>The line below is in error, or so SuperPatch POV tells me. Float expected, pigment
>found.
>
>> #declare F1=function{pigment{cylindrical scale .25}}

Funny.. it renders on mine.  Make sure you're running the 3.1e
version.

Post a reply to this message

Wups! Sorry for crying wolf. I see that I had renamed the other SuperPatch
"povray.exe"
to spovray.exe which is called from a batch file so all my POV-Rays can be run. Back
on
track here, thanks.

Post a reply to this message

On 11 Jun 1999 17:59:20 -0400, par### [at] fwicom (Ron Parker) wrote:

>/*
>  This is a little something I just threw together that
>  I think has some potential.  Render it and see what
>  you think.  Try it at 320x200 with AA .3 to start.
>
>  Note: this requires the superpatch,
>  http://www2.fwi.com/~parkerr/superpatch
>*/
>
An excellent example, to my mind, of minimising object creation. If
I'd tried to model a lit cigarette with smoke rising from it you can
bet your bottom dollar the scene would have had more than 2 objects in
it.

Impressive - and humbling.


Cheers,

Cliff Bowman
Why not pay my 3D Dr Who site a visit at
http://www.geocities.com/Area51/Dimension/7855/
PS change ".duffnet" to ".net" if replying via e-mail

Post a reply to this message