The texture is below, just realised I have missed out one of the light dirt
textures on the rust surface, will add that and reduce the reflection a bit on
the rust surface then do another render.


#declare lampBaseNormal =   normal {
    bozo
    scallop_wave
    scale 0.55
    turbulence 0.575
    lambda 2.5
    omega 0.75
    normal_map {
        [ 0.0 agate 0.1 scale 0.75 agate_turb 0.6 ]            // reduced all by
0.1
        [ 0.1 agate 0.1 scale 0.75 agate_turb 0.6 ]
        [ 0.2 wrinkles 0.1 scale 0.15 turbulence 0.6 ]
        [ 0.956 wrinkles 0.05 scale 0.15 turbulence 0.6 ]
        [ 0.975 agate 0.1 scale 0.75 agate_turb 0.6 ]
        [ 1.0 agate 0.1 scale 0.75 agate_turb 0.6 ]

    }

  }


#declare ldirt = texture {
    pigment { bozo scallop_wave turbulence 0.8753 omega 0.775 lambda 3.2 octaves
7
    colour_map {
        [ 0.0 rgbt 1 ]
        [ 0.8 rgbt 1 ]
        [ 0.8 rgbt <0.5, 0.34, 0.25, 1> ]
        [ 0.925 rgbt <0.25, 0.2, 0.15, 0.8> ]
        [ 1.0 rgbt <0.5, 0.34, 0.25, 1.0> ]
    }
    scale 0.02
    }
    normal { granite 0.5 scale 0.001 }
    finish { diffuse albedo 0.81 reflection { 0.001 0.01 fresnel on } }
}


#declare dirt = texture {
    pigment { bozo scallop_wave turbulence 0.8753 omega 0.775 lambda 3.2 octaves
7
    colour_map {
        [ 0.0 rgbt 1 ]
        [ 0.75 rgbt 1 ]
        [ 0.75 rgbt <0.5, 0.34, 0.25, 1> ]
        [ 0.9 rgbt <0.25, 0.2, 0.15, 0.5> ]
        [ 1.0 rgbt <0.5, 0.34, 0.25, 1.0> ]
    }
    scale 0.02
    }
    normal { granite 0.5 scale 0.001 }
    finish { diffuse albedo 0.81 reflection { 0.001 0.01 fresnel on } }
}

#declare vdirt = texture {
    pigment { bozo scallop_wave turbulence 0.8753 omega 0.775 lambda 3.2 octaves
7
    colour_map {
        [ 0.0 rgbt 1 ]
        [ 0.55 rgbt 1 ]
        [ 0.55 rgbt <0.25, 0.14, 0.09, 1> ]
        [ 0.9 rgbt <0.08, 0.06, 0.045, 0.125> ]
        [ 1.0 rgbt <0.25, 0.14, 0.09, 0.45> ]
    }
    scale 0.02
    }
    normal { granite 0.5 scale 0.001 }
    finish { diffuse albedo 0.75 reflection { 0.001 0.005 fresnel on } }
}



#declare lampBaseTex = texture
    {
        pigment {rgb <0.3, 0.025, 0.003> }
        finish { specular albedo 0.1 roughness 0.01 diffuse albedo 0.75
reflection { 0.01 0.05 fresnel on } }
        normal { lampBaseNormal scale 0.5}
    }
    texture
    {
        pigment {
            bozo
            turbulence 0.456
            omega 0.8
            lambda 2
            octaves 8
            colour_map
            {
                [ 0 rgbt 1 ]
                [ 0.3 rgbt 1 ]
                [ 0.3 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 0.4 rgbt <0.45, 0.2, 0.07, 0.975> ]
                [ 0.5 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 0.6 rgbt <0.45, 0.2, 0.07, 0.985> ]
                [ 0.7 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 0.8 rgbt <0.45, 0.2, 0.07, 0.975> ]
                [ 0.9 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 1.0  rgbt <0.45, 0.2, 0.07, 0.96> ]
            }
            scale <0.075, 0.15, 0.075>
        }
        finish { specular albedo 0.1 roughness 0.01 diffuse albedo 0.875
reflection { 0.01 0.025 fresnel on } }
        normal {average normal_map {
            [ 1 lampBaseNormal scale 0.5 ]
            [ 1 granite 0.8 scale 0.05 ]
            }
           }

    }
texture { ldirt }

#declare lampBaseTexDirt = texture { lampBaseTex }
    texture { dirt }

#declare lampBaseTexVDirt = texture { lampBaseTex }
    texture { vdirt }


#declare lampBubblePaint = texture
{
        pigment { gradient x turbulence 0.73 omega 0.4 colour_map
        {
        [ 0 rgb <0.3, 0.025, 0.003> ]
        [ 0.6 rgb <0.3, 0.025, 0.003> ]
        [ 0.7 rgb <0.325, 0.06, 0.01> ]
        [ 0.8 rgb <0.325, 0.06, 0.01> ]
        [ 1.0 rgb <0.3, 0.025, 0.003> ]
        }
        scale <0.01, 0.1, 0.02>
        }
        finish { specular albedo 0.1 roughness 0.01 diffuse albedo 0.75
reflection { 0.01 0.05 fresnel on } }
        normal { crackle 3 turbulence 0.05 scale 0.025 }
}
    texture
    {
        pigment {
            bozo
            turbulence 0.456
            omega 0.8
            lambda 2
            octaves 8
            colour_map
            {
                [ 0 rgbt 1 ]
                [ 0.3 rgbt 1 ]
                [ 0.3 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 0.4 rgbt <0.45, 0.2, 0.07, 0.975> ]
                [ 0.5 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 0.6 rgbt <0.45, 0.2, 0.07, 0.985> ]
                [ 0.7 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 0.8 rgbt <0.45, 0.2, 0.07, 0.975> ]
                [ 0.9 rgbt <0.45, 0.2, 0.07, 1> ]
                [ 1.0  rgbt <0.45, 0.2, 0.07, 0.96> ]
            }
            scale <0.075, 0.15, 0.075>
        }
        finish { specular albedo 0.1 roughness 0.01 diffuse albedo 0.875
reflection { 0.01 0.025 fresnel on } }
        normal { crackle 3 turbulence 0.05 scale 0.03 }

    }

#declare lampBubblePaintDirt = texture { lampBubblePaint }
    texture { dirt }

#declare lampBubblePaintVDirt = texture { lampBubblePaint }
    texture { vdirt }


#declare lampRust = texture {
        pigment { granite turbulence 0.35 omega 0.7 lambda 2.2
            colour_map {
            [ 0.0 rgb <0.015, 0.0045, 0> ]
            [ 0.3 rgb <0.05, 0.0175, 0.00075> ]
            [ 1.0 rgb <0.03, 0.009, 0.002> ]
            }
            scale 0.2
        }
        finish { specular albedo 0.1 roughness 0.01 brilliance 5 diffuse albedo
0.575 reflection { 0.05 0.09 metallic 0.6 fresnel on } }
        normal { granite 0.12 turbulence 0.35 scale 0.05}
}


#declare  lampRustDirt = texture { lampRust }
texture { dirt }

#declare  lampRustVDirt = texture { lampRust }
texture { vdirt }

#declare  lampRustLDirt = texture { lampRust }
texture { ldirt }


#declare lampPaintRust = texture {
wrinkles
cubic_wave
turbulence 0.0625
omega 0.675
octaves 7
//sine_wave
//agate
//agate_turb 0.375
texture_map {
[ 0.0 lampBaseTex scale 4 ]
[ 0.6 lampBaseTex scale 4 ]
[ 0.625 lampBubblePaint scale 2 ]
[ 0.675 lampBubblePaint scale 2 ]
[ 0.7 lampRust scale 3 ]
[ 1.0 lampRust scale 3 ]
}
scale 0.25
}

#declare lampPaintRustDirt = texture {
wrinkles
cubic_wave
turbulence 0.0625
omega 0.675
octaves 7
//sine_wave
//agate
//agate_turb 0.375
texture_map {
[ 0.0 lampBaseTexDirt scale 4 ]
[ 0.6 lampBaseTexDirt scale 4 ]
[ 0.625 lampBubblePaintDirt scale 2 ]
[ 0.675 lampBubblePaintDirt scale 2 ]
[ 0.7 lampRustDirt scale 3 ]
[ 1.0 lampRustDirt scale 3 ]
}
scale 0.25
}



#declare lampPaintRustVDirt = texture {
wrinkles
cubic_wave
turbulence 0.0625
omega 0.675
octaves 7
//sine_wave
//agate
//agate_turb 0.375
texture_map {
[ 0.0 lampBaseTexVDirt scale 4 ]
[ 0.6 lampBaseTexVDirt scale 4 ]
[ 0.625 lampBubblePaintVDirt scale 2 ]
[ 0.675 lampBubblePaintVDirt scale 2 ]
[ 0.7 lampRustVDirt scale 3 ] // was VDirt
[ 1.0 lampRustVDirt scale 3 ] // was VDirt
}
scale 0.25
}

#declare lampPaintRustLDirt = texture {
wrinkles
cubic_wave
turbulence 0.0625
omega 0.675
octaves 7
//sine_wave
//agate
//agate_turb 0.375
texture_map {
[ 0.0 lampBaseTexDirt scale 4 ]
[ 0.6 lampBaseTexDirt scale 4 ]
[ 0.625 lampBubblePaintDirt scale 2 ]
[ 0.675 lampBubblePaintDirt scale 2 ]
[ 0.7 lampRustLDirt scale 3 ]
[ 1.0 lampRustLDirt scale 3 ]
}
scale 0.25
}



material {
texture { gradient y turbulence 0.025
texture_map {
    [ 0.0  lampRust ]
    [ 0.025  lampPaintRustVDirt ]     //VDirt
    [ 0.15  lampPaintRustDirt ]       //Dirt
    [ 1.0  lampPaintRustDirt ]        //Dirt
}
translate <0, -0.05, 0>
}
interior { ior 1.6 }
}
}


Seab

Post a reply to this message

On 21-3-2013 12:35, s.day wrote:
> Thomas de Groot <tho### [at] degrootorg> wrote:
>> On 20-3-2013 22:47, s.day wrote:
>>> Trying to age my lantern, HDR seems to look better with new shiny objects
>>> though...
>>>
>>
>> IMHO this is looking really excellent. I can see no fault with it.
>>
>> Thomas
>
> Thanks Thomas, it is alwasy easier to find the faults when you created the model
> though. There are some not perfect joins on the glass (coincident surface at the
> very top and where the sphere is connected to the cone the angle/join is not
> perfect). However, I suppose often glass objects have these imperfections anyway
> so maybe I meant to do it ;-)

I did not see those, and even now, I think those imperfections are 
acceptable as RL proxies ;-)

>
> Also, the object is not fully accurate, it was modelled from a photo and I could
> not really see how the wire around the glass was connected up so I didn't
> connect it to anything. Having found a few more photo's now I see that it is
> connected to the bottom wire and this wire runs around (not through) the lamp
> base.. I should fix this but am suffering from the 80:20 rule..

Ah yes! That is more obvious indeed. I wondered how the glass was lifted 
up with the bottom wire going through the base. I think there should be 
some kind of handle attached to it?

Otherwise, it is an excellent piece of modelling.

Thomas

Post a reply to this message

On 21-3-2013 12:48, s.day wrote:
>
> The texture consists of several layered textures in a texture map ....

You are very good at this. I often use texture avatars from your Old 
Royal IRTC scene.

Thomas

Post a reply to this message

"Trevor G Quayle" <Tin### [at] hotmailcom> wrote:
> "s.day" <s.d### [at] uelacuk> wrote:
> > Trying to age my lantern, HDR seems to look better with new shiny objects
> > though...
>
> No, I think this looks just as good this way, maybe even better.  Making things
> look shiny and new is easy, making them look old or worn or dirty or dusty is a
> real challenge.
>
> -tgq

Yes, I agree. I have often had a good model only to wreck it with a bad texture.
Dust is probably the most difficult to add with realism, especially if it is a
close up view.

Sean

Post a reply to this message

On 21/03/2013 11:48 AM, s.day wrote:
> next I need to try to add a tiger lily to the scene

I don't know if you have used PlantStudio? Version 1.0 is free.

http://www.kurtz-fernhout.com/PlantStudio/

-- 
Regards
     Stephen

Post a reply to this message

Stephen <mca### [at] aolcom> wrote:
> On 21/03/2013 11:48 AM, s.day wrote:
> > next I need to try to add a tiger lily to the scene
>
> I don't know if you have used PlantStudio? Version 1.0 is free.
>
> http://www.kurtz-fernhout.com/PlantStudio/
>
> --
> Regards
>      Stephen

Thanks, some of the sample images look pretty good, I will take a look at this.
This lily will be fairly large/close so maybe difficult to get the detail level
good enough (alghough if I attempt it with CSG it may look more like a lego
flower ;-)

Sean

Post a reply to this message

On 21/03/2013 2:00 PM, s.day wrote:
>
> Thanks, some of the sample images look pretty good, I will take a look at this.
> This lily will be fairly large/close so maybe difficult to get the detail level
> good enough (alghough if I attempt it with CSG it may look more like a lego
> flower ;-)
>
> Sean
>
It will probably make a good starting point, where you can export it to 
PoseRay to subdivide it. Then use your own textures.

-- 
Regards
     Stephen

Post a reply to this message

Thomas de Groot <tho### [at] degrootorg> wrote:
> On 21-3-2013 12:48, s.day wrote:
> >
> > The texture consists of several layered textures in a texture map ....
>
> You are very good at this. I often use texture avatars from your Old
> Royal IRTC scene.
>
> Thomas

Thanks Thomas, I never did finish off the rest of that train model (adding the
carriages etc). I had lots of ideas for scenes to use that model in but it they
all needed the carriages completed etc. Still on my to do list then..

Post a reply to this message

On 21-3-2013 23:49, s.day wrote:
> Thanks Thomas, I never did finish off the rest of that train model (adding the
> carriages etc). I had lots of ideas for scenes to use that model in but it they
> all needed the carriages completed etc. Still on my to do list then..
>

I know that feeling :-)

Thomas

Post a reply to this message

Jaime Vives Piqueres <jai### [at] ignoranciaorg> wrote:

> > Trying to age my lantern, HDR seems to look better with new shiny
> > objects though...
> >
>
>    Very nice modeling... proportions look perfect, with all the tiny
> details at the correct scale. Lighting is very good too... I cannot see
> any obvious artifacts. Texturing on the paint is also impressive, but
> the rusty parts look like too reflective... I guess you didn't go for a
> texture_map?
>
> --
> Jaime

Hi Jaime,

Thanks for noticing the shiny rust, I have modified this and think the result is
a  subtle but good improvement.

Sean

Post a reply to this message

Attachments:
Download 'lantern_rust.png' (587 KB)

Preview of image 'lantern_rust.png'