![](/i/fill.gif) |
![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Thomas de Groot nous apporta ses lumieres en ce 2007/11/05 03:47:
> "alphaQuad" <alp### [at] earthlink net> schreef in bericht
> news:web.472e20902a06dfe95b922c2d0@news.povray.org...
>> "alphaQuad" <alp### [at] earthlink net> wrote:
>>> dont think I got the hang of it yet
>>
>> here's a curiosity: what can POV do?
>>
>> what about a half moon in the middle of the day?
>>
>
> This has been solved very nicely by Bill Pragnell (look for a message dated
> november 23, 2005, I think in this same ng) and I have used the trick in
> several of my scenes. I took some notes which I reproduce here:
>
> 1) use a hollow sphere around your scene (or use inverse) set background to
> black
> 2) give it the required color gradient you would give a sky_sphere, but use
> a partial transparency, ambient 1, diffuse 0
> 3) put the moon and the light source (sun) outside of this sphere: the parts
> in shadow will have the same color as the local sky
> 4) if you want to use radiosity: use an interior_texture on your sphere. The
> ouside texture should be rgb 0, with transmit=1
>
> note 1: you may have to experiment a bit with the transparency and/or the
> gradient colors to get the desired effect.
> note 2: instead of a sphere, you can use other objects of course: a plane or
> a cube or whatever.
>
> Hope this helps
>
> Thomas
>
>
Additional note: the sphere center don't need to be at the camera location or on
the ground. A more realistic result can be done with a flatened sphere with it's
center moved down like: (good for you clouds)
sphere{0,10000 scale<1,0.5,1>translate -2500*y texture{...}}
--
Alain
-------------------------------------------------
I know I'm not sexy. When I put my underwear on I can hear the Fruit-
of-the-Loom guys giggling.
Rodney Dangerfield
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
For anyone following along here, think I found it.
http://news.povray.org/povray.binaries.images/thread/%3Cweb.4381be8f2e4ee441731f01d10%40news.povray.org%3E/?ttop=251451
&toff=1300
that was painful going back to nov 2005 and
not reading some of the subjects, had to look away 'til got I there.
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"Thomas de Groot" <t.d### [at] inter nlDOTnet> wrote:
> 1) use a hollow sphere around your scene (or use inverse) set background to
> black
> 2) give it the required color gradient you would give a sky_sphere, but use
> a partial transparency, ambient 1, diffuse 0
> 3) put the moon and the light source (sun) outside of this sphere: the parts
> in shadow will have the same color as the local sky
> 4) if you want to use radiosity: use an interior_texture on your sphere. The
> ouside texture should be rgb 0, with transmit=1
from that I applied (inside and out) a gradient (as)"you would give a
sky_sphere"
with a transparency but apparently did not have the experience required.
with filter numbers 1 and .5, both produced a strange patern.
You may learn more figuring things out for yourself but
if you can get there alone, you wont learn a thing. In the nov2005 thread it was
asked "how did you do that"? A picture (a script) is worth a thousand words of
explanation. It is a loss to many when code is not posted.
failed attempt
sphere { <0,0,0>, 100.0
uv_mapping
material { half_moon }
rotate <0,-78,0>
rotate <0,0,-15>
translate <0,500,3000>
}
outside
/*sphere { <0,0,0>, 2000.0
pigment {
gradient y
color_map {
[0.0 rgbf <0.6,0.7,1.0,1>]
[1 rgbf <0.4,0.5,0.8,1>]
}
}
finish { ambient 1 diffuse 0 }
} */
sphere { <0,0,0>, 2000.0
interior_texture {
// ior 1.5
pigment {
gradient y
color_map {
[0.0 rgbf <0.6,0.7,1.0,1>]
[1 rgbf <0.4,0.5,0.8,1>]
}
}
finish { ambient 1 diffuse 0 }
}
texture {
pigment {
rgb 0
transmit 1
}
//finish { ambient 1 diffuse 0 }
}
}
Post a reply to this message
Attachments:
Download 'waterscene_04.jpg' (102 KB)
Preview of image 'waterscene_04.jpg'
![waterscene_04.jpg](/povray.binaries.images/attachment/%3Cweb.472f6d7d2a06dfe9c51101a30%40news.povray.org%3E/waterscene_04.jpg?preview=1)
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"alphaQuad" <alp### [at] earthlink net> wrote in message
news:web.472f6d7d2a06dfe9c51101a30@news.povray.org...
Added a line that may help.
I usually do this with fog. See below.
>
> sphere { <0,0,0>, 2000.0
> interior_texture {
> // ior 1.5
> pigment {
> gradient y
> color_map {
> [0.0 rgbf <0.6,0.7,1.0,1>]
> [1 rgbf <0.4,0.5,0.8,1>]
> }
scale 2000
> }
> finish { ambient 1 diffuse 0 }
> }
> texture {
> pigment {
> rgb 0
> transmit 1
> }
> //finish { ambient 1 diffuse 0 }
> }
> }
>
// to prevent the fog going forever
sphere {
0,2000
pigment {rgbf 1}
inverse
}
fog {
rgb <0.2,0.2,0.4>
fog_type 1
distance 2400
}
fog {
rgb <0.6,0.5,0.7>*0.8
fog_type 2
fog_offset 0
fog_alt 300
distance 2000
}
light_group {
light_source {
<5000,1500,5000>
<0.8,0.75,0.7>*2
}
sphere {
0,1
pigment {
image_map {
png "Moon.png"
map_type 1
interpolate 2
}
}
finish {ambient 0 brilliance 2}
scale 300
rotate z*20
translate <-600,450,7000>
}
global_lights off
}
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
well it was a labor to play with filters.
and certainly a great deal of help was provided that gave some insight.
Great.
not happy with foggy clouds. they are bozo mapped. Bruno's look crisp.
some ideas mentioned were not completely understood, maybe some day.
(or some insightful and generous script posting)
the gradient sphere was never seen but now that I think about it, that pattern
would go away if you scale y maybe?
PO
Post a reply to this message
Attachments:
Download 'waterscene_05.jpg' (604 KB)
Preview of image 'waterscene_05.jpg'
![waterscene_05.jpg](/povray.binaries.images/attachment/%3Cweb.47301a3b2a06dfe9fceffeaf0%40news.povray.org%3E/waterscene_05.jpg?preview=1)
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"Gail Shaw" <initialsurname@sentech sa dot com> wrote:
> "alphaQuad" <alp### [at] earthlink net> wrote in message
> news:web.472f6d7d2a06dfe9c51101a30@news.povray.org...
>
> Added a line that may help.
>
> I usually do this with fog. See below.
my previous post was posted before reading your post. Will try this next but
should be some time before I have a report.
thank you Gail, it looks like what I could not conceive with so little
experience.
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"alphaQuad" <alp### [at] earthlink net> schreef in bericht
news:web.472f54862a06dfe9c51101a30@news.povray.org...
> For anyone following along here, think I found it.
>
>
http://news.povray.org/povray.binaries.images/thread/%3Cweb.4381be8f2e4ee441731f01d10%40news.povray.org%3E/?ttop=251451
> &toff=1300
>
That's the one.
>
>
> that was painful going back to nov 2005 and
> not reading some of the subjects, had to look away 'til got I there.
>
<grin>
Thomas
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
This is the code I used in one of my images:
//-- start code --
#declare MoonMap =
material {
texture {
pigment {
image_map {
png "PlanetMaps\MoonMap.png"
map_type 1
once
interpolate 2
}
scale <1,1,1>
//rotate 90*x
}
normal {
bump_map {
png "PlanetMaps\MoonBump.png"
map_type 1
once
interpolate 2
}
scale <1,1,1>
//rotate 90*x
bump_size 1.0
}
finish {
ambient 0.0
diffuse 0.5
}
}
//rotate <20.0, 0.0, -25.0>
}
sphere { // Moon
<0,0,0>,1
material {
MoonMap
}
scale 80.0
rotate -90*y
translate <-300.0, 200.0, 1000.0>
}
// Sky
#declare BlueSkySphere =
texture {
pigment {
gradient y
pigment_map {
[0.0 rgb <0.6,0.7,1.0>*1.5 transmit 0.5]
[1.0 rgb <0.437467, 0.824265, 1.0>*1.5 transmit 0.5]
}
}
finish {
ambient 0.9
diffuse 0.0
}
}
#declare CosmosSkySphere =
texture {
pigment {
color rgbt <0,0,0,1>
}
finish {
ambient 0.0
diffuse 0.0
}
}
sphere {
<0,0,0>,1
texture { BlueSkySphere }
interior_texture { CosmosSkySphere } //using inverse puts the inside of
the sphere outside
no_shadow
no_reflection
inverse // no need for hollow
scale 400
}
//-- end code--
Thomas
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
alphaQuad napsal(a):
> ...
> from that I applied (inside and out) a gradient (as)"you would give a
> sky_sphere"
> with a transparency but apparently did not have the experience required.
> ...
> sphere { <0,0,0>, 2000.0
> interior_texture {
> // ior 1.5
> pigment {
> gradient y
> color_map {
> [0.0 rgbf <0.6,0.7,1.0,1>]
> [1 rgbf <0.4,0.5,0.8,1>]
> }
> }
> finish { ambient 1 diffuse 0 }
> }
> ...
scale the pigment 2000 times.
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
alphaQuad nous apporta ses lumieres en ce 2007/11/06 02:39:
> well it was a labor to play with filters.
>
> and certainly a great deal of help was provided that gave some insight.
>
> Great.
>
>
> not happy with foggy clouds. they are bozo mapped. Bruno's look crisp.
>
> some ideas mentioned were not completely understood, maybe some day.
> (or some insightful and generous script posting)
>
> the gradient sphere was never seen but now that I think about it, that pattern
> would go away if you scale y maybe?
>
> PO
>
>
> ------------------------------------------------------------------------
>
Nice! That's what I can call a beleiveable moon.
--
Alain
-------------------------------------------------
You know you've been raytracing too long when you wonder if ground fog or
athmosphere will look better for your company's market share pie chart.
Christoph Rieder
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |