![](/i/fill.gif) |
![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Hello. I've enjoyed povray off and on for a few years but never posted.
Lately, I've been enjoying all the images everyone has here and thought I'd
add a few of my own. These where for the last irtc theme, absence, but I
never got around to sending them.
The first one, attached here, is a simple bit of negative space fun.
#version 3.6;
//+w640 +h240 +a0.03
#declare blur_on = true;
#declare color_on = true;
// ----------------------------------------
global_settings {
assumed_gamma 1.0
}
#default {
texture {
pigment {
color rgb 1
}
finish {
ambient 0
diffuse 1
}
}
}
// ----------------------------------------
camera {
angle 35
location <0.0, 0.0, -5.0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
#if(blur_on=true)
aperture 1
variance 1/1000000
confidence 0.999
blur_samples 10
focal_point <0.0, 0.0, 0.0>
#end
}
// ----------------------------------------
#declare word =
text {
ttf "times.ttf" "Absent" 2, 0
}
#declare word_min=min_extent( word )-<0.25,0.25,0>;
#declare word_max=max_extent( word )+<0.25,0.25,0>;
#declare word_scale = word_max-word_min;
#declare word_offset = word_min;
#declare R = seed( 213 );
union {
#declare i = 0;
#while (i < 25000)
#local X = word_offset.x + word_scale.x*rand(R);
#local Y = word_offset.y + word_scale.y*rand(R);
#local Z = word_offset.z + word_scale.z*rand(R);
#if (!inside( word, <X, Y, Z> ))
box {
<-1, -1, -1>
< 1, 1, 1>
scale 0.002 + 0.018*rand(R)
rotate <0, 30 - 60*rand(R), 30 - 60*rand(R)>
translate <X, Y, Z>
#if (color_on = true )
pigment { rgbt <0.25, 0.25+0.5*rand(R), 0.75+0.25*rand(R), 0> }
#end
}
#end
#declare i = i + 1;
#end
#if (color_on = false )
pigment { rgbt <0.25, 0.75, 1.0, 0.9> }
#end
translate <-word_offset.x - word_scale.x/2.0, -word_offset.y -
word_scale.y/2.0, 0>
}
light_source {
<0, 0, -10>
1.0
shadowless
fade_distance 10.0
fade_power 100
}
Post a reply to this message
Attachments:
Download 'spelling_boxes.jpg' (111 KB)
Preview of image 'spelling_boxes.jpg'
![spelling_boxes.jpg](/povray.binaries.images/attachment/%3Cweb.456c80fcdb4a9f2bc81efaa0%40news.povray.org%3E/spelling_boxes.jpg?ttop=443866&toff=4100&preview=1)
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Here's the second one. It's pretty abstract: The yang collaspes and the yin
rules. In the absence of harmony, chaos overwhelms.
#version 3.6;
#include "functions.inc"
// ----------------------------------------
global_settings {
assumed_gamma 1.0
}
#default {
texture {
pigment {
color rgb 1
}
finish {
ambient 0
diffuse 1
}
}
}
// ----------------------------------------
camera {
location <0.0, 1.0, 0.0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
aperture .6
variance 1/1000000
confidence 0.9
blur_samples 100
focal_point <0, -0.24, 0>
}
// ----------------------------------------
light_source {
<0.0, 2.8, 0.0>
color rgb 0.5
fade_distance 3.75
fade_power 100
}
light_source {
<0.0, 1.0, 0.0>
color rgb 0.5
fade_distance 1.3
fade_power 50
}
// ----------------------------------------
// A wave plane to see the shadow
plane {
y, -0.95
texture {
pigment {
color rgb <0.8, 0.8, 1.0>
}
normal {
waves
scale <.1, 1, .1>
}
finish {
phong 2
phong_size 1
}
}
}
// ----------------------------------------
// The yang
sphere {
<0, -0.5, 0>
0.2
texture {
pigment {
color rgb <1, 1, 1>
}
}
}
// ----------------------------------------
// The yin shadow
union
{
isosurface {
function{ f_comma( x,y,z, 1) }
contained_by {sphere { 0, 1.5 } }
scale <.1, .05, .1>
rotate <0, -90, 0>
translate <0, 2, 0>
pigment { color rgb 1 }
}
sphere {
<0, 0, -.05>
.02
translate <0, 2, 0>
}
torus {
.1, .01
translate <0, 2, 0>
}
}
Post a reply to this message
Attachments:
Download 'absent_yang.jpg' (59 KB)
Preview of image 'absent_yang.jpg'
![absent_yang.jpg](/povray.binaries.images/attachment/%3Cweb.456c81a72f598490bc81efaa0%40news.povray.org%3E/absent_yang.jpg?ttop=443866&toff=4100&preview=1)
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Oh, very cleaver... nice.
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Oops, forgot the last absent image. Sphere over checkered plane.
#version 3.6;
#include "metals.inc"
#declare arealight_on = true;
// ----------------------------------------
global_settings {
assumed_gamma 1.0
}
#default {
texture {
pigment {
color rgb 1
}
finish {
ambient 0
diffuse 1
}
}
}
// ----------------------------------------
camera {
location <-1.0, 1.0, -2.0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
}
light_source {
<1, 2, -1>
color rgb 0.5
fade_distance 4
fade_power 10
#if (arealight_on = true)
area_light
<0.3, 0, 0>, <0, 0, 0.3>
10, 10
circular
orient
#end
}
// ----------------------------------------
#declare tile=
superellipsoid {
<0.5, 0.5>
scale <0.12, 0.1, 0.12>
translate <0, -0.1, 0>
}
#declare i = -5;
#while (i < 40)
#declare j = -7;
#while (j < 40)
object {
tile
translate <0.2*i, 0, 0.2*j>
#if (mod( i+j,2 ) = 0)
texture {
pigment {
color rgb <0.9, 0.9, 0.9>
}
finish {
phong 1
phong_size 10
}
}
#else
texture {
pigment {
color rgb <0.0, 0.0, 0.0>
}
finish {
phong 1
phong_size 20
}
}
#end
}
#declare j = j+1;
#end
#declare i = i+1;
#end
// ----------------------------------------
#declare t2 =
texture {
pigment {
color rgbft <1.0, 1.0, 1.0, 0.0, 1.0>
}
}
sphere {
<-0.1, 0.4, -0.2>, 0.2
texture {
gradient y
scale 0.4
translate 0.2
texture_map {
[0.0 T_Silver_1A]
[0.2 T_Silver_1A]
[0.4 t2]
[1.0 t2]
}
}
}
Post a reply to this message
Attachments:
Download 'missing_sphere.jpg' (153 KB)
Preview of image 'missing_sphere.jpg'
![missing_sphere.jpg](/povray.binaries.images/attachment/%3Cweb.456c9d0b2f598490bc81efaa0%40news.povray.org%3E/missing_sphere.jpg?ttop=443866&toff=4100&preview=1)
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
the first one is very nice and subtle. One of the IRTC entries used the
same empty space idea and the very word. Still, between that and this, i
feel this one has a lot more empty spaceness going for it... :)
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
"nemesis" <nam### [at] gmail com> wrote:
> the first one is very nice and subtle. One of the IRTC entries used the
> same empty space idea and the very word. Still, between that and this, i
> feel this one has a lot more empty spaceness going for it... :)
:o)
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Interesting.
Sven
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
o.bb.spammed wrote:
> Here's the second one. It's pretty abstract: The yang collaspes and the yin
> rules. In the absence of harmony, chaos overwhelms.
Oh goodie, I have a new desktop wallpaper :)
...Chambers
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Nice image!
If you add some sparkles, and changed the blocks to starry shapes, it
would make an excellent Christmas rendering!
Reuben
reu### [at] pslconnect com
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Reuben Pearse <reu### [at] pslconnect com> wrote:
> Nice image!
>
> If you add some sparkles, and changed the blocks to starry shapes, it
> would make an excellent Christmas rendering!
>
> Reuben
> reu### [at] pslconnect com
Fun idea. Something like this maybe? Needs the proper stars still.
Post a reply to this message
Attachments:
Download 'noel.jpg' (64 KB)
Preview of image 'noel.jpg'
![noel.jpg](/povray.binaries.images/attachment/%3Cweb.4575cfa02f598490bc81efaa0%40news.povray.org%3E/noel.jpg?ttop=443866&toff=4100&preview=1)
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |