To all users:

Please post your metal textures here.
Once this inc file is done I will move to waters.inc, stones.inc, woods.inc, 
etc.. so you can go ahead and post those textures too if you want. Remember: 
radiosity compatibility. ;-)

ian

Post a reply to this message

Here are six metal textures. Nothing really special. Just thought they might 
be of interest.

Thomas

Post a reply to this message

Attachments:
Download 'textures_test_metals.jpg' (69 KB) Download 'textures_test_metals.inc.txt' (8 KB) Download 'textures_test_metals.pov.txt' (2 KB)

Preview of image 'textures_test_metals.jpg'

"Thomas de Groot" <tDOTdegroot@interDOTnlANOTHERDOTnet> wrote:
> Here are six metal textures. Nothing really special. Just thought they might
> be of interest.

The rusty steel looks great. The other ones in the front row I'm not sure about.
The three in the back look rather non-metallic to me - but then again, they
might all be oxidized - in that case I guess they're ok.

Post a reply to this message

"clipka" <nomail@nomail> schreef in bericht 
news:web.49cf72ef4ee6dd4eea392f10@news.povray.org...
>
> The rusty steel looks great. The other ones in the front row I'm not sure 
> about.
> The three in the back look rather non-metallic to me - but then again, 
> they
> might all be oxidized - in that case I guess they're ok.
>
>

The two in front you mention are fantasy metals, just for fun; the two 
greenish ones are bronzes with an oxydized/patina layer. Back left, is a 
rusty iron.

They may not be exactly RL, but I am not sure that metals.inc should only 
contain RL stuff. However, I leave selection to the community.

Thomas

Post a reply to this message

"[GDS|Entropy]" <gds-entropy    AT    hotmail   DOT  com> wrote:
> To all users:
>
> Please post your metal textures here.
> Once this inc file is done I will move to waters.inc, stones.inc, woods.inc,
> etc.. so you can go ahead and post those textures too if you want. Remember:
> radiosity compatibility. ;-)
>
> ian

A rusty iron-texture

---[Snip]---------------
//*PMRawBegin

#include "textures.inc"
//*PMRawEnd

global_settings {
   adc_bailout 0.0039216
   assumed_gamma 1.5
   max_trace_level 256
   noise_generator 2
}

sky_sphere {
   pigment {
      color rgb <0.054902, 0.219608, 0.4>
   }
}

cylinder {
   <0, 3, 0>, <0, -3, 0>, 2

   texture {
      pigment {
         spherical
         turbulence <1, 1, 1>
         omega 1
         lambda 6

         color_map {
            [ 0.1 color rgb <0.478431, 0.513725, 0.462745>
            ]
         }
      }

      normal {
         boxed
         30
         turbulence <1, 1, 1>
         omega 1
         lambda 6
         frequency 15
      }

      finish {
         ambient rgb <0, 0, 0>
         diffuse 0.3
         specular 0.6
         conserve_energy

         reflection {
            rgb <0.1, 0.1, 0.1>
            metallic 1
         }
      }
      scale 15
   }
   scale 1
   rotate <0, 0, 0>
   translate <1.6, 0, 5.53333>
}

sphere {
   <0, 0, 0>, 2

   texture {
      uv_mapping

      pigment {
         spherical
         turbulence <1, 1, 1>
         omega 1
         lambda 6

         color_map {
            [ 0.1 color rgb <0.478431, 0.513725, 0.462745>
            ]
         }
      }

      normal {
         boxed
         30
         turbulence <1, 1, 1>
         omega 1
         lambda 6
         frequency 15
      }

      finish {
         ambient rgb <0, 0, 0>
         diffuse 0.3
         specular 0.6
         conserve_energy

         reflection {
            rgb <0.1, 0.1, 0.1>
            metallic 1
         }
      }
      scale 7.5
   }
   scale 1
   rotate <0, 0, 0>
   translate <2.13333, 0, -3.13333>
}

torus {
   3, 1

   texture {
      pigment {
         spherical
         turbulence <1, 1, 1>
         omega 1
         lambda 6

         color_map {
            [ 0.1 color rgb <0.478431, 0.513725, 0.462745>
            ]
         }
      }

      normal {
         boxed
         30
         turbulence <1, 1, 1>
         omega 1
         lambda 6
         frequency 15
      }

      finish {
         ambient rgb <0, 0, 0>
         diffuse 0.3
         specular 0.6
         conserve_energy

         reflection {
            rgb <0.1, 0.1, 0.1>
            metallic 1
         }
      }
      scale 7.5
   }
   scale 1
   rotate <90, -45, 0>
   translate <-3.73333, 0, 3.5>
}

light_source {
   //*PMName Key-Light
   <7, 5, -10>, rgb <1, 1, 1>
   area_light <6, 0, 0>, <0, 6, 0>, 9, 9
   adaptive 2
   jitter
   circular
   orient
}

light_source {
   //*PMName Fill-Light
   <-7, 5, -10>, rgb <0.5, 0.5, 0.5>
   shadowless
   media_interaction off
}

camera {
   perspective
   location <-0.3, 4, -9>
   sky <0, 1, 0>
   direction <0, 0, 1>
   right <1.3333, 0, 0>
   up <0, 1, 0>
   look_at <0, 0, 0>
}
---[Snap]------------

Post a reply to this message

Attachments:
Download 'rostiges eisen(2).png' (405 KB)

Preview of image 'rostiges eisen(2).png'

Metallic spaceship-hull panels

.. or greebles-in-a-texture if you like :)

--- START CODE ---
#declare MetalPanels=
texture {
 pigment {
  average
  pigment_map {
   [1
   cells
   pigment_map {
    [0
     cells
     color_map {
      [0 rgb .6]
      [1 rgb 1]
     }
     scale 1.5
    ]
    [.4
     cells
     color_map {
      [0 rgb .8]
      [1 rgb 1]
     }
     translate <.25,.5,.2>
    ]
   }
   ]
   [1
   cells
   color_map {
    [0 rgb .8]
    [1 rgb 1]
   }
   translate <.25,1.5,.2>
   scale 2
   translate <2.25,1.5,3.5>
   ]
  }
  scale .25
 }
 normal {
  average
  normal_map {
   [1
   cells
   normal_map {
    [0
     cells
     bump_size 1
     scale 1.5
    ]
    [.4
     cells
     bump_size .8
     translate <.25,.5,.2>
    ]
   }
   scale 1
   ]
   [1
   cells
   normal_map {
    [0
     cells
     bump_size 1
     scale .5
    ]
    [.4
     cells
     bump_size .8
     translate <.25,.5,.2>
    ]
   }
   scale .25
   ]
   [1
   cells
   bump_size .5
   translate <.25,1.5,.2>
   scale 2
   translate <2.25,1.5,3.5>
   ]
  }
 }
 finish {ambient 0 diffuse 1 brilliance 4 specular 1 roughness .01 metallic}
}

#declare PanelScars=
texture {
 pigment {
  crackle form <1,0,0>
  color_map {
   [0 rgbt <.1,.01,0,.5>]
   [.2 rgbt <.1,.01,0,1>]
  }
  scale .5
  turbulence .2
  lambda 3
  scale 4
 }
 normal {
  dents .1
 }
 finish {
  diffuse .5 ambient 0
 }
}

#declare PanelDirt=
texture {
 pigment {
  granite
  color_map {
   [0 rgb .2*<.8,.75,.7> transmit .99]
   [1 rgb .1*<.8,.75,.7> transmit .8]
  }
 }
 finish {ambient 0 diffuse .5}
}

#declare PanelDirt2=
texture {
 pigment {
  granite
  color_map {
   [0 rgb .2*<.8,.75,.7> transmit .99]
   [1 rgb .1*<.8,.75,.7> transmit .6]
  }
 }
 finish {ambient 0 diffuse .5}
}


//Test-scene:
#local Area_Lights=off;
#local Skylights=60;

#local Seed=seed(123);


camera {
 location <2,2,2>*2
 look_at 0
}
//some fancy lighting
light_source {
 <-500,500,500>*50
 rgb <1.5,1.3,1.1>
 #if (Area_Lights)
 area_light
 x*5000,y*5000
 4,4
 circular
 orient
 #end
}
#local MI=Skylights;
#local I=0;

#while (I<MI)
 #local LL=vrotate(vrotate(x,z*360*rand(Seed)),y*180*rand(Seed));
 #local LH=pow(LL.y,2);
 #local LX=pow(1+LL.x/2,1);
 #local LL=LL*5000;
 light_source {
  LL
  rgb <.4,.5,.9>*2.5/MI
  #if (Area_Lights)
  area_light
  x*5000,y*5000
  4,4
  adaptive 2 jitter circular orient
  #end
 }
 #local I=I+1;
#end

sphere {
 0,1
 uv_mapping
 texture {MetalPanels translate 1 scale .25}
 texture {PanelScars scale <.125,.125,.5>}
 texture {PanelDirt scale <.5,.25,1>}
 texture {PanelDirt2 scale <.25,.125,.7>}
}
torus {
 1.5,.5
 uv_mapping
 texture {MetalPanels translate 1 scale .25}
 texture {PanelScars scale <.125,.125,.5>}
 texture {PanelDirt scale <.5,.25,1>}
 texture {PanelDirt2 scale <.25,.125,.7>}
}
union {
 cylinder {-x*4,x*4,.35}
 cylinder {-z*4,z*4,.35}
 texture {MetalPanels translate 1 scale .25}
 texture {PanelScars scale <.125,.125,.5>}
 texture {PanelDirt scale <.5,.25,.5>}
 texture {PanelDirt2 scale <.7,.125,.7>}
}

sphere {
 0,1
 pigment {bumps
  color_map {
   [.25 rgb <.7,.8,.9>]
   [.7 rgb 1]
  }
  poly_wave 2
  scale <1,.25,1>*5
  warp {turbulence .5 lambda 3}
  scale .5/5
 }
 finish {ambient 1 diffuse 0}
 scale 100
 no_shadow
 no_image
}
plane {y,-2
 pigment {
  granite
  color_map {
   [0 rgb <.5,.4,.3>]
   [1 rgb <.6,.5,.4>]
  }
 }
 finish {ambient 1 diffuse 0}
 no_image
 no_shadow
}
--- END CODE ---

cu!
-- 
#macro G(b,e)b+(e-b)*C/50#end#macro _(b,e,k,l)#local C=0;#while(C<50)
sphere{G(b,e)+3*z.1pigment{rgb G(k,l)}finish{ambient 1}}#local C=C+1;
#end#end _(y-x,y,x,x+y)_(y,-x-y,x+y,y)_(-x-y,-y,y,y+z)_(-y,y,y+z,x+y)
_(0x+y.5+y/2x)_(0x-y.5+y/2x)            // ZK http://www.povplace.com

Post a reply to this message

Attachments:
Download 'metalpanels.jpg' (40 KB)

Preview of image 'metalpanels.jpg'

"Meothuru" <nomail@nomail> wrote:
> A rusty iron-texture

Looks more like old oil than rust to me - but great effect in any case!

Post a reply to this message

Zeger Knaepen wrote:
> Metallic spaceship-hull panels
> 
> .. or greebles-in-a-texture if you like :)

  That one could be quite useful to many, I'm sure.

Post a reply to this message

Warp <war### [at] tagpovrayorg> wrote:
> Zeger Knaepen wrote:
> > Metallic spaceship-hull panels
> >
> > .. or greebles-in-a-texture if you like :)
>
>   That one could be quite useful to many, I'm sure.

Definitely so.

Post a reply to this message

"[GDS|Entropy]" <gds-entropy    AT    hotmail   DOT  com> wrote:
> To all users:
>
> Please post your metal textures here.
> Once this inc file is done I will move to waters.inc, stones.inc, woods.inc,
> etc.. so you can go ahead and post those textures too if you want. Remember:
> radiosity compatibility. ;-)
>
> ian

Here's another rusty one ...

#declare radiosity_on = true;
#declare globalreflection =1;

#if (radiosity_on)
// radiosity (global illumination) settings
global_settings {
  radiosity {
    pretrace_start 0.08           // start pretrace at this size
    pretrace_end   0.04           // end pretrace at this size
    count 35                      // higher -> higher quality (1..1600) [35]
    nearest_count 5               // higher -> higher quality (1..10) [5]
    error_bound 1.8               // higher -> smoother, less accurate [1.8]
    recursion_limit 3             // how much interreflections are calculated
(1..5+) [3]
    low_error_factor .5           // reduce error_bound during last pretrace
step
    gray_threshold 0.0            // increase for weakening colors (0..1) [0]
    minimum_reuse 0.015           // reuse of old radiosity samples [0.015]
    brightness 1                  // brightness of radiosity effects (0..1) [1]

    adc_bailout 0.01/2
    //normal on                   // take surface normals into account [off]
    //media on                    // take media into account [off]
    //save_file "file_name"       // save radiosity data
    //load_file "file_name"       // load saved radiosity data
    //always_sample off           // turn sampling in final trace off [on]
    //max_sample 1.0              // maximum brightness of samples

  }
  assumed_gamma 1.0
}
#else
global_settings {
  assumed_gamma 1.0
}
#end

#declare base = texture {
  pigment { color rgb <0.91, 0.95, 0.91>*0.5}
  normal {
     wrinkles
      normal_map {
        [ 0.0 granite 0.00 scale 0.001]
        [ 0.2 granite 0.0 ]
        [ 0.28 wrinkles 0.05 turbulence 0.5 scale 0.005]
        [ 0.38 wrinkles 0.05 turbulence 0.5 scale 0.005]
        [ 0.4 granite 0.0 ]
        [ 0.62 granite 0.05 turbulence 0.5 scale 0.005]
        [ 0.9 granite 0.0 ]
        [ 1.0 granite 0.00 scale 0.001]
      }
  turbulence 0.05
  scale 300
  }
    #if (radiosity_on)
      finish {
        ambient 0.0
        brilliance 2
        diffuse 0.3
        metallic
        specular 0.80
        roughness 1/2000
        reflection 0.9*globalreflection
      }
    #else
      finish {
        ambient 0.01
        brilliance 2
        diffuse 0.3
        metallic
        specular 0.80
        roughness 1/2000
        reflection 0.9*globalreflection
      }
    #end
}

#declare tex1 = texture {
  pigment { granite
    color_map {
      [ 0 color rgb <0.7, 0.4, 0.2> ]
      [ 1 color rgb <0.6, 0.2, 0.05> ]
    } turbulence 0.2 scale 0.5
  }
  normal { bumps 0.2
  turbulence 0.05
  scale 0.5
  }
    #if (radiosity_on)
      finish {
        ambient 0.0
        brilliance 2
        diffuse 0.3
        metallic
        specular 0.20
        roughness 1/20
        reflection 0.1*globalreflection
      }
    #else
      finish {
        ambient 0.01
        brilliance 2
        diffuse 0.3
        metallic
        specular 0.20
        roughness 1/20
        reflection 0.1*globalreflection
      }
    #end
}

#declare tex2 = texture {
  wrinkles
  texture_map {
     [0  base]
     [0.5 tex1 ]

  } scale 0.2 turbulence 0.5
}

#declare final= texture {
  wrinkles
  texture_map {
     [0  base]
     [0.1 base]
     [0.1 tex2 scale 0.005]
     [0.11 tex2 scale 0.005]
     [0.12 base]
     [0.5 base]
     [0.7 tex2 scale 0.05]
  } scale 0.2 turbulence 0.5
}

Post a reply to this message

Attachments:
Download 'metaltex.png' (216 KB)

Preview of image 'metaltex.png'

galvanized steel, might need some work though

#declare GalvanizedSteel=
material {
 texture {
  pigment {crackle solid scale .1
   color_map {
    [0 rgb .5]
    [1 rgb .9]
   }
  }
  normal {granite -.03}
  finish {ambient 0 diffuse 1 brilliance 3 specular 1 roughness .01 metallic 
reflection {0,.125 fresnel on metallic 1}}
 }
 interior {ior 30}
}

cu!
-- 
#macro G(b,e)b+(e-b)*C/50#end#macro _(b,e,k,l)#local C=0;#while(C<50)
sphere{G(b,e)+3*z.1pigment{rgb G(k,l)}finish{ambient 1}}#local C=C+1;
#end#end _(y-x,y,x,x+y)_(y,-x-y,x+y,y)_(-x-y,-y,y,y+z)_(-y,y,y+z,x+y)
_(0x+y.5+y/2x)_(0x-y.5+y/2x)            // ZK http://www.povplace.com

Post a reply to this message

Attachments:
Download 'galvanized steel.jpg' (43 KB)

Preview of image 'galvanized steel.jpg'

Great work everyone!!

Keep it up!

ian

Post a reply to this message

"Warp" <war### [at] tagpovrayorg> schreef in bericht 
news:49cfb8da$1@news.povray.org...
> Zeger Knaepen wrote:
>> Metallic spaceship-hull panels
>>
>> .. or greebles-in-a-texture if you like :)
>
>  That one could be quite useful to many, I'm sure.

Absolutely.

Thomas

Post a reply to this message

I like your textures.

Thomas

Post a reply to this message

Thomas de Groot wrote:
> Here are six metal textures. Nothing really special. Just thought they might 
> be of interest.
> 
> Thomas
> 
> 
> 
Rust on chrome looks great, so does middle back, makes me think of lead? 
or something about wet batteries?

Post a reply to this message

That is an excellent one!

Thomas

Post a reply to this message

"Jim Charter" <jrc### [at] msncom> schreef in bericht 
news:49d175de@news.povray.org...
> Rust on chrome looks great, so does middle back, makes me think of lead? 
> or something about wet batteries?

Middle back and right back are my combination, with some adaptations, of two 
separate textures, one by Meothuru, the other by jivvy (originally in Moray 
format).

Note: code files are attached in the message with the image.

Thomas

Post a reply to this message

This is great for far away; greebles for close up. Well done!
By the way, how is your update of the greebles macro coming along? (just 
curious...)

Thomas

Post a reply to this message

"[GDS|Entropy]" <gds-entropy    AT    hotmail   DOT  com> wrote:
> To all users:
>
> Please post your metal textures here.
> Once this inc file is done I will move to waters.inc, stones.inc, woods.inc,
> etc.. so you can go ahead and post those textures too if you want. Remember:
> radiosity compatibility. ;-)
>
> ian

Sorry to be so brain-challenged, but: radiosity compatibility? I've seen that
term mentioned several times lately, and have no clue what it means re:
textures.  I must have missed something somewhere. Please explain?

KW

Post a reply to this message

"Zeger Knaepen" <zeg### [at] povplacecom> wrote:
> Metallic spaceship-hull panels
>
> .. or greebles-in-a-texture if you like :)

Unique and useful. Definitely a keeper.

KW

Post a reply to this message

"Zeger Knaepen" <zeg### [at] povplacecom> wrote:
> galvanized steel, might need some work though

Very nice...

But how on EARTH did I not know about the 'solid' crackle pattern until now?
*smacks forehead* Obviously I'm not idly reading the docs during enough coffee
breaks!

:)

Post a reply to this message

> Keep it up!

Here's a few I had stored away. Some are perty generic though.

#declare tex_gray_metal = texture { 
   pigment{color <0.3,0.3,0.35>}
   finish {
      ambient 0.50
      brilliance 2
      diffuse 0.4
      metallic
      specular 0.50
      roughness 5/60
      reflection 0.1
   }
};

#declare tex_black_metal = texture { 
   pigment{Gray05}
   normal{facets coords 1 scale 0.1}
   finish {
      ambient 0.10
      brilliance 2
      diffuse 0.4
      metallic
      specular 0.50
      roughness 5/60
      reflection 0.1
   }
   scale 0.5
};

#declare tex_cast_metal = texture { 
   pigment {color <0.1,0.1,0>}
   normal {
      bumps 
      scale <0.002,0.002,0.005>*2
   }
   finish {
      specular 0.5 
      roughness 0.15
   } 
};

#declare chrome = texture{
  pigment{ color rgb <1,1,0.941176> }
  finish{ 
     ambient 0 
     diffuse 0.4 
     specular 0.9 
     roughness 0.06 
     reflection 0.4 
     metallic 
  }
};

#declare chrome2 = texture {
   pigment { color <1,1,0.941176> }
   finish { 
      ambient 0 
      diffuse 0.4 
      specular 0.9 
      roughness 0.06 
      reflection 0.2 
      metallic 
   }
};

#declare brushed = texture {
  pigment { color <1,1,0.968627> }
  normal { 
     wrinkles 0.3 
     scale 0.05 
  }
  finish { 
     ambient 0 
     diffuse 0.25 
     specular 0.9 
     roughness 0.1 
     reflection 0.2 
     metallic 
     brilliance 0.9 
     conserve_energy 
  }
};

#declare steel = texture {
  pigment { color rgb <1,1,0.941176> }
  finish { 
     ambient 0 
     diffuse .3 
     specular .9 
     roughness .1 
     reflection .3 
     metallic
  }
  normal { wrinkles .1 scale 1 }
};

#declare brass = texture {
  pigment { color rgb <0.549019,0.333333,0.2> }
  normal { 
     wrinkles 0.1 
     scale 1 
  }
  finish { 
     ambient 0 
     diffuse 0.2 
     specular 0.5 
     roughness 0.02 
     reflection 0.6 
     metallic 
  }
};

Post a reply to this message

Attachments:
Download 'my_metals.jpg' (178 KB)

Preview of image 'my_metals.jpg'

"Thomas de Groot" <tDOTdegroot@interDOTnlANOTHERDOTnet> wrote in message 
news:49d1dc84$1@news.povray.org...
> This is great for far away; greebles for close up. Well done!
> By the way, how is your update of the greebles macro coming along? (just 
> curious...)

not so good :(

I was working on it this weekend.  It works, but it's extremely slow.  As 
in: 25 minutes parsing time for 1 very simple greebled patch.  An entire 
spaceship made with those greebled patches would take a couple of hours. 
Not very useful, is it :(

I'm not sure yet how to make it faster.

oh well, I'll find a way :)

cu!
-- 
#macro G(b,e)b+(e-b)*C/50#end#macro _(b,e,k,l)#local C=0;#while(C<50)
sphere{G(b,e)+3*z.1pigment{rgb G(k,l)}finish{ambient 1}}#local C=C+1;
#end#end _(y-x,y,x,x+y)_(y,-x-y,x+y,y)_(-x-y,-y,y,y+z)_(-y,y,y+z,x+y)
_(0x+y.5+y/2x)_(0x-y.5+y/2x)            // ZK http://www.povplace.com

Post a reply to this message

My own textures aren't comparable to these incredible examples, but I 
have some other suggestions:

LightBeam's "Pyramolles" metallic material:
http://news.povray.org/povray.binaries.images/thread/%3C41aa4cb1@news.povray.org%3E/?ttop=231772&toff=1650

Jaime Vives Piqueres's t_custom_paint:
http://news.povray.org/41d83ed3@news.povray.org

Michael Raiford's copper texture:
http://news.povray.org/41e52fcd$1@news.povray.org

Ross's texture:
http://news.povray.org/povray.general/thread/%3C42c5bb9d%40news.povray.org%3E/

Helge H's texture:
http://news.povray.org/povray.binaries.images/thread/%3Cweb.4403bbf171d7750e1c6902970@news.povray.org%3E/?ttop=284288&toff=1550


;-)
Paolo



 >[GDS|Entropy]  on date 29/03/2009 04:06 wrote:
> To all users:
> 
> Please post your metal textures here.
> Once this inc file is done I will move to waters.inc, stones.inc, woods.inc, 
> etc.. so you can go ahead and post those textures too if you want. Remember: 
> radiosity compatibility. ;-)
> 
> ian 
> 
>

Post a reply to this message

"[GDS|Entropy]" <gds-entropy    AT    hotmail   DOT  com> wrote:
> Please post your metal textures here.
> Once this inc file is done I will move to waters.inc, stones.inc, woods.inc,
> etc.. so you can go ahead and post those textures too if you want. Remember:
> radiosity compatibility. ;-)

These textures are all great, but they all seem to fill very specific needs.
What might be nice is to also offer a set of 'bog-standard' ;-) polished,
diffuse or otherwise finished metals which just consist of a well-chosen
pigment colour and the standard finish/normal in question (i.e., Gold_Polished,
Gold_Diffuse, Gold_Beaten) etc.

Does anyone know of any decent photographic reference table(s) that compare
different metal colours? Even just jewellery metals would be a starting point.
(I've tried searching for this before and always come up short). I know some of
the common ones are defined in colors.inc, but to be honest most of them don't
look like the metals they're named for, so starting afresh would be my best
option.

I'm happy to knock up a standard set like this as long as I can find some good
image references.

Comments?

Post a reply to this message

Very evocative!
;-)
Paolo

 >Zeger Knaepen  on date 29/03/2009 19:31 wrote:
> Metallic spaceship-hull panels
> 
> .. or greebles-in-a-texture if you like :)
>

Post a reply to this message

Bill Pragnell wrote:
  > These textures are all great, but they all seem to fill very 
specific needs.
> What might be nice is to also offer a set of 'bog-standard' ;-) polished,
> diffuse or otherwise finished metals which just consist of a well-chosen
> pigment colour and the standard finish/normal in question (i.e., Gold_Polished,
> Gold_Diffuse, Gold_Beaten) etc.
> 
> Does anyone know of any decent photographic reference table(s) that compare
> different metal colours? Even just jewellery metals would be a starting point.
> (I've tried searching for this before and always come up short). I know some of
> the common ones are defined in colors.inc, but to be honest most of them don't
> look like the metals they're named for, so starting afresh would be my best
> option.
> 
> I'm happy to knock up a standard set like this as long as I can find some good
> image references.
> 
> Comments?
> 

Well, what I have is some data measured with a spectrophotometer. Colors 
(converted into scRGB color space - which is just sRGB primaries but 
with a linear gamma mapping), diffuse reflection as measured together 
with some IOR for fresnel reflection.

I made some macros for them, looks like this:


...snip
//******************************************************

// some micro normals

#declare P_Micro1 = pigment {
   granite turbulence 0
   color_map {
     [0.0 rgb 0.3]
     [1.0 rgb 0.7]
   }
   scale 0.003
}


#declare P_Micro2 = pigment {
   onion turbulence 0.5
   color_map{
     [0.0  color rgb 1.00]
     [0.45 color rgb 0.99]
     [0.55 color rgb 0.96]
     [1.0  color rgb 0.95]
   }
   scale 0.01
}



#declare P_Macro1 = pigment {
   crackle turbulence 1
   color_map {
     [0.00 rgb 0.3]
     [0.01 rgb 0.3]
     [0.02 rgb 0.7]
     [1.00 rgb 0.7]
   }
   scale 0.3
}

// "micro"-normals for blurred reflection - to get some highlights
#macro P_Polish(Polish)
   pigment_pattern {
     average
     pigment_map {
       [1 P_Micro1 translate x*20]
       [1 P_Micro1 translate y*20]
       [1 P_Micro1 translate z*20]
       [1 P_Micro2 translate -x*20]
       [1 P_Micro2 translate -y*20]
       [1 P_Micro2 translate -z*20]
     }
   }
   1 - Polish
#end


// "macro"-normals for scratches and dents
#macro P_Dents(Dents)
   pigment_pattern {
     average
     pigment_map {
       [1 P_Macro1 translate y*10]
       [1 P_Macro1 translate z*10]
     }
   }
   Dents
#end


// averaged normals
#macro N_Pattern(Polish, Dents)
   normal {
     average
     normal_map {
       [1 P_Polish(Polish)]
       [1 P_Dents(Dents)]
     }
   }
#end



// MATERIAL MACROS

#macro MaterialGold(Polish, Dents)
   material {
     texture {
       pigment {rgb <0.9927, 0.6952, 0.3302>}
       N_Pattern(Polish, Dents)
       finish {
         ambient 0  diffuse 1-0.7280
         specular 0  brilliance 3
         reflection {0.0 1.0 fresnel on metallic}
         conserve_energy
       }
     }
     interior {ior 2.83}
   }
#end


#macro MaterialSilver(Polish, Dents)
   material {
     texture {
       pigment {rgb <0.9284, 0.9016, 0.8678>}
       N_Pattern(Polish, Dents)
       finish {
         ambient 0  diffuse 1-0.9001
         specular 0 brilliance 3
         reflection {0.0 1.0 fresnel on metallic}
         conserve_energy
       }
     }
     interior {ior 3.64}
   }
#end


#macro MaterialCopper(Polish, Dents)
   material {
     texture {
       pigment {rgb <0.7802, 0.2985, 0.1078>}
       N_Pattern(Polish, Dents)
       finish {
         ambient 0  diffuse 1-0.3832
         specular 0  brilliance 2.4
         reflection {0.0 1.0 fresnel on metallic}
         conserve_energy
       }
     }
     interior {ior 3.26}
   }
#end

//******************************************************
...snip


Note that I did not use any specular or phong highlights, it all depends 
    on (blurred) reflections so they work well with "radiosity-only" 
scenes or MC-Pov. But I guess to add some specular values is simple and 
the values for brilliance are just wild guesses anyway (maybe they 
should be equal to the ior, I must admit that I have no idea how POV 
computes this brilliance value).

Example images, one is MCPov with 200 passes and one is POV Beta 31 with 
conventional lighting and 128 light sources (no radiosity).

Settings are always 0.5 for "Polished" and 0.2 for "Dents".

And I have (over)used the kitchen probe once more again ;)

Post a reply to this message

Attachments:
Download 'material_test_mcpov.jpg' (62 KB) Download 'material_test_lightdome.jpg' (50 KB)

Preview of image 'material_test_mcpov.jpg'

Preview of image 'material_test_lightdome.jpg'

Kenneth wrote:
> "[GDS|Entropy]" <gds-entropy    AT    hotmail   DOT  com> wrote:
>> To all users:
>>
>> Please post your metal textures here.
>> Once this inc file is done I will move to waters.inc, stones.inc, woods.inc,
>> etc.. so you can go ahead and post those textures too if you want. Remember:
>> radiosity compatibility. ;-)
>>
>> ian
> 
> Sorry to be so brain-challenged, but: radiosity compatibility? I've seen that
> term mentioned several times lately, and have no clue what it means re:
> textures.  I must have missed something somewhere. Please explain?
> 
> KW
> 

ambient 0 in the finish statement, otherwise it would emit light.

For "radiosity-lit-only" scenes (or MCPov for that matter) it would even 
mean "specular 0" and "phong 0".

-Ive

Post a reply to this message

I like them.
Some of these are very ...organic.
;-)
Paolo

 >Thomas de Groot  on date 29/03/2009 11:20 wrote:
> Here are six metal textures. Nothing really special. Just thought they might 
> be of interest.
> 
> Thomas
> 
> 
>

Post a reply to this message

"Zeger Knaepen" <zeg### [at] povplacecom> schreef in bericht 
news:49d1ec3c$1@news.povray.org...
>
> not so good :(
>
> I was working on it this weekend.  It works, but it's extremely slow.  As 
> in: 25 minutes parsing time for 1 very simple greebled patch.  An entire 
> spaceship made with those greebled patches would take a couple of hours. 
> Not very useful, is it :(
>
> I'm not sure yet how to make it faster.
>
> oh well, I'll find a way :)
>

In the meantime, the present version works fine :-)

I am sure you will find a way eventually.

Thomas

Post a reply to this message

Beautiful. This is just what I was thinking of. Are you willing to share these,
or just the colour data? :) How many metals have you created like this?

Ive <"ive### [at] lilysoftorg"> wrote:
> Note that I did not use any specular or phong highlights, it all depends
>     on (blurred) reflections so they work well with "radiosity-only"
> scenes or MC-Pov. But I guess to add some specular values is simple and
> the values for brilliance are just wild guesses anyway

Yeah, sounds good. Doesn't really matter, as long as they look good most of the
time, users can tweak easily enough.

> And I have (over)used the kitchen probe once more again ;)

Never!

To be honest, I wasn't even thinking of anything this ambitious - just a basic
polished finish, maybe some dents, really just to get the basic colours
consistent and believable. Great work!

Bill

Post a reply to this message

"Kenneth" <kdw### [at] earthlinknet> wrote:
> Sorry to be so brain-challenged, but: radiosity compatibility? I've seen that
> term mentioned several times lately, and have no clue what it means re:
> textures.  I must have missed something somewhere. Please explain?

Basically just making sure that it can be used in radiosity scenes without
acting as a light emitter there (due to ambient set to >0).

Post a reply to this message

"Tim Attwood" <tim### [at] anti-spamcomcastnet> wrote:
>       ambient 0.50

Yuck! :P

Post a reply to this message

Bill Pragnell wrote:
> This is just what I was thinking of. Are you willing to share these,
> or just the colour data? :) 

Sure. But I have only four more metal materials and here they are:


...snip
/--------------------------------------------------

#macro MaterialBronze(Polish, Dents)
   material {
     texture {
       pigment {rgb <0.5568, 0.3484, 0.1528>}
       N_Pattern(Polish, Dents)
       finish {
         ambient 0  diffuse 1-0.3768
         specular 0  brilliance 2
         reflection {0.0  1.0 fresnel on metallic}
         conserve_energy
       }
     }
     interior {ior 3.1}
   }
#end


#macro MaterialBrass(Polish, Dents)
   material {
     texture {
       pigment {rgb <0.5709, 0.3356, 0.1491>}
       N_Pattern(Polish, Dents)
       finish {
         ambient 0  diffuse 1-0.3702
         specular 0  brilliance 3
         reflection {0.0 1.0 fresnel on metallic}
         conserve_energy
       }
     }
     interior {ior 8.0}
   }
#end


#macro MaterialSteel(Polish, Dents)
   material {
     texture {
       pigment {rgb <0.4412, 0.4137, 0.3727>}
       N_Pattern(Polish, Dents)
       finish {
         ambient 0  diffuse 1-0.4163
         specular 0  brilliance 2.8
         reflection {0.0 1.0 fresnel on metallic}
         conserve_energy
       }
     }
     interior {ior 8.6}
   }
#end


#macro MaterialChrome(Polish, Dents)
   material {
     texture {
       pigment {rgb <0.9310, 0.9265, 0.9221>}
       N_Pattern(Polish, Dents)
       finish {
         ambient 0  diffuse 1-0.9642
         specular 0 brilliance 3
         reflection {0.0 1.0 fresnel on metallic}
         conserve_energy
       }
     }
     interior {ior 15}
   }
#end

/--------------------------------------------------
...snip


Feel free to use them in any way you like. (Note, the diffuse setting is 
quite important in combination with the color itself).


I do not claim there is something "physically" accurate with them - 
especially with the way I did handle the fresnel reflection. In the 
"real world" metals have fresnel reflection but in the "real world" the 
IOR is a complex number and for metals the imaginary part of the IOR is 
the important one. To do some tests with POV is since quite a while on 
my "to do"-list... oh well, if only the "real life" would not need most 
of my time :)


> To be honest, I wasn't even thinking of anything this ambitious - just a basic
> polished finish, maybe some dents, really just to get the basic colours
> consistent and believable. Great work!
> 

BTW, the colors from "metals.inc" in the POV contribution are not so 
bad, I think. The problem is, all of them (and this is also true for 
colors.inc, woods.inc and so on) are created in the early days of 
POV-Ray when everybody used assumed gamma 2.2 (or even assumed gamma was 
not yet introduced, POV simply did work with gamma 2.2). But we had a 
kind of paradigm change regarding the gamma handling and the new beta 
enforces a linear gamma. So to use them they all have to be inverse 
gamma corrected. And wrong gamma correction makes colors not only darker 
or brighter, it changes also the hue.

-Ive

Post a reply to this message

Ive <"ive### [at] lilysoftorg"> wrote:
> For "radiosity-lit-only" scenes (or MCPov for that matter) it would even
> mean "specular 0" and "phong 0".

That's not necessary, as without classic light sources these values don't have
any effect anyway (well, maybe a *tiny* bit more computing time).

They should definitely be non-zero for materials to work in non-radiosity-lit
scenes, as they will have to simulate highlights from the classic lights, which
we can't see otherwise.


Ideally, there should be *some* connection between these values and the
reflectivity of the material (and likewise between the roughness or
corresponding phong parameter, and the blurriness of reflectivity in case
micronormals are used), though I'm not sure how exactly these should be
related.

Post a reply to this message

Ive wrote:
> ambient 0 in the finish statement, otherwise it would emit light.

  That's what #default { finish { ambient 0 } } is for.

  What happens if you *want* the texture to have an ambient value >0?

Post a reply to this message

Warp wrote:
> Ive wrote:
>> ambient 0 in the finish statement, otherwise it would emit light.
> 
>   That's what #default { finish { ambient 0 } } is for.

This does not work if the texture already has a finish with ambient > 0.
But I'm pretty sure you know that.


>   What happens if you *want* the texture to have an ambient value >0?
Well, in a radiosity scene - thats what I was talking about - this means 
you are going to define a metal (remember, this thread is about metal 
textures) with a temperature of lets say 4500° Kelvin. But I guess you 
know that too ;)


-Ive

Post a reply to this message

clipka wrote:
> Ive <"ive### [at] lilysoftorg"> wrote:
>> For "radiosity-lit-only" scenes (or MCPov for that matter) it would even
>> mean "specular 0" and "phong 0".
> 
> That's not necessary, as without classic light sources these values don't have
> any effect anyway (well, maybe a *tiny* bit more computing time).
> 
> They should definitely be non-zero for materials to work in non-radiosity-lit
> scenes, as they will have to simulate highlights from the classic lights, which
> we can't see otherwise.
> 

Well, I did see it the other way round. If you define a texture that 
looks great with nice specular/phong highlights you might be 
disappointed how it looks if used in a radiosity only lit scene, because 
all highlights are gone.

-Ive

Post a reply to this message

clipka nous illumina en ce 2009-04-01 04:52 -->
> Ive <"ive### [at] lilysoftorg"> wrote:
>> For "radiosity-lit-only" scenes (or MCPov for that matter) it would even
>> mean "specular 0" and "phong 0".
> 
> That's not necessary, as without classic light sources these values don't have
> any effect anyway (well, maybe a *tiny* bit more computing time).
> 
> They should definitely be non-zero for materials to work in non-radiosity-lit
> scenes, as they will have to simulate highlights from the classic lights, which
> we can't see otherwise.
> 
> 
> Ideally, there should be *some* connection between these values and the
> reflectivity of the material (and likewise between the roughness or
> corresponding phong parameter, and the blurriness of reflectivity in case
> micronormals are used), though I'm not sure how exactly these should be
> related.
> 
> 
Any bluring will have an effect on the tightness of the highlights. The tighter 
the highlight, the more visible the effect.

Low reflectivity goes with weak highlights. Ether use a multiple of the 
reflection value or something like the square root of the reflection value. The 
highlights tend to look as if it increase faster than the perceived reflection 
for low reflection.

-- 
Alain
-------------------------------------------------
You know you've been raytracing too long when you have ever gotten in a flame 
war over various rendering softwares.
Stephan Ahonen

Post a reply to this message

Warp nous illumina en ce 2009-04-01 10:41 -->
> Ive wrote:
>> ambient 0 in the finish statement, otherwise it would emit light.
> 
>   That's what #default { finish { ambient 0 } } is for.
> 
>   What happens if you *want* the texture to have an ambient value >0?
You just add finish{ambient YourValue} and it will override that defined elsewhere.

If you provide a texture that is INTENDED as having some ambient, just add a 
comment to that effect to your texture. Make it clear that that texture will 
then illuminate it's surrounding in any radiosity scene.

-- 
Alain
-------------------------------------------------
John' First Law of Software Developer Productivity:

"A program written by someone who does not work for you will be done when it is 
done."

Post a reply to this message

Warp <war### [at] tagpovrayorg> wrote:
> > ambient 0 in the finish statement, otherwise it would emit light.
>
>   That's what #default { finish { ambient 0 } } is for.

Not with material to place in a lib. Those should have all parameters set, just
to be sure. After all, you never know what the user sets his defaults to.

>   What happens if you *want* the texture to have an ambient value >0?

Then you're screwed with radiosity...

Post a reply to this message

Ive <"ive### [at] lilysoftorg"> wrote:
> Well, I did see it the other way round. If you define a texture that
> looks great with nice specular/phong highlights you might be
> disappointed how it looks if used in a radiosity only lit scene, because
> all highlights are gone.

(As a matter of fact, I think the material definitions should get some overhaul,
too, so that specular highlights and specular reflection are automatically "in
sync", so you don't have to worry about such issues)

Post a reply to this message

clipka wrote:

> Warp <war### [at] tagpovrayorg> wrote:

>>   What happens if you *want* the texture to have an ambient value >0?

> Then you're screwed with radiosity...

include files could use a #define such as RADIOSITY_TEXTURES
to provide two versions of a texture depending on whether the
#define is set before #including. For textures which just use
a different ambient value that would be no extra effort to
write using a simple macro for ambient.

#macro AMBIENT(ambient_value)
#ifdef RADIOSITY_TEXTURES
   ambient 0
#else
   ambient ambient_value
#end
#end

#declare T_SOME_TEXTURE = texture
{
   pigment {...}
   normal  {...}
   finish  {... AMBIENT(0.15)}
}

Post a reply to this message

Ive <"ive### [at] lilysoftorg"> wrote:
> Kenneth wrote:

> > Sorry to be so brain-challenged, but: radiosity compatibility? I've seen that
> > term mentioned several times lately, and have no clue what it means re:
> > textures.  I must have missed something somewhere. Please explain?

>
> ambient 0 in the finish statement, otherwise it would emit light.
>
> For "radiosity-lit-only" scenes (or MCPov for that matter) it would even
> mean "specular 0" and "phong 0".
>

Got it. (Although the specular and phong stuff is new--I need to do some
experiments to see.)

Here's an 'old pitted iron texture' that I dug out of one of my scenes (I
actually started with one of the stones.inc pigments, and modified it)...

#declare old_pitted_iron_texture =
texture {
        pigment{
                granite  // AGATE works well for this too.
                color_map {

                        [0.000 rgb .8*<.4, .4, .380>]
                        [0.153 rgb .4]
                        [0.398 rgb .5*<0.7, 0.4, 0.25>]
                        [0.398 rgb .2*<0.7, 0.7, 0.7>]
                        [1.000 rgb <0.545, 0.380, 0.345>]
                          }

               }
        finish{
              ambient .2 // 0 for radiosity
              diffuse 1
              phong .6
              phong_size 24
        }
        normal {granite .7 scale 9}
    }

KW

Post a reply to this message

Attachments:
Download 'old_pitted_iron.jpg' (52 KB)

Preview of image 'old_pitted_iron.jpg'

Ive wrote:
> Warp wrote:
>> Ive wrote:
>>> ambient 0 in the finish statement, otherwise it would emit light.
>>
>>   That's what #default { finish { ambient 0 } } is for.
> 
> This does not work if the texture already has a finish with ambient > 0.
> But I'm pretty sure you know that.

  Then wouldn't the correct suggestion be "don't put an 'ambient' term
in the finish of the texture" rather than "use 'ambient 0'"?

  The former doesn't fix the ambient, so you can later change it to
whatever you want with #default. The latter fixes it and you can't
change it without modifying the texture code.

Post a reply to this message

Alain wrote:
> Warp nous illumina en ce 2009-04-01 10:41 -->
>> Ive wrote:
>>> ambient 0 in the finish statement, otherwise it would emit light.
>>
>>   That's what #default { finish { ambient 0 } } is for.
>>
>>   What happens if you *want* the texture to have an ambient value >0?
> You just add finish{ambient YourValue} and it will override that defined
> elsewhere.

  Wouldn't it simply be easier if the texture didn't define any ambient
at all? Then you can use #default to set it to whatever you want.

Post a reply to this message

clipka wrote:
> Warp <war### [at] tagpovrayorg> wrote:
>>> ambient 0 in the finish statement, otherwise it would emit light.
>>   That's what #default { finish { ambient 0 } } is for.
> 
> Not with material to place in a lib. Those should have all parameters set, just
> to be sure.

  Just to be sure of what?

  Why shouldn't the ambient term of a texture be definable with a
#default block, even if the texture is in a library?

>>   What happens if you *want* the texture to have an ambient value >0?
> 
> Then you're screwed with radiosity...

  That didn't answer my question.

Post a reply to this message

Warp wrote:

>   Why shouldn't the ambient term of a texture be definable with a
> #default block, even if the texture is in a library?

because the designer of the texture might wish to specify
the intended ambient value for use with classical lighting.

Post a reply to this message

Ive <"ive### [at] lilysoftorg"> wrote:
> Warp wrote:
> > Ive wrote:
> >> ambient 0 in the finish statement, otherwise it would emit light.
> >
> >   That's what #default { finish { ambient 0 } } is for.
>
> This does not work if the texture already has a finish with ambient > 0.

That's true.

Actually there's already a very easy way to turn off ALL ambient light settings
in a scene: global_settings{ambient_light 0}

It's really a multiplier (which is why it's set up as <1,1,1> by default); a
very useful little on/off ambient-light switch for running radiosity scenes.

KW

Post a reply to this message

"Kenneth" <kdw### [at] earthlinknet> wrote:
> Ive <"ive### [at] lilysoftorg"> wrote:
> > Warp wrote:
> > > Ive wrote:
> > >> ambient 0 in the finish statement, otherwise it would emit light.
> > >
> > >   That's what #default { finish { ambient 0 } } is for.
> >
> > This does not work if the texture already has a finish with ambient > 0.
>
> That's true.
>
> Actually there's already a very easy way to turn off ALL ambient light settings
> in a scene: global_settings{ambient_light 0}
>
> It's really a multiplier (which is why it's set up as <1,1,1> by default); a
> very useful little on/off ambient-light switch for running radiosity scenes.
>
> KW

I find that even worse - in a radiosity scene, you often want some objects to
give out light via an ambient term. Specifically with lightprobes, you need the
lightprobe image to be ambient X and diffuse 0. Radiosity based lightprobe
scenes often have no actual lights - all the lighting originates from the
lightprobe. Setting the global ambient multiplier to 0 turns off the lightprobe
in those cases, and your scene ends up black...

Post a reply to this message