|
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Thomas de Groot wrote:
> I think now that an easier workflow would be to slice a pie section from a
> featureless shaft, exactly covering one flute width and twice the half rib
> widths; to craft the flute and finally to apply a rotational sweep to
> restore the complete shaft.
>
Thanks for that. Probably how I will proceed.
>
>>>If you want to follow the classical rules, number and form of the flutes
>>>are fixed, but that is another discussion entirely.
>>
>>I would be intereseted if you have any references. Right now I am using
>>18 flutes, so a 20 degree rotation.
>
> 24 seems to have been the general use in antiquity, at least in the
> classical period. However, older columns could have up to 48 flutes. Ribs
> were sharp during the Doric Order period, but flat (with deeper flutes)
> later.
>
>>
Interesting. I have been making counts of visible flutes on coluns here
and there, (including the new MMA classical wing,) then doubling the
number, but it never seems quite that many. I will have to pay closer
attention.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
46c5dabe$1@news.povray.org...
> Shay wrote:
>
>
>
> I am not really sure there is support for an interpolated or function
> driven reduction of the radius in the sphere_sweep syntax but I have only
> ever looked at it briefly. In any case I still would not be able to
> compose such a function.
>
Does that fit your needs?
#declare P1=.7;
#declare P2=.9;
#declare P3=1.1;
#declare P4=1.15;
#declare Shaft=
sphere_sweep {
cubic_spline
5,
<0, 7.5, 0>, P1
<0, 5.5, 0>, P2
<0, 0, 0>,P3
<0, -5.5, 0>,P4
<0, -7.5, 0>, P4
pigment {color rgb 1 }
}
#declare Flute =
sphere_sweep {
cubic_spline
5,
<P1, 7.5, 0>, 0.1
<P2, 5, 0>, .1
<P3, 0, 0>, .1
<P4, -5, 0>,.1
<P4, -7.5, 0>, .1
pigment {color rgb 1 }
}
#declare Flutes= union{
#declare C_Flute =0;
#while (C_Flute<20)
object{Flute rotate y*18*C_Flute}
#declare C_Flute =C_Flute+1;
#end
}
difference{
object{Shaft}
object{Flutes}
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
M_a_r_c wrote:
Thanks, yes, the constant radius on your flutes are one of the problems
I wanted to overcome, but obviously, tha can be adjusted by eyeball or a
static calulation beforehand, and I now see the possibilities. Also it
renders much faster than my spline solution.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
46c615ec$1@news.povray.org...
> M_a_r_c wrote:
>
> Thanks, yes, the constant radius on your flutes are one of the problems I
> wanted to overcome, but obviously, tha can be adjusted by eyeball or a
> static calulation beforehand, and I now see the possibilities. Also it
> renders much faster than my spline solution.
I didn't study the greek architecture, it's a fast try at a sphere_sweep
solution as Shay suggested :-)
I wondered wether the flute radius had to be constant or not but I see no
problem at making it vary as a fraction of the shaft radius.
That's better I think.
#declare P1=.7;
#declare P2=.9;
#declare P3=1.6; // Obelix nudged my elbow here ;-) just to show as flute
radius follows shaft radius... better with 1.1
#declare P4=1.15;
#declare Shaft=
sphere_sweep {
cubic_spline
5,
<0, 12.5, 0>, P1
<0, 10.0, 0>, P2
<0, 5, 0>,P3
<0, 0.0, 0>,P4
<0, -2.5, 0>, P4
}
#local N_flutes=20; //Number of flutes
#local Flute_Ratio=.95; //flute radial coverage
#local F_fctr=pi*Flute_Ratio/N_flutes;
#declare Flute =
sphere_sweep {
cubic_spline
5,
<P1, 12.5, 0>, F_fctr*P1
<P2, 10, 0>, F_fctr*P2
<P3, 5, 0>, F_fctr*P3
<P4, 0, 0>, F_fctr*P4
<P4, -2.5, 0>, F_fctr*P4
}
#declare Flutes= union{
#declare C_Flute =0;
#while (C_Flute<20)
object{Flute rotate y*C_Flute*360/N_flutes}
#declare C_Flute =C_Flute+1;
#end
}
difference{
object{Shaft}
object{Flutes}
pigment {color rgb 1 }
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
46c6b8cb$1@news.povray.org...
Last one, I think, now radius and y coordinate declared in the same 2d
vector
// radius and y coordinate declared in same 2d vector
#declare P1=<.7,12.5>;
#declare P2=<.9,10>;
#declare P3=<1.1,5>;
#declare P4=<1.15,0>;
#declare P5=<1.1,-2.5>;
#declare Shaft=
sphere_sweep {
cubic_spline
5,
<0, P1.y, 0>, P1.x
<0, P2.y, 0>, P2.x
<0, P3.y, 0>, P3.x
<0, P4.y, 0>, P4.x
<0, P5.y, 0>, P5.x
}
#local N_flutes=25; //Number of flutes
#local Flute_Ratio=.9; //flute radial coverage
#local F_fctr=pi*Flute_Ratio/N_flutes;
#declare Flute =
sphere_sweep {
cubic_spline
5,
<P1.x, P1.y, 0>, F_fctr*P1.x
<P2.x, P2.y, 0>, F_fctr*P2.x
<P3.x, P3.y, 0>, F_fctr*P3.x
<P4.x, P4.y, 0>, F_fctr*P4.x
<P5.x, P5.y, 0>, F_fctr*P4.x
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
46c6c1cf$1@news.povray.org...
Ooops
#declare Flute =
sphere_sweep {
cubic_spline
5,
<P1.x, P1.y, 0>, F_fctr*P1.x
<P2.x, P2.y, 0>, F_fctr*P2.x
<P3.x, P3.y, 0>, F_fctr*P3.x
<P4.x, P4.y, 0>, F_fctr*P4.x
<P5.x, P5.y, 0>, F_fctr*P5.x // not F_fctr*P4.x as in previous post
}
Marc
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
M_a_r_c wrote:
> 46c6c1cf$1@news.povray.org...
> Ooops
>
> #declare Flute =
> sphere_sweep {
> cubic_spline
> 5,
> <P1.x, P1.y, 0>, F_fctr*P1.x
> <P2.x, P2.y, 0>, F_fctr*P2.x
> <P3.x, P3.y, 0>, F_fctr*P3.x
> <P4.x, P4.y, 0>, F_fctr*P4.x
> <P5.x, P5.y, 0>, F_fctr*P5.x // not F_fctr*P4.x as in previous post
> }
>
>
> Marc
>
>
Poifect! Thanks, I am immediately switching to this method.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|